FPGA实现(按键消抖+矩阵扫描+数码管显示)

最新推荐文章于 2024-05-15 22:49:57 发布
最新推荐文章于 2024-05-15 22:49:57 发布
阅读量1.1w 收藏 244
点赞数 31
分类专栏： 技术博客 文章标签： fpga verilog
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/qq_40964256/article/details/105567087
版权

一、按键消抖

谈到按键，我们首先应该想到消抖，在一般设计中，认为抖动的总时间会持续20ms以内(这个数值在程序消抖时会用到)，具体情况如下图所示：
在这里插入图片描述
硬件消抖
一方面我们可以通过RS触发器来完成消抖：
在这里插入图片描述
但是比较明显，这种电路只适用于单刀双掷的情况，而通常我们使用更多的是两脚或四脚按键，针对此类按键目前常用下面两种电路来实现消抖：
在这里插入图片描述
其原理是利用电阻和电容对波形进行积分，不过硬件方法一般只在按键数量较少时使用，不然会使用到大量的电阻电容；更为经济和简洁的方法是通过编程实现消抖。

软件消抖
对于单按键的消抖模块，其接口如下图所示：
在这里插入图片描述
接口声明功能描述如下：

接口名称I/O功能描述
CLKI50M时钟
nRSTI复位信号
KEY_INI按键输入
KEY_FLAGO按键状态的切换
KEY_STATEO按键状态

软件消抖主要涉及信号跳变沿检测、计数器和状态机

	//======判断按键输入信号跳变沿========//
	always @(posedge CLK or negedge nRST)
		if(!nRST)
			begin
				key_a <= 1'b0;
				key_b <= 1'b0;
			end
		else
			begin
				key_a <= KEY_IN;
				key_b <= key_a;
			end
	assign flag_H2L = key_b && (!key_a);//下降沿
	assign flag_L2H = (!key_b) && key_a;//上升沿

设计状态机如下：
在这里插入图片描述

当前状态下一个状态跳转条件
Key_upKey_up(!flag_H2L) — 没检测的下降沿
Key_upFilter_Up2Down(flag_H2L) — 检测到下降沿
Filter_Up2DownKey_up(!cnt_full).(flag_L2H) — 还没达到消抖时间就遇到上升沿
Filter_Up2DownFilter_Up2Down(!flag_L2H).(!cnt_full) — 没到达消抖时间也没遇到上升沿
Filter_Up2DownKey_down(cnt_full) — 到达消抖时间
Key_downFilter_Down2Up(flag_L2H) — 遇到上升沿
Key_downKey_down(!flag_L2H) — 没遇到上升沿
Filter_Down2UpKey_down(flag_H2L).(!cnt_full) — 还没达到消抖时间就遇到下升沿
Filter_Down2UpFilter_Down2Up(!flag_H2L).(!cnt_full) — 没到达消抖时间也没遇到下升沿
Filter_Down2UpKey_up(cnt_full) — 到达消抖时间

按键消抖完整模块 KeyPress.v 如下：

module KeyPress(
	CLK,
	nRST,
	KEY_IN,
	KEY_FLAG,
	KEY_STATE
);
	input CLK;
	input nRST;
	input KEY_IN;
	
	output reg KEY_FLAG;
	output reg KEY_STATE;
	
	reg key_a, key_b;
	reg en_cnt, cnt_full;
	reg [3:0]state;
	reg [19:0]cnt;
	wire flag_H2L, flag_L2H;
	
	localparam
		Key_up			=	4'b0001,
		Filter_Up2Down	=	4'b0010,
		Key_down			=	4'b0100,
		Filter_Down2Up	=	4'b1000;
		
	//======判断按键输入信号跳变沿========//
	always @(posedge CLK or negedge nRST)
		if(!nRST)
			begin
				key_a <= 1'b0;
				key_b <= 1'b0;
			end
		else
			begin
				key_a <= KEY_IN;
				key_b <= key_a;
			end
	assign flag_H2L = key_b && (!key_a);
	assign flag_L2H = (!key_b) && key_a;
	
	//============计数使能模块==========//
	always @(posedge CLK or negedge nRST)
		if(!nRST)
			cnt <= 1'b0;
		else if(en_cnt)
			cnt <= cnt + 1'b1;
		else
			cnt <= 1'b0;
			
	//=============计数模块=============//
	always @(posedge CLK or negedge nRST)
		if(!nRST)
			cnt_full <= 1'b0;
		else if(cnt == 20'd999_999)
			cnt_full <= 1'b1;
		else
			cnt_full <= 1'b0;
	
	//=============有限状态机============//
	always @(posedge CLK or negedge nRST)
		if(!nRST)
			begin
				en_cnt <= 1'b0;
				state <= Key_up;
				KEY_FLAG <= 1'b0;
				KEY_STATE <= 1'b1;
			end
		else
			case(state)
				//保持没按
				Key_up: begin 
					KEY_FLAG <= 1'b0;
					if(flag_H2L) begin
						state <= Filter_Up2Down;
						en_cnt <= 1'b1;
					end
					else
						state <= Key_up;							
				end
				//正在向下按	
				Filter_Up2Down: begin
					if(cnt_full) begin
						en_cnt <= 1'b0;
						state <= Key_down;
						KEY_STATE <= 1'b0;
						KEY_FLAG <= 1'b1;
					end
					else if(flag_L2H) begin
						en_cnt <= 1'b0;
						state <= Key_up;
					end
					else
						state <= Filter_Up2Down;
				end
				//保持按下状态
				Key_down: begin
					KEY_FLAG <= 1'b0;
					if(flag_L2H) begin
						state <= Filter_Down2Up;
						en_cnt <= 1'b1;
					end
					else 
						state <= Key_down;
				end
				//正在释放按键
				Filter_Down2Up: begin
					if(cnt_full) begin
						en_cnt <= 1'b0;
						state <= Key_up;
						KEY_FLAG <= 1'b1;
						KEY_STATE <= 1'b1;
					end
					else if(flag_H2L) begin
						en_cnt <= 1'b0;
						state <= Key_down;
					end						
					else
						state <= Filter_Down2Up;
				end
				//其他未定义状态
				default: begin
					en_cnt <= 1'b0;
					state <= Key_up;
					KEY_FLAG <= 1'b0;
					KEY_STATE <= 1'b1;
				end
			endcase	
endmodule

二、键盘扫描

矩阵键盘的原理图如下所示：
在这里插入图片描述
我们将行端口接到FPGA的输出端口，列端口接到FPFA的输入端口。当行端口被全部赋值为低电平之后，如果有某一个键按下则对应的列端口会被拉低，按键所在列被确定下来；然后我们可以先将行端口全部赋值为高电平(则列端口检测到的电平全为高)，再依次赋值为低电平，当列端口的电平不全为高时对应的行即为按键所在行。

对于矩阵扫描模块，其接口如下图所示：
在这里插入图片描述

接口声明功能描述如下：

接口名称I/O功能描述
CLKI50M时钟
nRSTI复位信号
KEY_COLI列端口信号
KEY_ROWO行端口信号
KEY_ValueO扫描到的键值
Value_enO键值有效性标识

设计行扫描的状态机如下：
在这里插入图片描述

当前状态下一个状态跳转条件
NO_KEYNO_KEY(!KeyPress:u0).(!KeyPress:u1).(!KeyPress:u2).(!KeyPress:u3)
NO_KEYROW_ONE(!KeyPress:u0).(!KeyPress:u1).(!KeyPress:u2).(KeyPress:u3) + (!KeyPress:u0).(!KeyPress:u1).(KeyPress:u2) + (!KeyPress:u0).(KeyPress:u1) + (KeyPress:u0)
ROW_ONENO_KEY(!KEY_COL[0]) + (KEY_COL[0]).(!KEY_COL[1]) + (KEY_COL[0]).(KEY_COL[1]).(!KEY_COL[2]) + (KEY_COL[0]).(KEY_COL[1]).(KEY_COL[2]).(!KEY_COL[3])
ROW_ONEROW_TWO(KEY_COL[0]).(KEY_COL[1]).(KEY_COL[2]).(KEY_COL[3])
ROW_TWONO_KEY(!KEY_COL[0]) + (KEY_COL[0]).(!KEY_COL[1]) + (KEY_COL[0]).(KEY_COL[1]).(!KEY_COL[2]) + (KEY_COL[0]).(KEY_COL[1]).(KEY_COL[2]).(!KEY_COL[3])
ROW_TWOROW_THREE(KEY_COL[0]).(KEY_COL[1]).(KEY_COL[2]).(KEY_COL[3])
ROW_THREENO_KEY(!KEY_COL[0]) + (KEY_COL[0]).(!KEY_COL[1]) + (KEY_COL[0]).(KEY_COL[1]).(!KEY_COL[2]) + (KEY_COL[0]).(KEY_COL[1]).(KEY_COL[2]).(!KEY_COL[3])
ROW_THREEROW_FOUR(KEY_COL[0]).(KEY_COL[1]).(KEY_COL[2]).(KEY_COL[3])
ROW_FOURNO_KEY

矩阵扫描完整模块 Key_Value.v 如下：

module KeyValue(
	CLK,
	nRST,
	KEY_ROW,
	KEY_COL,
	KEY_Value,
	Value_en
);
	input CLK;
	input nRST;
	input [3:0]KEY_COL;
	output reg Value_en;
	output reg [3:0]KEY_ROW;
	output reg [3:0]KEY_Value;
	
	wire [3:0]key_flag;
	wire [3:0]key_state;
	
	reg [4:0]state;
	reg row_flag;//标识已定位到行
	reg [1:0]rowIndex;
	reg [1:0]colIndex;
	
	localparam
		NO_KEY		=	5'b00001,
		ROW_ONE		=	5'b00010,
		ROW_TWO		=	5'b00100,
		ROW_THREE	=	5'b01000,
		ROW_FOUR	=	5'b10000;
		
	KeyPress u0(
		.CLK(CLK),
		.nRST(nRST),
		.KEY_IN(KEY_COL[0]),
		.KEY_FLAG(key_flag[0]),
		.KEY_STATE(key_state[0])
	);
	
	KeyPress u1(
		.CLK(CLK),
		.nRST(nRST),
		.KEY_IN(KEY_COL[1]),
		.KEY_FLAG(key_flag[1]),
		.KEY_STATE(key_state[1])
	);
	
	KeyPress u2(
		.CLK(CLK),
		.nRST(nRST),
		.KEY_IN(KEY_COL[2]),
		.KEY_FLAG(key_flag[2]),
		.KEY_STATE(key_state[2])
	);
	
	KeyPress u3(
		.CLK(CLK),
		.nRST(nRST),
		.KEY_IN(KEY_COL[3]),
		.KEY_FLAG(key_flag[3]),
		.KEY_STATE(key_state[3])
	);

	//==========通过状态机判断行===========//
	always @(posedge CLK or negedge nRST)
		if(!nRST)
			begin
				state <= NO_KEY;
				row_flag <= 1'b0;
				KEY_ROW <= 4'b0000;
			end
		else
			case(state)
				NO_KEY: begin
					row_flag <= 1'b0;
					KEY_ROW <= 4'b0000;	
					if(key_flag != 4'b0000) begin
						state <= ROW_ONE;
						KEY_ROW <= 4'b1110;
					end
					else
						state <= NO_KEY;
				end
				
				ROW_ONE: begin
					//这里做判断只能用KEY_COL而不能用key_state
					//因为由于消抖模块使得key_state很稳定
					//不会因为KEY_ROW的短期变化而变化
					//而KEY_COL则会伴随KEY_ROW实时变化
					if(KEY_COL != 4'b1111) begin
						state <= NO_KEY;
						rowIndex <= 4'd0;
						row_flag <= 1'b1;
					end
					else begin
						state <= ROW_TWO;
						KEY_ROW <= 4'b1101;
					end						
				end
				
				ROW_TWO: begin
					if(KEY_COL != 4'b1111) begin
						state <= NO_KEY;
						rowIndex <= 4'd1;
						row_flag <= 1'b1;
					end
					else begin
						state <= ROW_THREE;
						KEY_ROW <= 4'b1011;
					end						
				end
				
				ROW_THREE: begin
					if(KEY_COL != 4'b1111) begin
						state <= NO_KEY;
						rowIndex <= 4'd2;
						row_flag <= 1'b1;
					end
					else begin
						state <= ROW_FOUR;
						KEY_ROW <= 4'b0111;
					end						
				end
				
				ROW_FOUR: begin
					if(KEY_COL != 4'b1111) begin
						rowIndex <= 4'd3;
						row_flag <= 1'b1;
					end
					state <= NO_KEY;
				end
			endcase
	
	//===========判断按键所在列=============//
	always @(posedge CLK or negedge nRST)
		if(!nRST)
			colIndex <= 2'd0;
		else if(key_state != 4'b1111)
			case(key_state)
				4'b1110: colIndex <= 2'd0;
				4'b1101: colIndex <= 2'd1;
				4'b1011: colIndex <= 2'd2;
				4'b0111: colIndex <= 2'd3;
			endcase
	
	//===========通过行列计算键值==========//
	always @(posedge CLK or negedge nRST)
		if(!nRST)
			Value_en <= 1'b0;
		else if(row_flag)
			begin
				Value_en <= 1'b1;
				KEY_Value <= 4*rowIndex + colIndex;
			end
		else
			Value_en <= 1'b0;
			
endmodule

三、数码管显示控制

数码管的连接图如下：
在这里插入图片描述
从图上我们可以看出8个8段数码管通过共阳的方式连接，其位选端和段选端分为用8个I/O进行控制。

对于显示控制模块，其接口如下图所示：
在这里插入图片描述
接口声明功能描述如下：

接口名称I/O功能描述
CLKI50M时钟
nRSTI复位信号
KEY_ValueI键盘键值
Value_enI键值有效性标识
SELO位选信号
SEGO段选信号

数码管显示控制完整模块 ShowControl.v 如下：

module ShowControl(
	CLK,
	nRST,
	KEY_Value,
	Value_en,
	SEL,
	SEG
);

	input CLK;
	input nRST;
	input Value_en;
	input [3:0]KEY_Value;
	output reg [7:0]SEL;
	output reg [7:0]SEG;
	
	reg clock_1k;
	reg [14:0]cnt;
	reg [3:0]data_tmp;
	reg [31:0]disp_data;
	
	//=========产生数码管驱动脉冲=======//
	always @(posedge CLK or negedge nRST)
		if(!nRST)
			begin
				cnt <= 15'b0;
				clock_1k <= 1'b1;
			end
		else if(cnt == 15'd24_999)
			begin
				cnt <= 15'b0;
				clock_1k <= ~clock_1k;
			end
		else
			cnt <= cnt + 1'b1;
			
	//==========更新要显示的数据=========//
	always @(posedge CLK or negedge nRST)
		if(!nRST)
			disp_data <= 32'd0;
		else if(Value_en)
			disp_data <= {disp_data[27:0],KEY_Value};
		else
			disp_data <= disp_data;
			
	//=============位选控制============//
	always @(posedge clock_1k or negedge nRST)
		if(!nRST)
			SEL <= 8'b1111_1111;
		else if(SEL == 8'b1111_1111)
			SEL <= 8'b1111_1110;
		else
			SEL <= {SEL[6:0],SEL[7]};
		
	//=============段选控制============//
	always @(*)
		case(SEL)
				8'b1111_1110: data_tmp <= disp_data[3:0];
				8'b1111_1101: data_tmp <= disp_data[7:4];
				8'b1111_1011: data_tmp <= disp_data[11:8];
				8'b1111_0111: data_tmp <= disp_data[15:12];
				8'b1110_1111: data_tmp <= disp_data[19:16];
				8'b1101_1111: data_tmp <= disp_data[23:20];
				8'b1011_1111: data_tmp <= disp_data[27:24];
				8'b0111_1111: data_tmp <= disp_data[31:28];
		endcase
	
	//=============段选解析============//
	always @(*)
		case(data_tmp)
			4'h0: SEG <= 8'b11000000;
			4'h1: SEG <= 8'b11111001;
			4'h2: SEG <= 8'b10100100;
			4'h3: SEG <= 8'b10110000;
			4'h4: SEG <= 8'b10011001;
			4'h5: SEG <= 8'b10010010;
			4'h6: SEG <= 8'b10000010;
			4'h7: SEG <= 8'b11111000;
			4'h8: SEG <= 8'b10000000;
			4'h9: SEG <= 8'b10010000;
			4'ha: SEG <= 8'b10001000;
			4'hb: SEG <= 8'b10000011;
			4'hc: SEG <= 8'b11000110;
			4'hd: SEG <= 8'b10100001;
			4'he: SEG <= 8'b10000110;
			4'hf: SEG <= 8'b10001110;
		endcase
endmodule

四、顶层模块

对于顶层模块，其接口如下图所示：
在这里插入图片描述
其接口功能如前文所述-------------------------------------------------------------------

本设计顶层模块完整代码 DigitalTube.v 如下：

module DigitalTube(
	CLK,
	nRST,
	KEY_ROW,
	KEY_COL,
	SEL,
	SEG
);
	input CLK;
	input nRST;
	input [3:0]KEY_COL;
	output [3:0]KEY_ROW;
	output [7:0]SEL; //位选
	output [7:0]SEG; //段选
	
	wire value_en;
	wire [3:0]key_value;
	
	KeyValue keyValue1(
		.CLK(CLK),
		.nRST(nRST),
		.KEY_ROW(KEY_ROW),
		.KEY_COL(KEY_COL),
		.KEY_Value(key_value),
		.Value_en(value_en)
	);
	
	ShowControl showControl1(
		.CLK(CLK),
		.nRST(nRST),
		.KEY_Value(key_value),
		.Value_en(value_en),
		.SEL(SEL),
		.SEG(SEG)
	);
endmodule

参考文献

  • 明德杨《第二代开发板原理图v2》
  • 小梅哥《FPGA自学笔记——设计与验证》
小小小小小小菜鸡
关注
  • 31
    点赞
  • 踩
  • 244
    收藏
    觉得还不错? 一键收藏
  • 11
    评论
专栏目录
基于FPGA的矩阵键盘驱动
weixin_50810761的博客
01-22 1618
通过FPGA驱动矩阵键盘，提供源代码及TestBench文件，比较常见的模块，便于后续使用。
51单片机矩阵键盘在动态数码管上的显示
热门推荐
qq_56622761的博客
07-24 1万+
51单片机上的矩阵键盘一般是4*4大小的，用矩阵键盘动态控制数码管，需要程序同时调用动态数码管模块和矩阵键盘模块。 1.1 矩阵键盘原理 独立键盘与单片机连接时，每一个按键都需要单片机的一个 I/O 口，若某单片机系统需较多按键，如果用独立按键便会占用过多的 I/O 口资源。单片机系统中 I/O 口资源往往比较宝贵，当用到多个按键时为了减少 I/O 口引脚，引 入了矩阵键盘。 无论是独立键盘还是矩阵键盘，单片机检测其是否被按下的依据都是一样的，也就是检测与该键对应的 I/O 口...
用FPGA设计矩阵键盘
最新发布
A_scanf_的博客
05-15 439
将P口的高四位（四个行）设置为低电平，将P口的低四位（四个列）设置为高电平。读取P口的低四位，检查哪一位从高电平变为低电平。是给某一行/某一列，高电平，其余七个全部为底电平，这时候读取电平变换，有电平变高表示按键按下，将P口的高四位（代表四个行）设置为高电平，将P口的低四位（代表四个列）设置为输入口；等待按键被按下，读取P1口的低四位，检查哪一位从低电平变为高电平。实验目的：设计一个可以读取按键按下数据的矩阵键盘。（本实验用的是逐行/逐列扫描方式）key4x4模块代码。
用FPGA实现16位矩阵键盘键值在数码管的显示
08-03
用FPGA实现16位矩阵键盘键值在数码管的显示，按下按键时对应的键值会显示在数码管上。包含了所需要的所有源代码。
基于FPGA的按键消抖
qq_52548731的博客
07-14 4177
fpga实现按键消抖
【FPGA入门】第五篇、按键消抖
大屁桃的博客
06-20 4694
博主学习FPGA的笔记
FPGA学习——按键消抖的多种实现方法
qq_54347584的博客
07-26 4621
FPGA实现按键消抖包括状态机实现按键消抖
【FPGA】按键消抖
wanerXR的博客
05-22 1万+
目录一丶按键原理二丶按键消抖三丶消抖方式1.延迟采样①任务描述②编写代码③时序图分析④仿真2.抖动稳定后采样①任务描述②编写代码③时序图分析④仿真四丶消抖场景五丶消抖应用 一丶按键原理 我们首先来看原理图 可以看到有4条输入线接到FPGA的IO口（最左边四个KEY）上，分两种情况： 1.当按键KEY1按下时，D3V3(也就是电源)通过电阻R（原理图上折线的那一段）然后再通过按键KEY1最终进入GND形成一条通路，那么这条线路的全部电压都加到了R这个电阻上，KEY1(最左边四个IO口)这个引脚就是个低电平。
FPGA4*4矩阵键盘实现简单电子琴
06-10
该篇文章将介绍如何使用FPGA实现一个4*4矩阵...这一设计综合运用了寄存器、计数器、时钟信号、复位信号、键盘扫描、按键识别、音频控制、LED显示控制以及蜂鸣器控制等技术，实现了基于FPGA的4*4矩阵键盘电子琴功能。
FPGA外接矩阵键盘实现各种操作
10-30
本项目“FPGA外接矩阵键盘实现各种操作”展示了如何利用FPGA来处理矩阵键盘输入，并实现一系列功能，如数码管显示菜单、按键计数和生成特定序列。 矩阵键盘是一种常见的输入设备，通过排列按键形成一个行列交叉的...
单片机c语言，4乘4矩阵按键+8位数码管proteus
04-30
在本项目中，我们关注的是如何利用C语言来控制单片机，实现4乘4矩阵按键的扫描与处理，以及如何在8位数码管上显示相关信息。Proteus是一款强大的电子设计自动化工具，用于电路仿真和PCB设计，我们将使用它来辅助我们...
FPGA按键数码管显示
01-07
本项目“FPGA按键数码管显示”着重于使用FPGA实现数字输入与显示的功能，是学习和实践数字电路、嵌入式系统以及FPGA设计的一个典型实例。下面我们将深入探讨相关的知识点。 1. **FPGA基本原理**：FPGA由一系列可...
二、13【FPGA】按键消抖
ARM_qiao的博客
05-12 3346
按键消抖代码实现
#FPGA（矩阵键盘—数码管）
byhyf83862547的博客
02-11 658
2.设备：Cyclone II EP2C8Q208C8N。（2）行raw作为输出，列col作为输入。（3）2ms扫描一行。3.实验：数码管显示矩阵键盘按下的数字。5.步骤:（1）行raw扫描。FPGA矩阵键盘运行效果。
基于FPGA的 矩阵键盘按键识别 【原理+源码】
记录所学，分享知识，结识挚友
12-21 4093
最近了解了矩阵键盘扫描的原理，动手实现了一下，在这里做一个简单的总结。
基于FPGA的4x4矩阵键盘控制器verilog开发实现
FPGA/MATLAB学习教程/源码/项目合作开发
11-28 8871
这里第一部分的主要目标是设计一个键盘扫描程序，并读取4*4键盘上的键盘，并以0，1，2，3，4，5，6，7，8，9，A，B，C，D，E，F在7段数码管上显示出来。这里我们将用到开发板的键盘和数码管。本模块分为键盘扫描和数码管显示两个部分。这两个部分非常的简单，这里我们合在一起设计。
FPGA学习——矩阵键盘驱动及数码管显示键值
zsisinterested的博客
05-23 7600
矩阵键盘原理 在做矩阵键盘的驱动时，写了好多次都没有成功，出现了各种奇奇怪怪的错误。最后在网上看了无数篇的博客和讲解，终于搞懂了原理。 矩阵键盘的电路原理图如图所示（在网上看到别人的就随手down了下来）： 矩阵键盘一共十六个按键，共接出八个引脚（四个行四个列），其中四个输入，四个输出。一般都把四个行作为输入的四条线，把四个列作为输出。 先将四条列线全部拉低，若有按键被按下，电路接通，则对应的行线也被拉低，输出低电平，其余行线为高电平。然后在依次拉低每一条列线，其余列线置高电平，来判断是哪一根列线使输出行
单片机矩阵按键应用——动态显示
m0_72885897的博客
12-05 897
矩阵按键、数码管
FPGA入门学习——按键消抖
weixin_45897960的博客
10-16 180
我们所使用的按键开关为机械弹性开关，当机械触点断开、闭合时，由于机械触点的弹性作用，一个按键开关在闭合时不会马上稳定地接通，在断开时也不会一下子断开。因而在闭合及断开的瞬间均伴随有一连串的抖动，为了不产生这种现象而做的措施就是按键消抖。
FPGA用按键消抖实现流水灯
07-28
FPGA用按键消抖实现流水灯的方法是通过在按键输入信号上应用消抖电路来解决按键抖动问题。消抖电路可以使用计数器和状态机的组合来实现。当按键按下时，计数器开始计数，如果在一定的时间内没有检测到按键抬起的信号，那么就认为按键有效，触发流水灯的状态变化。这样可以避免因按键抖动而导致流水灯频繁切换的问题。 在给出的代码中，按键消抖的实现是通过计数器cnt来实现的。当按键按下时，计数器开始计数，当计数器达到最大值时，即认为按键有效，触发流水灯的状态变化。同时，在计数器达到最大值之前，如果检测到按键抬起的信号，计数器会被清零，重新开始计数。 具体实现的代码如下： ```verilog module key_ctrl ( input clk, input rst_n, input wire key, output wire \[3:0\] led_on ); parameter MAX = 25'd25_000_000; reg \[25:0\] cnt; //计数寄存器 reg\[3:0\] led_r; //记录0.5s计数器设计 always @(posedge clk or negedge rst_n) begin if(!rst_n) begin cnt <= 26'd0; end else if (cnt == MAX - 1'd1) begin cnt <= 26'd0; end else begin cnt <= cnt + 1'd1; end end always @(posedge clk or negedge rst_n) begin if(!rst_n) begin led_r <= 4'b0001; end else if(!key) begin if (cnt == MAX - 1'd1) begin led_r <= {led_r\[2:0\], led_r\[3\]}; end else begin led_r <= led_r; end end else begin led_r <= led_r; end end assign led_on = led_r; endmodule ``` 这段代码中，按键消抖的实现是通过两个always块来完成的。第一个always块用于计数器的计数和清零，第二个always块用于观察按键状态并触发流水灯的状态变化。通过这种方式，可以实现按键消抖并实现流水灯效果。 #### 引用[.reference_title] - *1* [FPGA按键消抖后实现流水灯控制](https://blog.csdn.net/Headogerz/article/details/81529807)[target="_blank" data-report-click={"spm":"1018.2226.3001.9630","extra":{"utm_source":"vip_chatgpt_common_search_pc_result","utm_medium":"distribute.pc_search_result.none-task-cask-2~all~insert_cask~default-1-null.142^v91^control_2,239^v3^insert_chatgpt"}} ] [.reference_item] - *2* [FPGA按键流水灯](https://blog.csdn.net/jynyyhd/article/details/131698029)[target="_blank" data-report-click={"spm":"1018.2226.3001.9630","extra":{"utm_source":"vip_chatgpt_common_search_pc_result","utm_medium":"distribute.pc_search_result.none-task-cask-2~all~insert_cask~default-1-null.142^v91^control_2,239^v3^insert_chatgpt"}} ] [.reference_item] - *3* [【FPGA第二天】按键消抖+流水灯](https://blog.csdn.net/qq_53085291/article/details/130352656)[target="_blank" data-report-click={"spm":"1018.2226.3001.9630","extra":{"utm_source":"vip_chatgpt_common_search_pc_result","utm_medium":"distribute.pc_search_result.none-task-cask-2~all~insert_cask~default-1-null.142^v91^control_2,239^v3^insert_chatgpt"}} ] [.reference_item] [ .reference_list ]
评论 11
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值