Verilog 文件操作-$fgetc，$fgets，$fscanf，$fread

最新推荐文章于 2024-07-22 09:00:00 发布
最新推荐文章于 2024-07-22 09:00:00 发布
阅读量1w 收藏 139
点赞数 22
文章标签： fpga verilog 仿真器
原文链接：https://ica123.com/archives/16157
版权

原文网站： Verilog 文件操作-$fgetc，$fgets，$fscanf，$fread – 芯片天地

在Verilog 仿真中， 我们有时需要将文件中的数据，读入到仿真工程中使用。在Verilog 语法中提供$fgetc，$fgets，$fscanf，$fread 等系统函数，帮助开发者将文件中的数据读出，供仿真程序使用。

$fgetc 使用

reg [7:0] <8-bit_reg>;
<8-bit_reg> = $fgetc(<file_desc>);

file_desc：为打开的文件句柄

从文件中读取一个字符， 每执行一次$fgetc，就从文件中读取一个字符， 文件的指针自动加一。 当读取到文件结束时， $fgetc 返回 -1， 可以通过-1(EOF) 来定位文件读取结束。

举例，从一个文本文件中读取数据(test.txt)

test.txt文本文件的内容如下：

1234
world
hello
This is a test file.

仿真工程如下（vivado）：

`timescale 1ns / 1ps
module sim_top(

    );
reg stop_flag = 0;

localparam FILE_TXT = "../../../test.txt";
//localparam FILE_TXT = "../../../test.bin";
integer fd;
integer i;
reg [7:0]   c;
initial begin
    i = 0;
    fd = $fopen(FILE_TXT, "r");
    if(fd == 0)
    begin
        $display("$open file failed") ;
        $stop;
    end
    $display("\n ============= file opened... ============= ") ;

    c = $fgetc(fd);
    i = i + 1;
    
    while ($signed(c) != -1)
    begin
        $write("%c", c) ;
        #10;
        c = $fgetc(fd);
        i = i + 1;
    end
    
    #10;
    $fclose(fd) ;
    $display("\n ============= file closed... ============= ") ;
    
    #100;
    $stop;
end

使用$fopen 打开文本文件，使用”r” 参数。 注意这里定义的是reg [7:0] c；因此使用 while ($signed(c) != -1) 来进行比较 ，而不能使用while (c!= -1)  。 因为 8’hff  != -1

即255 !=  -1  这个条件是永远成立的，所以不能判断出文件读取结束。$write 的使用和 $display 系统函数类似， 只是$write 没有额外增加换行操作。

仿真结果如下：

举例，从一个二进制文件中读取数据(test.bin)

在读取二进制文件中， 使用$fgetc 系统函数 得到的结果 可以是 8’h00 — 8’hff 当中的任何一个数值。$fgetc 的返回值是8bit的。 因此在读取二进制正常的读取过程中， 就会出现8’hff 这个值，如果使用 while ($signed(c) != -1) , 就会在读出正常数据8’hff 时，认为文件读取已经结束，但实际上文件读取并没有结束。所以为了避免这种情况的发生，这里提供一种方法来解决，之后的文章还有其他方法可以使用。

reg[15:0] c ;

将c 定义为16 bit （只要大于8bit 既可），这样平时读取的数据只能是c = 16’h00xx ，永远不会出现 16’hffff这种情况， 只有读取文件结束时， 才能读到16’hffff这样的值。这样就可以判断出文件结束了。

当定义 reg [7:0] c; 的仿真程序：

`timescale 1ns / 1ps
module sim_top(

    );

//localparam FILE_TXT = "../../../test.txt";
localparam FILE_TXT = "../../../test.bin";
integer fd;
integer i;
reg [7:0]   c;
initial begin
    i = 0;
    fd = $fopen(FILE_TXT, "rb");
    if(fd == 0)
    begin
        $display("$open file failed") ;
        $stop;
    end
    $display("\n ============= file opened... ============= ") ;

    c = $fgetc(fd);
    i = i + 1;
    
    while ($signed(c) != -1)
    begin
        $write("%c", c) ;
        #10;
        c = $fgetc(fd);
        i = i + 1;
    end
    
    #10;
    $fclose(fd) ;
    $display("\n ============= file closed... ============= ") ;
    stop_flag = 1;
    #100;
    $stop;
end
    
endmodule

使用 fd = $fopen(FILE_TXT, “rb“); 打开二进制文件 test.bin。

仿真结果如下：

在读取二进制文件，读到349 个是就结束了。原因就是读取到8’hff 时，认为文件已经结束了， 所以整个程序就退出了。

控制台输出结果如下：

修改仿真文件， 将reg [7:0] c;  修改为reg [15:0] c;

仿真结果如下：

我们会发现，平时读取的数据都是16’h00xx， 只有结束时， $fgetc 的结果为16’hffff。 相同的test.bin 文件，在读到690 个数值时， 才真正结束了。

控制台输出结果如下：

$fgets 使用

integer <integer>;
reg [8*<#_of_chars>:0] <string_reg>;
<integer> = $fgets(<string_reg>, <file_desc>);

integer：
    定一个整型数值， 用来保存读取文件的当前行数有多少个字节。 如果读出的字节为0， 
    表示文件读取结束或者读取错误。（注，文本文件中空行也是能读到一个字节的）。
string_reg: 定义字符串变量，用来保存从文件中读取的数据。
file_desc：为打开的文件句柄

从文件中每次读取一行的数据， 并且将当前行有多少个数据当作$fgets 的返回值，如果返回值为0， 表示文件读取结束或者读取错误。$fgets 主要针对文本文件使用， 对于读取二进制文件，也是可以操作的，但是不能表示明确的行的含义。

定义一个文本文件：

1234
abc
k
world
hello

This is a test file.

仿真文件如下：

`timescale 1ns / 1ps
module sim_top(

    );
reg stop_flag = 0;

localparam FILE_TXT = "../../../test.txt";
//localparam FILE_TXT = "../../../test.bin";
integer fd;
integer char_num;
integer i;
reg [8*32-1:0]   fbuf = 0;
//reg [7:0] fbuf[31:0];
initial begin
    i = 0;
    char_num = 0;
    fd = $fopen(FILE_TXT, "r");
    if(fd == 0)
    begin
        $display("$open file failed") ;
        $stop;
    end
    $display("\n ============= file opened... ============= ") ;

    char_num = $fgets(fbuf,fd);
    i = i + 1;
    
    while (char_num != 0)
    begin
        $write("%s", fbuf) ;
        #10;
        char_num = $fgets(fbuf,fd);
        i = i + 1;
    end
    
    #10;
    $fclose(fd) ;
    $display("\n ============= file closed... ============= ") ;
    stop_flag = 1;

    #100;
    $stop;
end
    

    
endmodule

仿真结果如下：

相同的仿真文件在quartus 下仿真:

从仿真结果来看，在仿真文件中使用reg [8*32-1:0] fbuf = 0; 我们这里定义了fbuf 是 32个字节，比文本文件中的每一行长度都大。所以在一次$fgets 可以完整读取一行文本数据，这里我们看到， 只需要7次就可以将文件完整读出。这里我们可以看出， fbuf 在vivado中没有显示，在quartus 下显示了正常的数据。 但在vivado中将fbuf的内容一个一个的打印输出， 发现结果依然是正确的。（这里使用的是vivado 2018.2）

当我们定义reg [15:0] fbuf = 0; 时，每次$fgets 最多只能读取两个字节，所以需要很多次$fgets 才能将这个文本文件读取结束。

仿真结果如下：

这里，我们发现需要$fgets 读取25次，才能将文本文件读取结束。

$fscanf 使用

integer <integer>;
<integer> = $fscanf(<file_desc>, "<format>", <destination_regs>);

integer：
    定义一个整型数值，正常读取为1，出错时为0，文件读取结束为 -1。
file_desc：为打开的文件句柄
format: 格式化输出，具体可以参照$display 中的格式化参数。表示以什么样的格式读取文件
destination_regs: 读取文件数据后， 保存在这个目标寄存器中。

按照格式将文件中的数据读到变量中， 格式可以参考$display 中的格式化内容。如果遇到空格或者换行，表示一次读取结束。 读取时，如果发生错误 则返回值为0，正常读取数据时为1， 读取文件结束时为-1。

text.txt 文件内容：

1234
abc
k
world
hello

This is a test file.

`timescale 1ns / 1ps
module sim_top(

    );
reg stop_flag = 0;

localparam FILE_TXT = "../../../test.txt";
//localparam FILE_TXT = "../../../test.bin";
integer fd;
integer char_num;
integer i;
reg [8*10-1:0]   fbuf = 0;
//reg [31:0] fbuf = 0;
initial begin
    i = 0;
    char_num = 0;
    fd = $fopen(FILE_TXT, "r");
    if(fd == 0)
    begin
        $display("$open file failed") ;
        $stop;
    end
    $display("\n ============= file opened... ============= ") ;

    char_num = $fscanf(fd,"%s",fbuf);
//    char_num = $fscanf(fd,"%c",fbuf);
    i = i + 1;
    
    while ($signed(char_num) != -1)
    begin
        $display("%s", fbuf) ;
        #10;
        char_num = $fscanf(fd,"%s",fbuf);
//        char_num = $fscanf(fd,"%c",fbuf);
        i = i + 1;
    end
    
    #10;
    $fclose(fd) ;
    $display("\n ============= file closed... ============= ") ;
    stop_flag = 1;
    #100;
    $stop;
end
    

initial
begin
    stop_flag = 0;
    #10;

    while(char_num != 0) #10;
    stop_flag = 1;

    #100;
    $stop;
end

endmodule

仿真文件中打开文本文件，$fscanf 以字符串方式读取文件的内容，遇到换车，换行，表示一次$fscanf 操作结束。

仿真结果如下：

遇到文本文件中的回车，换行 都表示一次$fscanf 操作结束。 因此， 打印结果会分为很多行打印输出。

$fread 使用

integer <integer>;
<integer> = $fread(<store>，<file_desc>); 
<integer> = $fread(<store>，<file_desc>, <start> ); 
<integer> = $fread(<store>，<file_desc>, <start>, <count> ); 
<integer> = $fread(<store>，<file_desc>, , <count> ); 
integer：整型数值，返回本次$fread 读取的真实字节数量，当返回值为0 ，表示错误读取或者文件结束。
store：将二进制文件中的数据读取到寄存器或者二维数组中。
file_desc：为打开的文件句柄
start: 为二维数组的起始地址
count: 从起始地址开始， 写入二维数组的数量。

举例：

integer code;
reg [7:0] mem [4:0];
integer fd;

initial
begin
    fd = $fopen("test.bin", "rb");
    code = $fread(mem, fd);
    code = $fread(mem, fd,1);
    code = $fread(mem, fd);
    code = $fread(mem, fd);
end

使用code = $fread(mem, fd); 表示从二进制文件中读取数据，一次存放到mem[0]，mem[1]，mem[2]，mem[3]。

使用code = $fread(mem, fd, 1); 表示从二进制文件中读取数据，一次存放到mem[1]，mem[2]，mem[3]。

使用code = $fread(mem, fd, 1, 2); 表示从二进制文件中读取数据，一次存放到mem[1]，mem[2]。

使用code = $fread(mem, fd,  , 3); 表示从二进制文件中读取数据，一次存放到mem[0]，mem[1]，mem[2]。

仿真文件：

`timescale 1ns / 1ps
module sim_top(

    );
reg stop_flag = 0;

//localparam FILE_TXT = "../../../test.txt";
localparam FILE_TXT = "../../../test.bin";
integer fd;
integer char_num;
integer i;
//reg [8*10-1:0]   fbuf = 0;
reg [7:0]   fbuf [3:0];
//reg [31:0] fbuf = 0;
initial begin
    i = 0;
    char_num = 0;
    fd = $fopen(FILE_TXT, "rb");
    if(fd == 0)
    begin
        $display("$open file failed") ;
        $stop;
    end
    $display("\n ============= file opened... ============= ") ;

    char_num = $fread(fbuf, fd, 0, 4); //读取二进制文件中的数据，存放到fbuf[0],fbuf[1],fbuf[2],fbuf[3]
//    char_num = $fread(fbuf, fd,1, 2); //读取二进制文件中的数据，存放到fbuf[1],fbuf[2]
    #10;
    $display("$fread[%03d]: %h%h%h%h", i,fbuf[3],fbuf[2],fbuf[1],fbuf[0]) ;//十六进制显示
    i = i + 1;
    
    while ($signed(char_num) != 0)
    begin
        char_num = $fread(fbuf, fd, 0, 4); //读取二进制文件中的数据，存放到fbuf[0],fbuf[1],fbuf[2],fbuf[3]
//        char_num = $fread(fbuf, fd,1,2); //读取二进制文件中的数据，存放到fbuf[1],fbuf[2]
        #10;
        $display("$fread[%03d]: %h%h%h%h", i,fbuf[3],fbuf[2],fbuf[1],fbuf[0]) ;//十六进制显示
        i = i + 1;
    end
    
    #10;
    $fclose(fd) ;
    $display("\n ============= file closed... ============= ") ;
    stop_flag = 1;
    #100;
    $stop;
end

endmodule

仿真文件结果：

每次从二进制文件中读取4个字节，但最后一次只能读出两个字节了，然后文件就结束了。

这里，我们可以看出，使用$fread 一次能从二进制文件中读出多少数据， 完全取决于fbuf 定义的大小，如果fbuf定义为reg [7:0]fbuf，那么是从二进制文件中读取一个字节了。

FPGA RISC-V 学习
关注
（1）D触发器verilog描述
kouq123的博客
11-18 6985
2.1 D触发器verilog描述 2.1.1 本节目录 第一，本节目录； 第二，本节引言； 第三，FPGA简介； 第四，verilog简介； 第五，D触发器verilog描述实例； 第六，结束语。 2.1.2 本节引言 给FPGA一个支点，它可以撬动整个数字逻辑。““给我一根杠杆我就能撬动地球”是古希腊数学家、物理学家阿基米德说的，这句话是阿基米德的经典语录，这句话还被翻译为“给我一个支点，我就能撬起整个地球”，用了夸张的方式来说明杠杆原理。” 2.1.3 FPGA简介 FPGA（F
verilog从txt中读取_Verilog中的文件操作
weixin_39980929的博客
12-19 2313
1.文件打开和关闭:首先定义integer指针，然后调用$fopen(file_name,mode)任务，不需要文件时，调用$fopen(file_name)常用mode包括“w"打开文件并从文件头开始写，如果不存在就创建文件。“w+"打开文件并从文件头开始读写，如果不存在就创建文件"a"打开文件并从文件末尾开始写，如果不存在就创建文件“a+"打开文件并从文件末尾开始读写，如果不存在就创建文件2....
verilog $fscanf相关讲解
热门推荐
weizhl10131729的博客
11-16 2万+
三类： 1.文件打开和关闭:首先定义integer指针，然后调用$fopen(file_name,mode)任务，不需要文件时，调用$fopen(file_name) 常用mode包括 “w"打开文件并从文件头开始写，如果不存在就创建文件。 “w+"打开文件并从文件头开始读写，如果不存在就创建文件 "a"打开文件并从文件末尾开始写，如果不存在就创建文件 “a+"
c++操作文件(ifstream&ofstream&fstream)
xppbin的博客
12-07 589
1、fstream提供了三个类，用来实现c++对文件的操作。（文件的创建、读、写）。 ifstream -- 从已有的文件读入 ofstream -- 向文件写内容 fstream - 可同时读写操作的文件类 ①文件打开(Open a file) 思路：要通过一个流对象打开一个文件，我们通过查阅c++api文档发现，使用它的成员函数open()： ios::nocreate 打开一个文件时，如果文件不存在，不创建文件 io...
高效学习，Verilog文件操作要点速览
最新发布
dpwkj的博客
07-22 691
在FPGA开发中，Verilog文件操作是一项不可或缺的技能。它不仅涉及到基本的文件读写，还涉及到复杂的数据存储和处理。本文将详细介绍Verilog文件操作的各个方面，并提供代码示例，帮助读者从入门到精通。
verilog测试函数语法大全
Lynnlc2020的博客
07-06 1092
erilog 测试波形的生成 值序列 线性产生值序列 eg： 循环产生值序列 eg:每隔50时间单位输出一次随机的256以内的数字，同时循环256次，循环结束之后延迟200时间单位结束 数组产生值序列 eg：首先需要实现数组列表数据的初始化，然后将数组列表中存储的数据对外输出 文件导入产生值序列 时钟的建立 timescale时间尺度 ‘timescale 1ns/10ps (时间单位，...
【SystemVerilog】$fscanf
小邦是名小ICer的博客
02-18 2618
SV 文件内容读取
关于fgets()函数的使用方法
qq_62096086的博客
03-18 1万+
在读取字符串时，scanf()和转换说明符%s只能读取一个单词。gets()函数简单易用，它读取整行输入，直至遇到换行符，然后丢弃换行符，存储其余字符，并在这些字符的末尾添加一个空字符使其成为一个C字符串。但是出现一个问题，gets()函数无法检测数组是否装得下输入行。于是，在2011年，C11标准委员会在标准中废除了gets()函数。 gets()函数的替代品 fgets() fgets()函数的第2个参数指明了读入字符的最大数量。如果该参数的值是n，那么fgets()将读入n-1个字符，或者读到遇到的第
VERILOG | fscanf
zhqy0204的博客
02-22 1056
fscanf is similar between Verilog and C++ VERILOG integer code ; code = $fscanf ( fd, format, args ); 参考Verilog mannual：ieee-standard-for-verilog-hardware-description-language.pdf C++ http:/...
verilog 读写文件
02-21
这些函数包括 $fread、$fgets、$fscanf 等。这些函数可以用来读取文件中的数据，并将其存储在 Verilog 中的变量中。 2. 文件输出函数：在 Verilog 中，文件输出函数用于将数据写入文件中。这些函数包括 $fwrite、$...
第一章:1.2.8.6 Verilog系统函数
linpeng_9527的博客
03-28 1966
Verilog HDL语言中共有以下一些系统函数和任务： $bitstoreal, $rtoi,$display,$setup,$finish,$skew,$hold,$setuphold, $itor,$strobe,$period,$time,$printtimescale,$timeformat,$realtime, $width,$realtobits,$write,$recovery. ...
fgets函数用法
03-20
详细描述了fgets函数的用法，该函数可读取文件中的字符串，可供C/CPP开发人员参考。
readmemh函数引用的txt格式_用于读取和写入文本文件Verilog代码
weixin_26869081的博客
12-24 1275
系统函数＄fopen用于打开一个文件，并还回一个整数指针．然后，＄fdisplay就可以使用这个文件指针在文件中写入信息，写完后，则可以使用＄fclose系统关闭这个文件例如：integer write_out_file;／／定义一个文件指针integer write_out_file=$fopen("write_out_file.txt");$fdisplay(write_out_file,"@...
verilog文件系统函数调用
莽野孤狼的博客
03-01 1万+
1 $open Integermulti_channel_descriptor= $fopen ( "file_name" ); 返回文件的多通道描述符，只允许写数据，最多能打开31个文件，最高位保留。 注意：用$fopen打开文件会将原来的文件清空，若要读数据就用$readmemb,$readmemh就可以了，这个语句不会清空原来文件中的数据。integerfd = $fopen (
常用的verilog系统函数 $feof， fscanf，$fopen，$readmemb，$readmemh，$fdisplay，$display，$fclose，函数的使用
笨蛋大乌龟的博客
03-19 9135
转载：https://blog.csdn.net/winson_cys/article/details/100175964?depth_1-utm_source=distribute.pc_relevant.none-task&utm_source=distribute.pc_relevant.none-task Verilog编写testbench时，系统函数比较常用的一般为displ...
fgets函数的使用
weixin_46733914的博客
07-29 1万+
fgets函数的函数原型：char *fgets(char * ch,int mode,FILE *fp); 第一个参数ch是一个字符数组； 第二个参数mode表示这个数组需要读取多少个字符； 第三个参数fp表示一个文件指针; fgets函数可以在读取(mode-1)个字符后就结束，或读取到换行符后结束，再或者读到文件结尾后结束; 例子:char ch[10]; int mode=10;(假设fp已经分配好了) fgets(ch,10,fp); 这个函数表示从fp这个文件指针中读取10个字符 第一种情况：当
fgets()用法笔记
weixin_34049032的博客
08-14 1181
为了避免缓冲区溢出，从终端读取输入时应当用fgets()代替gets()函数。但是这也将带来一个问题，因为fgets()的调用格式是： fgets (buf, MAX, fp)fgets (buf, MAX, stdin) buf是一个char数组的名称，MAX是字符串的最大长度，fp是FILE指针。fgets()函数读取到它所遇到的第一个换行符的后面，或者读取比字符串的最大长...
Verilog 中的fscanf函数的使用
winson_cys的博客
08-31 2万+
Verilog编写testbench时，系统函数比较常用的一般为display、display、display、fopen、fclose、fclose、fclose、fwrite、$fmonitor。但是关于对于读取文件中的数据所采用的fread、fscanf、fgets使用频率相对较少。今天由于需要读取文件中的2进制数据，并且没次只读取文件中的一行，并将数据作为输出。经过好几个小时的折腾，决定写...
verilog tb $fscanf函数是什么意思
05-20
`$fscanf` 是 Verilog 语言中的一个系统任务，用于从文件中读取格式化数据并将其存储到变量中。 具体来说，`$fscanf` 可以从指定的文件中读取数据，并将数据按照指定的格式解析后存储到指定的变量中。它的用法如下： ```verilog $fscanf(file, format, arg1, arg2, ...) ``` 其中，`file` 是文件句柄，用于指定要读取的文件；`format` 是解析数据的格式字符串，用于指定要读取的数据类型和格式；`arg1`、`arg2` 等参数是存储读取数据的变量。 举个例子，假设我们有一个文件 `input.txt`，其中包含以下数据： ``` 10 20 30 ``` 我们可以使用 `$fscanf` 从文件中读取这些数据，并存储到三个变量中： ```verilog module test; reg [31:0] a, b, c; integer file; initial begin file = $fopen("input.txt", "r"); $fscanf(file, "%d %d %d", a, b, c); $fclose(file); $display("a=%d, b=%d, c=%d", a, b, c); end endmodule ``` 这样，当我们运行这个 Verilog 模块时，就会从文件中读取数据并打印出来： ``` a=10, b=20, c=30 ```
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值