随机贪心算法简介(搜出一个自己高中的时候写的程序)

高三的时候准备信息学奥赛，到处做编程题。。

 

当时自己为AC了这道题得意了好一阵子…… 是TOJ上的一道题目，

其解题思路涉及到 随机贪心。。

 

什么是随机贪心？这里用我自己的话给个简单的介绍吧。

贪心算法就是根据问题的本质，给出一个最优解导向，然后不断的去迭代进而求出最优解。

而在很多时候，未必能准确的找到这个最优解导向（或者根本不存在，比如NP问题），但却可以找到一个近似的导向算法（近似贪心算法）。那么我们也可以在迭代若干次之后得到一个最优解的近似解。

假如我们打乱整个系统的初始状态为其等效状态，然后再进行上述迭代，又可以求到一个近似解。

如果我们能穷举出所有的等效初始状态，然后从所有的近似解里取最优解，那么就可以得到整个问题的最优解了。

而在实际情况中，可能无法枚举所有情况（复杂度太高），那么我们可以不断的随机去模拟初始状态，然后从该状态求近似解。

然后我们多次随机取其中的最佳值。这样，我们随机次数越高，结果就越准确。

我们把这种算法叫做随机贪心算法。

 

发上来纪念一下，这段青涩的代码，哈哈

记得当初我还写了个小解题报告，存在 yeah.net的邮箱里。。今天去看，居然因为我长期不登陆把我的删掉了。。可恶

 

{$N+}
program tju1033;
const
	limit=18;
var
	Ham:array[0..limit+1] of integer;
	n,i,u:integer;
	min:double;
	cost:array[1..limit,1..limit] of double;
	x,y:array[1..limit] of double;

procedure init;
var
	i,j:integer;
begin
	readln(n);
	for i:=1 to n do readln(x[i],y[i]);
	for i:=1 to n do
	for j:=1 to n do
		cost[i,j]:=sqrt(sqr(x[i]-x[j])+sqr(y[i]-y[j]));
	for i:=0 to n+1 do Ham[i]:=i;
end;

procedure Hamilton_Change;
var
	finish:boolean;
	i,j,k,tmp:integer;
begin
	finish:=false;
	Ham[0]:=Ham[1];
	Ham[n+1]:=Ham[n];
	while not finish do
	begin
		finish:=true;
		for i:=1 to n do
		for j:=i+1 to n do
			if cost[ Ham[i-1],Ham[i] ]+cost[ Ham[j],Ham[j+1] ]
			> cost[ Ham[i-1],Ham[j] ]+cost[ Ham[i],Ham[j+1] ] then
		begin
			for k:=0 to (j-i) div 2 do
			begin
				tmp:=Ham[i+k];
				Ham[i+k]:=Ham[j-k];
				Ham[j-k]:=tmp;
			end;
			finish:=false;
			Ham[0]:=Ham[1];
			Ham[n+1]:=Ham[n];
		end;
	end;
end;

procedure Count_Ans;
var
	total:double;
	i:integer;
begin
	total:=0;
	for i:=1 to n-1 do
	total:=total+cost[ Ham[i],Ham[i+1] ];
	if total<min then min:=total;
end;

procedure Random_adjust;
var
	i,a,b,tmp:integer;
begin
	for i:=1 to 1000 do
	begin
		a:=random(n+1);
		b:=random(n+1);
		if (a<>b) and (a<>0) and (b<>0) then
		begin
			tmp:=Ham[a];
			Ham[a]:=Ham[b];
			Ham[b]:=tmp;
		end;
	end;
end;

begin
	randomize;
	while not eof do
	begin
		init;
		min:=maxint;
		Hamilton_Change;
		Count_Ans;
		for i:=1 to 500 do
		begin
			Random_adjust;
			Hamilton_Change;
			Count_Ans;
		end;
		writeln(min:0:2);
	end;
end.