串口RS485

最新推荐文章于 2023-12-14 22:00:46 发布
最新推荐文章于 2023-12-14 22:00:46 发布
阅读量1.6k 收藏 2
点赞数 1
分类专栏： FPGA 文章标签： fpga
版权声明：本文为博主原创文章，遵循 CC 4.0 BY 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/qq_43796199/article/details/120107065
版权

RS485

一、RS485简介

RS-485是双向、半双工通信协议，信号采用差分传输方式，允许多个驱动器和接收器挂接在总线上，其中每个驱动器都能够脱离总线
在这里插入图片描述

二、实验内容

1.实验目标

在这里插入图片描述

2.实验原理图分析

所需模块 ：RS485总控模块
在这里插入图片描述
按键消抖模块：
在这里插入图片描述

呼吸灯模块：
在这里插入图片描述

流水灯模块：
在这里插入图片描述

UART_RX模块：
在这里插入图片描述

UART_TX模块 ：
在这里插入图片描述

LED_CTRL模块 ：
在这里插入图片描述
整体框图：
在这里插入图片描述

3.关于LED_CTRL模块的两种工作模式：

在这里插入图片描述
在这里插入图片描述

4.代码实现

按键消抖模块：

`timescale 1ns / 1ns
//
// Company: 
// Engineer: 
// 
// Create Date: 2021/09/05 19:58:40
// Design Name: 
// Module Name: key_filter
// Project Name: 
// Target Devices: 
// Tool Versions: 
// Description: 
// 
// Dependencies: 
// 
// Revision:
// Revision 0.01 - File Created
// Additional Comments:
// 
//


module key_filter#(
    parameter       CNT_MAX = 20'd999_999
)
(
    input   wire        sys_clk     ,
    input   wire        rst_n       ,
    input   wire        key_in      ,

    output  reg         key_flag   
);

reg  [19:0]   cnt_20ms      ;


always @(posedge sys_clk or negedge rst_n) begin
    if (rst_n == 1'b0) begin
        // reset
        cnt_20ms <= 20'd0;
    end
    else if (key_in == 1'b1) begin
        cnt_20ms <= 20'd0;
    end
    else if (cnt_20ms == CNT_MAX) begin
        cnt_20ms <= cnt_20ms;
    end
    else begin
        cnt_20ms <= cnt_20ms + 20'd1;
    end
end



always @(posedge sys_clk or negedge rst_n) begin
    if (rst_n == 1'b0) begin
        // reset
        key_flag <= 1'b0;
    end
    else if (cnt_20ms == (CNT_MAX - 20'd1)) begin
        key_flag <= 1'b1;
    end
    else begin
        key_flag <=  1'b0;
    end
end
endmodule

流水灯模块：

//
// Company: 
// Engineer: 
// 
// Create Date: 2021/09/05 20:36:16
// Design Name: 
// Module Name: water_led
// Project Name: 
// Target Devices: 
// Tool Versions: 
// Description: 
// 
// Dependencies: 
// 
// Revision:
// Revision 0.01 - File Created
// Additional Comments:
// 
//
module water_led#(
parameter   M  =  25'd24999999
)
(clk,rst_n,LED_L);

reg [24:0]  CNT1;
reg [2:0]   CNT2;

input  wire clk;
input  wire rst_n;
output reg  [3:0]   LED_L;

always @(posedge clk or negedge rst_n)begin
    if (rst_n == 1'b0) begin
        CNT1 <= 25'd0;
    end
    else if (CNT1 == 25'd24999999) begin
        CNT1 <= 25'd0;
    end
    else begin
        CNT1 <= CNT1 + 25'd1;
    end
end

always @(posedge clk or negedge rst_n)begin
    if (rst_n == 1'b0) begin
        CNT2 <= 3'd0;
    end
    else if ((CNT2 == 3'd4) && (CNT1 == (M-25'd1))) begin
        CNT2 <= 3'd0;
    end
    else if ((CNT1 == (M-1))) begin
        CNT2 <= CNT2 + 3'd1;
    end
    else begin
        CNT2 <= CNT2;
    end
end

always @(posedge clk)
    if (CNT2 == 3'd0) begin
        LED_L <= 4'd0;
    end
    else if (CNT2 == 3'd1) begin
        LED_L <= 4'd1;
    end
    else if (CNT2 == 3'd2) begin
        LED_L <= 4'd2;
    end
    else if (CNT2 == 3'd3) begin
        LED_L <= 4'd4;
    end
    else if (CNT2 == 3'd4) begin
        LED_L <= 4'd8;
    end
    else begin
        LED_L <= LED_L;
    end
endmodule

呼吸灯模块：

`timescale 1ns / 1ns
//
// Company: 
// Engineer: 
// 
// Create Date: 2021/08/24 13:39:06
// Design Name: 
// Module Name: breath_led
// Project Name: 
// Target Devices: 
// Tool Versions: 
// Description: 
// 
// Dependencies: 
// 
// Revision:
// Revision 0.01 - File Created
// Additional Comments:
// 
//

module breath_led#(
    parameter  CNT_1US_MAX = 7'd99,
    parameter  CNT_1MS_MAX = 10'd999,
    parameter  CNT_1S_MAX  = 10'd999
)
(
    input wire    sys_clk,
    input wire    sys_rst_n,

    output reg   led_out
);

reg  [9:0]   cnt_1s;
reg  [9:0]   cnt_1ms;
reg  [6:0]   cnt_1us;
reg          cnt_en; 


always @(posedge sys_clk or negedge sys_rst_n) begin
    if (sys_rst_n == 1'b0) begin
        cnt_1us <= 7'd0;     
    end
    else if (cnt_1us == CNT_1US_MAX) begin
        cnt_1us <= 7'd0;
    end
    else begin
        cnt_1us <= cnt_1us + 7'd1;
    end
end

always @(posedge sys_clk or negedge sys_rst_n) begin
    if (sys_rst_n == 1'b0) begin
        cnt_1ms <= 10'd0;        
    end
    else if ((cnt_1ms == CNT_1MS_MAX) && (cnt_1us == CNT_1US_MAX)) begin
        cnt_1ms <= 10'd0;
    end
    else if (cnt_1us == CNT_1US_MAX) begin
        cnt_1ms <= cnt_1ms + 10'd1;
    end
    else begin
        cnt_1ms <= cnt_1ms;
    end
end

always @(posedge sys_clk or negedge sys_rst_n) begin
    if (sys_rst_n == 1'b0) begin
        cnt_1s <= 10'd0;
    end
    else if ((cnt_1s == CNT_1S_MAX) && (cnt_1ms == CNT_1MS_MAX) && (cnt_1us == CNT_1US_MAX)) begin
        cnt_1s <= 10'd0;
    end
    else if ((cnt_1ms == CNT_1MS_MAX) && (cnt_1us == CNT_1US_MAX)) begin
        cnt_1s <= cnt_1s + 10'd1;
    end
    else begin
        cnt_1s <= cnt_1s;
    end
end

always @(posedge sys_clk or negedge sys_rst_n) begin
    if (sys_rst_n == 1'b0) begin
        cnt_en <= 1'b0;
    end
    else if ((cnt_1s == CNT_1S_MAX) && (cnt_1ms == CNT_1MS_MAX) && (cnt_1us == CNT_1US_MAX)) begin
        cnt_en <= ~cnt_en;
    end
    else begin
        cnt_en <= cnt_en;
    end
end

always @(posedge sys_clk or negedge sys_rst_n) begin
    if (sys_rst_n == 1'b0) begin
        led_out <= 1'b0;
    end
    else if (((cnt_en == 1'b0) && (cnt_1ms <= cnt_1s)) || ((cnt_en == 1'b1) && (cnt_1ms >= cnt_1s))) begin
        led_out <= 1'b1;
    end
    else begin
        led_out <= 1'b0;
    end 
end
endmodule

UART_RX模块：

`timescale 1ns / 1ns
//
// Company: 
// Engineer: 
// 
// Create Date: 2021/09/03 12:36:32
// Design Name: 
// Module Name: uart_rx
// Project Name: 
// Target Devices: 
// Tool Versions: 
// Description: 
// 
// Dependencies: 
// 
// Revision:
// Revision 0.01 - File Created
// Additional Comments:
// 
//


module uart_rx
#(
    parameter       UART_BPS       =   'd9600,
    parameter       CLK_FREQ         =   'd100_000_000
)
(
    input   wire                sys_clk     ,
    input   wire                rst_n       ,
    input   wire                rx          ,

    output  reg       [7:0]     Po_data     ,
    output  reg                 Po_flag
);

parameter  BAUD_CNT_MAX     =       CLK_FREQ/UART_BPS;

reg             rx_reg1;        // 同步到系统时钟下
reg             rx_reg2;     
reg             rx_reg3;        // 打两拍，减小亚稳态危�
reg             Start_flag;     // å¼?å§‹ä¸€ä¸ªæ•°æ®å¸§çš„ä¼ è¾“æ ‡å¿—ä¿¡å?
reg             Work_en;        // æ ‡è¯†æ•°æ®é‡‡é›†èŒƒå›´ï¼ŒæŽ¥æ”¶æ•°æ®å·¥ä½œä½¿èƒ½ä¿¡å?
reg     [15:0]  baud_cnt;       // 计数1ç å…ƒæ‰?éœ?要的时钟周期æ•?(在本实验中，1ç å…ƒ=1bit)
reg             Bit_flag;       // 每bit数据稳定点拉高一� 
reg     [3:0]   Bit_cnt;        // bit计数�
reg     [7:0]   rx_data;
reg             rx_flag;


always @(posedge sys_clk or negedge rst_n) begin
    if (rst_n == 1'b0) begin
        // reset
        rx_reg1 <= 1'b1;
        rx_reg2 <= 1'b1;
        rx_reg3 <= 1'b1;
    end
    else begin
        rx_reg1 <= rx;
        rx_reg2 <= rx_reg1;
        rx_reg3 <= rx_reg2;
    end
end




always @(posedge sys_clk or negedge rst_n) begin
    if (rst_n == 1'b0) begin
        Start_flag <= 1'b0;
    end
    else if ((rx_reg3 == 1'b1) && (rx_reg2 == 1'b0) && (Work_en == 1'b0)) begin
        Start_flag <= 1'b1;
    end
    else begin
        Start_flag <= 1'b0;
    end
end


always @(posedge sys_clk or negedge rst_n) begin
    if (rst_n == 1'b0) begin
        Work_en <= 1'b0;
    end
    else if (Start_flag == 1'b1) begin
        Work_en <= 1'b1;
    end
    else if ((Bit_cnt == 4'd8) && (Bit_flag == 1'b1)) begin
        Work_en <= 1'b0;
    end
    else begin
        Work_en <=  Work_en;
    end
end

always @(posedge sys_clk or negedge rst_n) begin
    if (rst_n == 1'b0) begin
        baud_cnt <=  16'd0;
    end
    else if ((baud_cnt == BAUD_CNT_MAX - 1) || (~Work_en)) begin
        baud_cnt <= 16'd0;
    end
    else begin
        baud_cnt <= baud_cnt + 1'b1;
    end
end

always @(posedge sys_clk or negedge rst_n) begin
    if (rst_n == 1'b0) begin
        Bit_flag <=  1'b0;
    end
    else if (baud_cnt == BAUD_CNT_MAX / 2 - 1) begin
        Bit_flag <= 1'b1;
    end
    else begin
        Bit_flag<= 1'b0;
    end
end

always @(posedge sys_clk or negedge rst_n) begin
    if (rst_n == 1'b0) begin
        Bit_cnt <=  1'b0;
    end
    else if ((Bit_flag) && (Bit_cnt == 4'd8)) begin
        Bit_cnt <=  1'b0;
    end
    else if (Bit_flag) begin
        Bit_cnt <= Bit_cnt + 1'b1;
    end
    else begin
        Bit_cnt <=  Bit_cnt;
    end
end

always @(posedge sys_clk or negedge rst_n) begin
    if (rst_n == 1'b0) begin
        rx_data <=  8'd0;
    end
    else if (((Bit_cnt >= 4'd1) && (Bit_cnt <= 4'd8)) && (Bit_flag == 1'b1))begin
        rx_data <= {rx_reg3,rx_data[7:1]};
    end
    else begin
        rx_data <= rx_data;
    end
end

always @(posedge sys_clk or negedge rst_n) begin
    if (rst_n == 1'b0) begin
        rx_flag <=  1'b0;
    end
    else if ((Bit_cnt == 4'd8) && (Bit_flag == 1'b1)) begin
        rx_flag <= 1'b1;
    end
    else
        rx_flag <= 1'b0;
end

always @(posedge sys_clk or negedge rst_n) begin
    if (rst_n == 1'b0) begin
        Po_data <=  8'd0;
    end
    else if (rx_flag == 1'b1) begin
        Po_data <= rx_data;
    end
    else begin
        Po_data <= Po_data;
    end
end


always @(posedge sys_clk or negedge rst_n) begin
    if (rst_n == 1'b0) begin
        Po_flag <=  1'd0;
    end
    else begin
        Po_flag <=  rx_flag;
    end
end



endmodule

UART_TX模块 ：

//
// Company: 
// Engineer: 
// 
// Create Date: 2021/09/04 19:36:40
// Design Name: 
// Module Name: uart_tx
// Project Name: 
// Target Devices: 
// Tool Versions: 
// Description: 
// 
// Dependencies: 
// 
// Revision:
// Revision 0.01 - File Created
// Additional Comments:
// 
//


module uart_tx
#(
    parameter       UART_BPS         =   'd9600,
    parameter       CLK_FREQ         =   'd100_000_000
)
(
    input  wire          sys_clk         ,
    input  wire          rst_n           ,
    input  wire  [7:0]   Pi_data         ,
    input  wire          Pi_flag         ,

    output reg           tx,
    output reg           Work_en
);


parameter  BAUD_CNT_MAX     =       CLK_FREQ/UART_BPS;

reg    [15:0]   baud_cnt    ;
reg    [3:0]    Bit_cnt    ;
reg             Bit_flag     ;





always @(posedge sys_clk or negedge rst_n)begin
    if (rst_n == 1'b0) begin
        Work_en <= 1'b0;
    end
    else if (Pi_flag == 1'b1) begin
        Work_en <= 1'b1;
    end
    else if ((Bit_cnt == 4'd9) && (Bit_flag == 1'b1)) begin
        Work_en <= 1'b0;
    end
    else begin
        Work_en <= Work_en;
    end
end


always @(posedge sys_clk or negedge rst_n)begin
    if (rst_n == 1'b0) begin
        baud_cnt <= 16'd0;
    end
    else if ((baud_cnt == BAUD_CNT_MAX - 1'b1)  || (~Work_en)) begin
        baud_cnt <= 16'd0;
    end
    else begin
        baud_cnt <= baud_cnt + 1'b1;
    end
end


always @(posedge sys_clk or negedge rst_n)begin
    if (rst_n == 1'b0) begin
        Bit_flag <= 1'b0;
    end
    else if (baud_cnt == (BAUD_CNT_MAX - 1'b1)) begin
        Bit_flag <= 1'b1;
    end
    else begin
        Bit_flag <= 1'b0;
    end
end

always @(posedge sys_clk or negedge rst_n)begin
    if (rst_n == 1'b0) begin
        Bit_cnt <= 1'b0;
    end
    else if ((Bit_cnt == 4'd9) && (Bit_flag == 1'b1)) begin
        Bit_cnt <= 4'd0;
    end
    else if ((Bit_flag == 1'b1) && (Work_en == 1'b1)) begin
        Bit_cnt <= Bit_cnt + 1'b1;
    end
    else begin
        Bit_cnt <= Bit_cnt;
    end
end


always @(posedge sys_clk or negedge rst_n)begin
    if (rst_n == 1'b0) begin
        tx  <= 1'b1;
    end
    else if (Work_en == 1'b1) begin
        case(Bit_cnt)
            0   : tx <= 1'b0;
            1   : tx <= Pi_data[0];
            2   : tx <= Pi_data[1];
            3   : tx <= Pi_data[2];
            4   : tx <= Pi_data[3];
            5   : tx <= Pi_data[4];
            6   : tx <= Pi_data[5];
            7   : tx <= Pi_data[6];
            8   : tx <= Pi_data[7];
            9   : tx <= 1'b1;
            default:tx<=1'b1;
        endcase
    end
end

endmodule

LED_CTRL模块 ：

//
// Company: 
// Engineer: 
// 
// Create Date: 2021/09/05 21:27:03
// Design Name: 
// Module Name: led_ctrl
// Project Name: 
// Target Devices: 
// Tool Versions: 
// Description: 
// 
// Dependencies: 
// 
// Revision:
// Revision 0.01 - File Created
// Additional Comments:
// 
//


module led_ctrl(
    input   wire            sys_clk     ,
    input   wire            rst_n       ,
    input   wire            key_flag_w  ,
    input   wire            key_flag_b  ,
    input   wire    [7:0]   pi_data     ,
    input   wire    [3:0]   led_out_w   ,
    input   wire            led_out_b   ,

    output  reg     [3:0]   led         ,
    output  wire    [7:0]   po_data     ,
    output  wire            po_flag
);


reg         w_en    ;
reg         b_en    ;


always @(posedge sys_clk or negedge rst_n)
    if (~rst_n) begin
        w_en <= 1'b0;
    end
    else if (key_flag_b == 1'b1) begin
        w_en <= 1'b0;
    end
    else if (key_flag_w == 1'b1) begin
        w_en  <= ~w_en;
    end
    else begin
        w_en <= w_en;
    end

always @(posedge sys_clk or negedge rst_n)
    if (~rst_n) begin
        b_en <= 1'b0;
    end
    else if (key_flag_w == 1'b1) begin
        b_en <= 1'b0;
    end
    else if (key_flag_b == 1'b1) begin
        b_en  <= ~b_en;
    end
    else begin
        b_en <= b_en;
    end

always @(posedge sys_clk or negedge rst_n)
    if (~rst_n) begin
        led <= 4'b0000;
    end
    else if (pi_data[0] == 1'b1) begin
        led <= led_out_w;
    end
    else if (pi_data[1] == 1'b1) begin
        led <= {led_out_b,led_out_b,led_out_b,led_out_b};
    end
    else begin
        led <= 4'b0000;
    end


assign po_data = {6'b000_000,b_en,w_en};

assign po_flag = {key_flag_w || key_flag_b};



endmodule

RS485总控模块

`timescale 1ns / 1ns
//
// Company: 
// Engineer: 
// 
// Create Date: 2021/09/05 21:52:41
// Design Name: 
// Module Name: rs485
// Project Name: 
// Target Devices: 
// Tool Versions: 
// Description: 
// 
// Dependencies: 
// 
// Revision:
// Revision 0.01 - File Created
// Additional Comments:
// 
//


module rs485(
    input   wire            sys_clk     ,
    input   wire            rst_n       ,
    input   wire            key_in_w    ,
    input   wire            key_in_b    ,
    input   wire            rx          ,


    output  wire            tx          ,
    output  wire    [3:0]   led         ,
    output  wire            re
);

parameter   KEY_CNT_MAX = 20'd999_999;
parameter   WATER_LED_CNT_MAX = 25'd24999999;
parameter   B_CNT_1US_MAX = 7'd99,
            B_CNT_1MS_MAX = 10'd999,
            B_CNT_1S_MAX  = 10'd999;

parameter   UART_BPS = 9600        ,
            CLK_FREQ = 100_000_000 ;

wire           w_flag      ;
wire           b_flag      ;
wire  [3:0]    w_led       ;
wire           b_led       ;
wire  [7:0]    rx_data     ;
wire  [7:0]    po_data     ;
wire           po_flag     ;



key_filter#(
    .CNT_MAX(KEY_CNT_MAX)
)key_filter_inst_w
(
    .sys_clk (sys_clk),
    .rst_n   (rst_n),
    .key_in  (key_in_w),

    .key_flag(w_flag)
);

key_filter#(
    .CNT_MAX(KEY_CNT_MAX)
)key_filter_inst_b
(
    .sys_clk (sys_clk),
    .rst_n   (rst_n),
    .key_in  (key_in_b),

    .key_flag(b_flag)
);

water_led
#(
    .M(WATER_LED_CNT_MAX)
)water_led_inst
(
    .clk (sys_clk),
    .rst_n(rst_n),

    .LED_L(w_led)
);


breath_led#(
    .CNT_1US_MAX(B_CNT_1US_MAX),
    .CNT_1MS_MAX(B_CNT_1MS_MAX),
    .CNT_1S_MAX (B_CNT_1S_MAX )
)breath_led_inst
(
    .sys_clk(sys_clk),
    .sys_rst_n(rst_n),

    .led_out(b_led)
);




uart_tx
#(
    .UART_BPS (UART_BPS),
    .CLK_FREQ (CLK_FREQ)
)uart_tx_inst
(
    .sys_clk(sys_clk),
    .rst_n  (rst_n),
    .Pi_data(po_data),
    .Pi_flag(po_flag),

    .tx     (tx),
    .Work_en(re)
);

uart_rx
#(
    .UART_BPS (UART_BPS),
    .CLK_FREQ (CLK_FREQ)
)uart_rx_inst
(
    .sys_clk(sys_clk),
    .rst_n  (rst_n),
    .rx     (rx),

    .Po_data(rx_data),
    .Po_flag()
);

led_ctrl led_ctrl_inst(
    .sys_clk     (sys_clk),
    .rst_n       (rst_n),
    .key_flag_w  (w_flag),
    .key_flag_b  (b_flag),
    .pi_data     (rx_data),
    .led_out_w   (w_led),
    .led_out_b   (b_led),

    .led         (led),
    .po_data     (po_data),
    .po_flag     (po_flag)
);


endmodule

三、下板实验

请添加图片描述
请添加图片描述
请添加图片描述
请添加图片描述

七十二骑士
关注
  • 1
    点赞
  • 踩
  • 2
    收藏
    觉得还不错? 一键收藏
  • 0
    评论
专栏目录
终于讲透了，史上最详细的RS485串口通讯！
嵌入式Linux
01-09 16万+
RS485接口组成的半双工网络，一般是两线制，多采用屏蔽双绞线传输，这种接线方式为总线式拓扑结构在同一总线上最多可以挂接32个结点。我们知道，最初数据是模拟信号输出简单过程量，后来仪表接...
串口/RS232/RS485 简解
白云苍狗
03-12 3365
串口通讯，RS232，RS485的区别，原理简介。
兆易创新+串口RS485通信
最新发布
m0_61973119的博客
12-14 807
485（一般称作 RS485/EIA-485）是隶属于 OSI 模型物理层的电气特性规定为 2 线，半双工，多点通信的标准。它的电气特性和 RS-232 大不一样。用缆线两端的电压差值来表示传递信号。。RS485 的特点包括：1） 接口电平低，。RS485 的电气特性：逻辑“1”以两线间的电压差为+(2~6)V表示；逻辑“0”以两线间的电压差为-(2~6)V 表示。接口信号电平比 RS232 降低了，不易损坏接口电路的芯片，且该电平与 TTL 电平兼容，可方便与 TTL 电路连接。2）。
嵌入式知识点总结——串口、RS232、RS485
weixin_46461874的博客
09-06 629
串口通信是指外设和计算机间，通过数据信号线 、地线、控制线等，按位进行传输数据的一种通讯方式。这种通信方式使用的数据线少，在远距离通信中可以节约通信成本，但其传输速度比并行传输低。
如何实现RS232/485串口转CANbus总线以及介绍使用说明
weixin_45754480的博客
10-21 6203
智能CAN/串口协议转换器LCNET Pro RS-232/485提供一路RS-485、一路RS-232和一路CAN通道，实现CAN与串口RS-485或RS-232之间的双向数据智能转换。每个通道独立隔离，每路通道采用金升阳电源模块和信号隔离芯片实现2500VDC电气隔离，电源输入防反设计，支持DC6.5~36V输入；具有优秀的EMC性能，可靠性测试项目：ESD接触放电8KV、浪涌±1KV、脉冲群...
15-STM32F10X系列 串口RS485记录 .docx
12-23
常见的串行通信标准有RS232和RS485。RS232接口存在电平过高、传输速率低、抗干扰能力弱和传输距离短等问题。而RS485则解决了这些问题，它的接口电平与TTL兼容，适合与集成电路直接连接，支持较高的数据速率（如100...
串口RS485调试助手vb源代码
07-19
串口，又称串行接口，是一种逐位传输数据的通信方式，通常包括RS-232、RS-422和RS-485等标准。其中，RS-485标准因其支持多点通信、长距离传输以及较高的抗干扰性，在许多工业环境中被优先选用。 RS-485协议允许在一...
USART_HAL库的_串口RS485_stm32cubemx485_
09-29
在本文中，我们将深入探讨...总的来说，使用STM32CubeMX和HAL库配置RS485串口，可以简化开发流程，使得开发者能够专注于应用程序的逻辑。通过理解USART的配置和操作，以及HAL库提供的函数，可以高效地实现RS485通信。
33-串口RS485.pptx
07-26
技术文档分享，免费获取请私信博主。
CC2530Zigbee无线串口RS485固件.zip
12-16
在本固件中，CC2530被用来实现Zigbee无线通信，并通过串行通信接口与RS485进行数据交互，提供了一种高效、可靠的远距离无线传输解决方案。 Zigbee是一种基于IEEE 802.15.4标准的低功耗、近距离、低成本的无线通信...
关于工业级RS485串口服务器的组网方式详解
fctel的博客
11-17 3016
工业级串口服务器提供串口转网络功能，是实现串口（TTL串口或RS232/RS485/RS422）数据与TCP/IP协议数据相互转换实现数据通过网络传输的工业互联通讯设备。通过连接多个串口设备并将串口数据流进行选择和处理，将串口数据转换为以太网数据，将串行数据通过网络进行传输，解决了改造方案中不带以太网模块的设备需要更换的问题，从而提高现有设备的利用率， 节约成本简化布线。接下来我们就来为大家详细介绍下工业级RS485串口服务器的组网方式，一起来看看吧！ 串口服务器对各种数据进行处理，将TCP/IP协议的以
串口通讯接口类型：TTL、RS232和RS485（电平标准）
shouchen1的博客
07-28 1万+
这是一帧，我们常见的帧格式：一共有10位，它的第一位时起始位，都是以低电平开始，中间的8个是数据位，数据位的内容由用户定义的，正好是一个字节，通过中间这8个数据位不同的排列组合就能代表256种不同的信息，第10位是停止位，都是以高电平结束。RS232只是改变了电平大小，传输的还是原来的串口的那些0或者1的数据，而且RS232也是全双工通讯，还是我们最开始那一帧串口数据，以下为转换成232之后的样子，它最大的好处就是抗干扰能力增强了，因为它的高低电平相差了近20V。其中TTL,即晶体管-晶体管逻辑电平。
详解RS232、RS485、RS422、串口 &握手！
ken2232的博客
09-23 5736
详解RS232、RS485、RS422、串口 &握手！
电气完整性
csdnqiang的博客
10-15 2575
电气完整性（Electrical Integrity，简称EI）包括信号完整性（Signal Integrity，简称SI）、电源完整性（Power Integrity，简称PI）和电磁完整性（Electromagnetic Integrity，EMI）。 信号完整性与信号完整性问题： 信号完整性就是信号从发送端发出，经过传输路径到达接收端后仍能保持可分辩的完整或相对完整的信号现象。 经过的传输路径有可能是传输线、电阻、电容、电感等。例如：发送芯片产生1GHZ的方波信号经过传输路径传输后，接收芯片仍能通过判
UART和RS232、RS485的基础知识
chunlovenan的专栏
04-15 2万+
UART和RS232、RS485的关系：   通讯问题，和交通是一样的。串口通信，我们这里可以用公交来类比。         公交运行可以简单分成两个部分：        1、车站        2、公路        其中车站决定了车上装什么（人），怎么发送（班次）等。        当汽车跑在路上，就要遵守公路交通的规则，过桥有过桥的规则，高速有高速的规则，和车站没有关系
串口服务器如何设置485信号,串口服务器485 设置
weixin_33428129的博客
08-10 2026
串口服务器485 设置 内容精选换一换有以下几种现象：将制作好的SD卡插入开发者板并上电后，开发者板LED1与LED2灯状态信息异常。将制作好的SD卡插入开发者板，并通过USB方式连接Ubuntu服务器，上电、开发者板启动完成后，Ubuntu服务器无虚拟网卡信息。将制作好的SD卡插入开发者板，并通过NIC方式连接Ubuntu服务器，上电、开发者板启动完成，配置Ubuntu服务有以下几种现象：将制作...
串口、COM口、UART口, TTL、RS-232、RS-485区别详解
热门推荐
wb790238030的博客
10-29 7万+
调试时总是会遇到各种各样的接口，各种各样的转换板，似懂非懂的感觉很不爽！ 首先，串口、UART口、COM口、USB口是指的物理接口形式(硬件)。而TTL、RS-232、RS-485是指的电平标准(电信号)。 串口：串口是一个泛称，UART、TTL、RS232、RS485都遵循类似的通信时序协议，因此都被通称为串口。 UART接口：通用异步收发器（Universal Asynchronous ...
串口、COM口、TTL、RS232、RS485区别详解
Freelings
03-11 1万+
原贴地址：http://xilinx.eetrend.com/article/10712   1、串口、COM口是指的物理接口形式(硬件)。而TTL、RS-232、RS-485是指的电平标准(电信号)。 2、接设备的时候，一般只接GND RX TX。不会接Vcc或者+3.3v的电源线，避免与目标设备上的供电冲突。 3、PL2303、CP2102芯片都是常用的USB转TTL串口的芯片，用US...
stm32串口rs485输出字符串
05-20
下面是使用STM32的HAL库，通过串口RS485输出字符串的代码示例： 1. 首先需要在CubeMX中配置串口和RS485控制脚的GPIO引脚。 2. 在代码中添加头文件和全局变量： ```c #include "stm32f4xx_hal.h" #include UART_...

“相关推荐”对你有帮助么？

  • 非常没帮助
  • 没帮助
  • 一般
  • 有帮助
  • 非常有帮助
提交
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值