先上效果图
初学shader那会,做的一个效果测试,一部分效果为shader手写,一部分效果shaderforge插件的效果。
第一步 建个球,用shaderforge拉个内发光效果shader赋给小球的材质
shaderforge连线图如下:
第二步 再建个小点的球,写个外发光shader,并且带有顶点动画,赋给小球材质
中间那个皱皱小白球,因为顶点动画的效果,导致凹凸不平。可以看出来外发光好像剥离出来了,因为这个外发光的原理就是shader中的另外一个pass在法线方向向外延伸,制作光晕效果。
shader代码如下:
Shader "Unlit/waifaguangVertex" //Shader文件索引路径
{
// 属性
Properties
{
_MainTex("Texture(RGB)", 2D) = "grey" {} //表面贴图 默认灰色
_Color("Color", Color) = (0, 0, 0, 1) //为贴图附加的颜色 默认为白色
_AtmoColor("Atmosphere Color", Color) = (0, 0.4, 1.0, 1) //光晕颜色
_Size("Size", Float) = 0.1 //光晕范围
_OutLightPow("Falloff",Float) = 5 //光晕平方参数
_OutLightStrength("Transparency", Float) = 15 //光晕强度
_Input1("Input 1", float) = 0.0
_Input2("Input 2", float) = 0.0
_Input3("Input 3", float) = 0.0
}
SubShader
{
Pass //通道1 用于给物体贴图、填色
{
Name "PlaneBase"
Tags{ "LightMode" = "Always" }
Cull Back
//CG程序开始
CGPROGRAM
//声明顶点着色器函数为vert
#pragma vertex vert
//声明片段着色器函数为frag
#pragma fragment frag
#include "UnityCG.cginc"
//函数可能用到的参数
uniform sampler2D _MainTex;
uniform float4 _MainTex_ST;
uniform float4 _Color;
uniform float4 _AtmoColor;
uniform float _Size;
uniform float _OutLightPow;
uniform float _OutLightStrength;
float _Input1;
float _Input2;
float _Input3;
//顶点着色器的输出
struct vertexOutput
{
float4 pos:SV_POSITION;
float3 normal:TEXCOORD0;
float3 worldvertpos:TEXCOORD1;
float2 texcoord:TEXCOORD2;
};
//顶点着色器函数
vertexOutput vert(appdata_base v)
{
vertexOutput o;
//顶点动画
v.vertex.xyz += v.normal * (sin((v.vertex.x + _Time * _Input3) * _Input2)+ cos((v.vertex.z + _Time * _Input3) * _Input2)) * _Input1;
// 顶点位置
o.pos = UnityObjectToClipPos(v.vertex);
// 法线
o.normal = v.normal;
// 世界坐标顶点位置
o.worldvertpos = mul(unity_ObjectToWorld, v.vertex).xyz;
// 纹理
o.texcoord = TRANSFORM_TEX(v.texcoord, _MainTex);
return o;
}
//片段着色器函数
float4 frag(vertexOutput i) :COLOR
{
float4 color = tex2D(_MainTex, i.texcoord);
// 纹理贴图叠加颜色
return color*_Color;
}
ENDCG
}
//通道2: 用于生成模型外部的光晕
Pass
{
Name "AtmosphereBase"
Tags{ "LightMode" = "Always" }
Cull Front
Blend SrcAlpha One
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
uniform float4 _Color;
uniform float4 _AtmoColor;
uniform float _Size;
uniform float _OutLightPow;
uniform float _OutLightStrength;
float _Input1;
float _Input2;
float _Input3;
struct vertexOutput
{
float4 pos:SV_POSITION;
float3 normal:TEXCOORD0;
float3 worldvertpos:TEXCOORD1;
};
vertexOutput vert(appdata_base v)
{
vertexOutput o;
//顶点动画
v.vertex.xyz += v.normal * (sin((v.vertex.x + _Time * _Input3) * _Input2)+ cos((v.vertex.z + _Time * _Input3) * _Input2)) * _Input1;
//顶点位置以法线方向向外延伸
v.vertex.xyz += v.normal*_Size;
o.pos = UnityObjectToClipPos(v.vertex);
o.normal = v.normal;
o.worldvertpos = mul(unity_ObjectToWorld, v.vertex);
return o;
}
float4 frag(vertexOutput i):COLOR
{
i.normal = normalize(i.normal);
//视角法线
float3 viewdir = normalize(i.worldvertpos.xyz - _WorldSpaceCameraPos.xyz);// normalize(i.worldvertpos - _WorldSpaceCamerePos);
float4 color = _AtmoColor;
//视角法线与模型法线点积形成中间指为1向四周逐渐衰减为0的点积值,赋给透明通道,形成光晕效果
color.a = pow(saturate(dot(viewdir, i.normal)), _OutLightPow);
color.a *= _OutLightStrength*dot(viewdir, i.normal);
return color;
}
ENDCG
}
}
FallBack "Diffuse"
}
以上代码参考了链接:https://blog.csdn.net/v_xchen_v/article/details/78262919,在其基础上添加了顶点动画的效果。
第三步 在大球和小球之间模拟气流效果
如下图所示:
本质上,其实也是一堆小球,一堆带有纹理动画效果的小球。
需要一张线图,虽然是程序员,但还是自己P了一张,比较简单:
纹理动画通过shaderforge实现,很简单,连线图如下:
新建个小球,大小介于外发光和内发光的两个球之间,建一个新的材质,赋给小球,再把刚才的shader赋给材质。
然后横向、纵向、斜向,按不同的尺寸复制几份小球,效果就出来了。