CMake | 关于版本号的那些事儿

目录

一、CMake版本号相关变量

举个栗子

二、在CMakeLists.txt中定义版本号

1.源码

（1）CMakeLists.txt

（2）version.h.in文件

（3）C++源码

（4）CMake配置，生成version.h

三、CMake读取配置文件获取版本号

1.相关命令

（1）file(READ <filename> <variable> )

（2）string(STRIP <string> <output_variable>)

2.源码

（1）配置文件VERSION

（2）version.h.in

（3）CMakeLists.txt

3.CMake配置，生成version.h文件

---

一、CMake版本号相关变量

        在CMakeLists.txt文件project命令中可以添加版本号：

project(recipe-04 VERSION 2.0.1 LANGUAGES C)

• CMAKE_PROJECT_VERSION 等变量会保存顶级CMakeLists.txt中通过project命令添加的版本号。
• PROJECT_VERSION、PROJECT_VERSION_MAJOR、PROJECT_VERSION_MINOR及PROJECT_VERSION_PATCH变量会保存最近的project命令里添加的版本号。

举个栗子

最顶层CMakeLists.txt：

cmake_minimum_required(VERSION 3.5 FATAL_ERROR)

project(First VERSION 1.2.3 LANGUAGES CXX)

project(Second VERSION 4.5.6  LANGUAGES CXX)

add_subdirectory(sub)

project(Second VERSION 7.8.9  LANGUAGES CXX)

同目录文件夹sub下的CMakeLists.txt文件：

project(SubProj VERSION 1.0.0)

message("CMAKE_PROJECT_VERSION = ${CMAKE_PROJECT_VERSION}")#4.5.6

message("PROJECT_VERSION_MAJOR = ${PROJECT_VERSION_MAJOR}")#1

message("PROJECT_VERSION_MINOR = ${PROJECT_VERSION_MINOR}")#0

message("PROJECT_VERSION_PATCH = ${PROJECT_VERSION_PATCH}")#0

message("PROJECT_VERSION = ${PROJECT_VERSION}")#1.0.0

二、在CMakeLists.txt中定义版本号

        利用project命令及PROJECT_VERSION等变量，加上提前配置的xxx.h.in文件，使用configure_file命令可以生成带有版本号相关信息的变量，供C++源码使用。

1.源码

（1）CMakeLists.txt

# set minimum cmake version
cmake_minimum_required(VERSION 3.5 FATAL_ERROR)

#调用CMake的 project 时定义项目版本
project(recipe-04 VERSION 2.0.1 LANGUAGES C)

#基于 version.h.in 生成 version.h
configure_file(
  version.h.in
  generated/version.h
  @ONLY
  )

# example code
add_executable(example example.c)

# needs to find the generated header file
target_include_directories(example
  PRIVATE
    ${CMAKE_CURRENT_BINARY_DIR}/generated
  )

（2）version.h.in文件

#pragma once

#define PROJECT_VERSION_MAJOR @PROJECT_VERSION_MAJOR@
#define PROJECT_VERSION_MINOR @PROJECT_VERSION_MINOR@
#define PROJECT_VERSION_PATCH @PROJECT_VERSION_PATCH@

#define PROJECT_VERSION "v@PROJECT_VERSION@"

（3）C++源码

#include "version.h"

#include <stdio.h>

int main() {
  printf("This is output from code %s\n", PROJECT_VERSION);
  printf("Major version number: %i\n", PROJECT_VERSION_MAJOR);
  printf("Minor version number: %i\n", PROJECT_VERSION_MINOR);

  printf("Hello CMake world!\n");
}

（4）CMake配置，生成version.h

#pragma once

#define PROJECT_VERSION_MAJOR 2
#define PROJECT_VERSION_MINOR 0
#define PROJECT_VERSION_PATCH 1

#define PROJECT_VERSION "v2.0.1"

三、CMake读取配置文件获取版本号

        使用file命令读取配置文件信息获取版本号，配合使用提前配置的xxx.h.in文件，通过configure_file命令来生成xxx.h文件。

1.相关命令

（1）file(READ <filename> <variable>)

file(READ <filename> <variable>
     [OFFSET <offset>] [LIMIT <max-in>] [HEX])

• 从名为<filename>的文件中读取内容，并将其存储在<variable>中。
• 可选地从给定的<offset>开始，最多读取<max-in>字节。
• HEX选项会将数据转换为十六进制表示（对二进制数据有用）。如果指定了十六进制选项，则输出中的字母（a到f）为小写。

if(EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/VERSION")
  file(READ "${CMAKE_CURRENT_SOURCE_DIR}/VERSION" PROGRAM_VERSION)
else()
  message(FATAL_ERROR "File ${CMAKE_CURRENT_SOURCE_DIR}/VERSION not found")
endif()

（2）string(STRIP <string> <output_variable>)

string(STRIP <string> <output_variable>)

在<output_variable>中存储给定<string>的子字符串，去掉前导和尾随空格。

string(STRIP "${PROGRAM_VERSION}" PROGRAM_VERSION)

2.源码

（1）配置文件VERSION

2.0.1-rc-2

（2）version.h.in

#pragma once

#include <string>

const std::string PROGRAM_VERSION = "@PROGRAM_VERSION@";

（3）CMakeLists.txt

# set minimum cmake version
cmake_minimum_required(VERSION 3.5 FATAL_ERROR)

# project name and language
project(recipe-05 LANGUAGES CXX)

# require C++11
set(CMAKE_CXX_STANDARD 11)
set(CMAKE_CXX_EXTENSIONS OFF)
set(CMAKE_CXX_STANDARD_REQUIRED ON)

#从文件中读取版本信息,将内容读入 PROGRAM_VERSION 变量中，该变量会去掉尾部的空格。当设置了变量 PROGRAM_VERSION ，就可以使用它来配置 version.hpp.in ，生成 generated/version.hpp 
if(EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/VERSION")
  file(READ "${CMAKE_CURRENT_SOURCE_DIR}/VERSION" PROGRAM_VERSION)
  string(STRIP "${PROGRAM_VERSION}" PROGRAM_VERSION)
else()
  message(FATAL_ERROR "File ${CMAKE_CURRENT_SOURCE_DIR}/VERSION not found")
endif()

# generate file version.hpp based on version.hpp.in
configure_file(
  version.hpp.in
  generated/version.hpp
  @ONLY
  )

# example code
add_executable(example example.cpp)

# needs to find the generated header file
target_include_directories(example
  PRIVATE
    ${CMAKE_CURRENT_BINARY_DIR}/generated
  )

3.CMake配置，生成version.h文件

#pragma once

#include <string>

const std::string PROGRAM_VERSION = "2.0.1-rc-2";