shader入门精要读书笔记40 素描风格的渲染

总结下头文件：

HLSLSupport.cginc - (自动包含) 为跨平台的着色器编译宏和定义提供帮助。
UnityShaderVariables.cginc - (自动包含)常用的全局变量。
UnityCG.cginc - 常用的辅助函数
AutoLight.cginc - 照明&阴影功能,如表面着色器在内部使用这个文件
Light.cginc - 标准表面着色器照明模式，当你写surface shaders时自动包含。
TerrainEngine.cginc - 对地形和植被着色器的辅助函数

一、思路：

素描效果，我们需要根据不同光照的漫发射，选择不同的纹理混合

二、实现：

代码：

Shader "Unity Shaders Book/Chapter 14/Hatching" {
	Properties {
		_Color ("Color Tint", Color) = (1, 1, 1, 1)
		_TileFactor ("Tile Factor", Float) = 1			//纹理的平铺系数，越大，素描线越密
		_Outline ("Outline", Range(0, 1)) = 0.1			控制轮廓线宽度
		_OutlineColor ("Outline Color", Color) = (0, 0, 0, 1)			//轮廓线颜色
		_Hatch0 ("Hatch 0", 2D) = "white" {}
		_Hatch1 ("Hatch 1", 2D) = "white" {}
		_Hatch2 ("Hatch 2", 2D) = "white" {}
		_Hatch3 ("Hatch 3", 2D) = "white" {}
		_Hatch4 ("Hatch 4", 2D) = "white" {}
		_Hatch5 ("Hatch 5", 2D) = "white" {}		//6张素描纹理，密度依次增大
	}
	
	SubShader {
		Tags { "RenderType"="Opaque" "Queue"="Geometry"}		//不透明的几何体
		
		UsePass "Unity Shaders Book/Chapter 14/Toon Shading/OUTLINE"			//使用之前的轮廓线渲染，
		
		Pass {
			Tags { "LightMode"="ForwardBase" }		//前向渲染
			
			CGPROGRAM
			
			#pragma vertex vert
			#pragma fragment frag 
			
			#pragma multi_compile_fwdbase
			
			#include "UnityCG.cginc"
			#include "Lighting.cginc"
			#include "AutoLight.cginc"
			#include "UnityShaderVariables.cginc"
			
			fixed4 _Color;
			float _TileFactor;
			sampler2D _Hatch0;
			sampler2D _Hatch1;
			sampler2D _Hatch2;
			sampler2D _Hatch3;
			sampler2D _Hatch4;
			sampler2D _Hatch5;
			
			struct a2v {
				float4 vertex : POSITION;
				float4 tangent : TANGENT; 
				float3 normal : NORMAL; 
				float2 texcoord : TEXCOORD0; 
			};
			
			struct v2f {
				float4 pos : SV_POSITION;
				float2 uv : TEXCOORD0;
				fixed3 hatchWeights0 : TEXCOORD1;		//定义两个fixed3，共6个数，存储6个混合权重(共6个纹理)
				fixed3 hatchWeights1 : TEXCOORD2;
				float3 worldPos : TEXCOORD3;
				SHADOW_COORDS(4)
			};
			
			v2f vert(a2v v) {
				v2f o;
				
				o.pos = UnityObjectToClipPos(v.vertex);
				
				o.uv = v.texcoord.xy * _TileFactor;			//纹理采样坐标
				
				fixed3 worldLightDir = normalize(WorldSpaceLightDir(v.vertex));
				fixed3 worldNormal = UnityObjectToWorldNormal(v.normal);
				fixed diff = max(0, dot(worldLightDir, worldNormal));		//得到漫反射系数
				
				o.hatchWeights0 = fixed3(0, 0, 0);			//权重初始化为0
				o.hatchWeights1 = fixed3(0, 0, 0);
					
				float hatchFactor = diff * 7.0;		//把diff范围弄到[0,7]
				
				if (hatchFactor > 6.0) {				//根据大小分别分配权重
					// Pure white, do nothing		//漫发射很大，以至于用白色
				} else if (hatchFactor > 5.0) {
					o.hatchWeights0.x = hatchFactor - 5.0;				//大于5的分配给第一个图的权重
				} else if (hatchFactor > 4.0) {
					o.hatchWeights0.x = hatchFactor - 4.0;				//大于四将多余4的部分分配给第一个图
					o.hatchWeights0.y = 1.0 - o.hatchWeights0.x;		//剩余的部分权重给相邻，也就是第二个图。
				} else if (hatchFactor > 3.0) {
					o.hatchWeights0.y = hatchFactor - 3.0;			//同上
					o.hatchWeights0.z = 1.0 - o.hatchWeights0.y;
				} else if (hatchFactor > 2.0) {
					o.hatchWeights0.z = hatchFactor - 2.0;
					o.hatchWeights1.x = 1.0 - o.hatchWeights0.z;
				} else if (hatchFactor > 1.0) {
					o.hatchWeights1.x = hatchFactor - 1.0;
					o.hatchWeights1.y = 1.0 - o.hatchWeights1.x;
				} else {
					o.hatchWeights1.y = hatchFactor;
					o.hatchWeights1.z = 1.0 - o.hatchWeights1.y;
				}
				
				o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;		//得到世界空间顶点坐标
				
				TRANSFER_SHADOW(o);		//阴影衰减计算等等
				
				return o; 
			}
			
			fixed4 frag(v2f i) : SV_Target {			
				fixed4 hatchTex0 = tex2D(_Hatch0, i.uv) * i.hatchWeights0.x;
				fixed4 hatchTex1 = tex2D(_Hatch1, i.uv) * i.hatchWeights0.y;
				fixed4 hatchTex2 = tex2D(_Hatch2, i.uv) * i.hatchWeights0.z;
				fixed4 hatchTex3 = tex2D(_Hatch3, i.uv) * i.hatchWeights1.x;
				fixed4 hatchTex4 = tex2D(_Hatch4, i.uv) * i.hatchWeights1.y;
				fixed4 hatchTex5 = tex2D(_Hatch5, i.uv) * i.hatchWeights1.z;
				fixed4 whiteColor = fixed4(1, 1, 1, 1) * (1 - i.hatchWeights0.x - i.hatchWeights0.y - i.hatchWeights0.z - 
							i.hatchWeights1.x - i.hatchWeights1.y - i.hatchWeights1.z);
				//进行权重计算，最后计算纯白色，把所有的剪掉就是留白部分

				fixed4 hatchColor = hatchTex0 + hatchTex1 + hatchTex2 + hatchTex3 + hatchTex4 + hatchTex5 + whiteColor;
				//相加混合
				
				UNITY_LIGHT_ATTENUATION(atten, i, i.worldPos);
				//阴影衰减计算
								
				return fixed4(hatchColor.rgb * _Color.rgb * atten, 1.0);
			}
			
			ENDCG
		}
	}
	FallBack "Diffuse"
}