第七章 基础纹理

纹理最初的目的是用一张图片来控制模型外观。使用纹理映射技术，把图片黏在模型表面，逐纹素控制模型颜色。

把纹理映射坐标存储在每个顶点，纹理坐标通常称UV坐标。

Unity中原点位于纹理左下角。

单张纹理

实践

Shader "Unity Shaders Book/Chapter 7/Single Texture"{
	Properties{
		_Color		("Color Tint", Color) = (1, 1, 1, 1)
		//声明纹理
		_MainTex	("Main Tex", 2D) = "white"{}
		//_Specular用于控制高光反射颜色，_Gloss用于控制高光区域的大小
		_Specular	("Specular", Color) = (1, 1, 1, 1)
		_Gloss		("Gloss", Range(8.0, 256)) = 20
	}

	SubShader{
		Pass{
			Tags{"LightMode"="ForwardBase"}

			CGPROGRAM

			#pragma vertex vert;
			#pragma fragment frag;
			#include "Lighting.cginc"

			fixed4 _Color;
			//需要为纹理类型声明一个float4类型的变量_MainTex_ST
			//在Unity中，我们需要使用纹理名_ST的方式来声明某个纹理的属性
			//_MainTex_ST可以让我们得到该纹理的缩放和平移值
			//_MainTex_ST.xy存储的是缩放值，_MainTex_ST.zw存储的是偏移值
			sampler2D _MainTex; float4 _MainTex_ST;
			fixed4 _Specular;
			float _Gloss;

			struct a2v{
				float4 vertex : POSITION;
				float3 normal : NORMAL;
				//将模型的第一组纹理存到该变量中
				float4 texcoord : TEXCOORD0;
			};

			struct v2f{
				float4 pos : SV_POSITION;
				float3 worldNormal : TEXCOORD0;
				float3 worldPos : TEXCOORD1;
				//用于存储纹理坐标的UV，便于片元着色器使用该坐标纹理采样
				float2 uv : TEXCOORD2;
			};

			//顶点着色器计算包括高光反射的模型
			v2f vert(a2v v){
				v2f o;
				o.pos = UnityObjectToClipPos(v.vertex);
				o.worldNormal = UnityObjectToWorldNormal(v.normal);
				o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
				//先使用缩放属性_MainTex_ST.xy对顶点纹理坐标进行缩放
				//再使用偏移属性_MainTex_ST.zw对结果进行偏移
				o.uv = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;
				//Unity 内置
				//o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
				return o;
			}

			fixed4 frag(v2f i) : SV_Target{
				fixed3 worldNormal = normalize(i.worldNormal);
				fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));

				//对纹理进行采样，第一个参数是被采样的纹理，第二个是纹理坐标，返回纹素值
				//使用采样结果和颜色属性的乘积来作为材质的反射率
				fixed3 albedo = tex2D(_MainTex, i.uv).rgb * _Color.rgb;

				//与环境光相乘得到环境光部分
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;
				
				fixed3 diffuse = _LightColor0.rgb * albedo * max(0, dot(worldNormal, worldLightDir));

				fixed3 viewDir = normalize(UnityWorldSpaceViewDir(i.worldPos));
				fixed3 halfDir = normalize(worldLightDir + viewDir);
				fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0, dot(worldNormal, halfDir)), _Gloss);
				fixed3 ccolor = ambient + diffuse + specular;
				return fixed4(ccolor, 1.0);
			}
			ENDCG
		}
	}
	FallBack "Specular"
}

纹理的属性

Warp Mode有两种属性：决定了纹理坐标超过[0,1]如何平铺

（1）一种是Repeat，这种模式下，如果纹理坐标超过1，那么它的整数部分会被舍弃，而直接使用小数部分采样，结果是纹理会不断重复。

（2）一种是clamp，超过范围的部分会截取到边界值，形成一个条形结构。

Filter Mode属性决定了当纹理由于变换而产生拉伸时将会采用哪种滤波。支持三种模式：P、B、T。得到的图片滤波效果依次提升，耗费性能也增大。纹理滤波会影响放大或缩小纹理时得到的图片质量。

纹理缩小过程比放大更复杂，多个像素将会对应一个目标像素。我们要处理抗锯齿问题，使用多级渐远技术。多级渐远技术是将原纹理提取使用滤波处理来得到很多更小的图像，形成一个金字塔，每一层都是上一层图像降采样的结果，可以快速得到结果像素，但会多占用33%的内存空间。勾选Generate Mip Maps即可开启。

凹凸映射