Neo4J 示例Cypher的语法

1. 首先，我们删除数据库中以往的图，确保一个空白的环境进行操作：

MATCH (n) DETACH DELETE n

MATCH是匹配操作，而小括号()代表一个节点node（可理解为括号类似一个圆形），括号里面的n为标识符。

2.创建一个人物节点：

CREATE (n:Person {name:'John'}) RETURN n

CREATE是创建操作，Person是标签，代表节点的类型。花括号{}代表节点的属性，属性类似Python的字典。这条语句的含义就是创建一个标签为Person的节点，该节点具有一个name属性，属性值是John。

在Neo4J的界面上可以看到创建成功的节点：

3. 继续来创建更多的人物节点，并分别命名：

CREATE (n:Person {name:'Sally'}) RETURN n;
CREATE (n:Person {name:'Steve'}) RETURN n;
CREATE (n:Person {name:'Mike'}) RETURN n;
CREATE (n:Person {name:'Liz'}) RETURN n;
CREATE (n:Person {name:'Shawn'}) RETURN n;

查看当前图：

MATCH (n) RETURN n LIMIT 25

![在这里插入图片描述](https://img-blog.csdnimg.cn/8a3a978daea44994a45bab3e47ca69f7.png

4. 接下来创建地区节点：

CREATE (n:Location {city:'Miami', state:'FL'});
CREATE (n:Location {city:'Boston', state:'MA'});
CREATE (n:Location {city:'Lynn', state:'MA'});
CREATE (n:Location {city:'Portland', state:'ME'});
CREATE (n:Location {city:'San Francisco', state:'CA'});

节点类型为Location，属性包括city和state。

目前共有6个人物节点、5个地区节点，Neo4J贴心地使用不用的颜色来表示不同类型的节点。

5. 接下来创建关系

MATCH (a:Person {name:'Liz'}), 
      (b:Person {name:'Mike'}) 
MERGE (a)-[:FRIENDS]->(b)

6. 关系也可以增加属性

MATCH (a:Person {name:'Shawn'}), 
      (b:Person {name:'Sally'}) 
MERGE (a)-[:FRIENDS {since:2001}]->(b)

在关系中，同样的使用花括号{}来增加关系的属性，也是类似Python的字典，这里给FRIENDS关系增加了since属性，属性值为2001，表示他们建立朋友关系的时间。

7. 接下来增加更多的关系

MATCH (a:Person {name:'Shawn'}), (b:Person {name:'John'}) MERGE (a)-[:FRIENDS {since:2012}]->(b);
MATCH (a:Person {name:'Mike'}), (b:Person {name:'Shawn'}) MERGE (a)-[:FRIENDS {since:2006}]->(b);
MATCH (a:Person {name:'Sally'}), (b:Person {name:'Steve'}) MERGE (a)-[:FRIENDS {since:2006}]->(b);
MATCH (a:Person {name:'Liz'}), (b:Person {name:'John'}) MERGE (a)-[:MARRIED {since:1998}]->(b)

人物关系图已建立好

建立不同类型节点之间的关系-人物和地点的关系

MATCH (a:Person {name:'John'}), (b:Location {city:'Boston'}) MERGE (a)-[:BORN_IN {year:1978}]->(b)

这里的关系是BORN_IN，表示出生地，同样有一个属性，表示出生年份。人物节点和地区节点之间，人物出生地关系已建立好。

9. 同样建立更多人的出生地

MATCH (a:Person {name:'Liz'}), (b:Location {city:'Boston'}) MERGE (a)-[:BORN_IN {year:1981}]->(b);
MATCH (a:Person {name:'Mike'}), (b:Location {city:'San Francisco'}) MERGE (a)-[:BORN_IN {year:1960}]->(b);
MATCH (a:Person {name:'Shawn'}), (b:Location {city:'Miami'}) MERGE (a)-[:BORN_IN {year:1960}]->(b);
MATCH (a:Person {name:'Steve'}), (b:Location {city:'Lynn'}) MERGE (a)-[:BORN_IN {year:1970}]->(b)

10. 至此，知识图谱的数据大致插入完毕，可以开始做查询了。我们查询下所有在Boston出生的人物

MATCH (a:Person)-[:BORN_IN]->(b:Location {city:'Boston'}) RETURN a,b

11. 查询所有对外有关系（箭头指出）的节点

MATCH (a)-->() RETURN a

注意这里箭头的方向，返回结果不含任何地区节点，因为地区并没有指向其他节点（只是被指向）

12. 查询所有对内有关系（箭头指向）的节点

MATCH (a)<--() RETURN a

13. 查询所有有关系的节点

MATCH (a)--() RETURN a

14. 查询所有对外有关系的节点，以及关系类型

MATCH (a)-[r]->() RETURN a.name, type(r)

╒════════╤═════════╕
│"a.name"│"type(r)"│
╞════════╪═════════╡
│"John"  │"BORN_IN"│
├────────┼─────────┤
│"Sally" │"FRIENDS"│
├────────┼─────────┤
│"Steve" │"BORN_IN"│
├────────┼─────────┤
│"Mike"  │"BORN_IN"│
├────────┼─────────┤
│"Mike"  │"FRIENDS"│
├────────┼─────────┤
│"Liz"   │"BORN_IN"│
├────────┼─────────┤
│"Liz"   │"MARRIED"│
├────────┼─────────┤
│"Liz"   │"FRIENDS"│
├────────┼─────────┤
│"Shawn" │"BORN_IN"│
├────────┼─────────┤
│"Shawn" │"FRIENDS"│
├────────┼─────────┤
│"Shawn" │"FRIENDS"│
└────────┴─────────┘

15. 查询所有有结婚关系的节点

MATCH (n)-[:MARRIED]-() RETURN n

16. 创建节点的时候就建好关系

CREATE (a:Person {name:'Todd'})-[r:FRIENDS]->(b:Person {name:'Carlos'})

17. 查找某人的朋友的朋友

MATCH (a:Person {name:'Mike'})-[r1:FRIENDS]-()-[r2:FRIENDS]-(friend_of_a_friend) RETURN friend_of_a_friend.name AS fofName

返回Mike的朋友的朋友：

从图上也可以看出，Mike的朋友是Shawn，Shawn的朋友是John和Sally

18. 增加/修改节点的属性

MATCH (a:Person {name:'Liz'}) SET a.age=34;
MATCH (a:Person {name:'Shawn'}) SET a.age=32;
MATCH (a:Person {name:'John'}) SET a.age=44;
MATCH (a:Person {name:'Mike'}) SET a.age=25;

19. 删除节点的属性

MATCH (a:Person {name:'Mike'}) SET a.test='test'

MATCH (a:Person {name:'Mike'}) REMOVE a.test

20. 删除节点

MATCH (a:Location {city:'Portland'}) DELETE a

21. 删除与某个节点有关系的节点

MATCH (a:Person {name:'Todd'})-[rel]-(b:Person) DELETE a,b,rel

删掉了与Todd 有关系的节点、Todd 节点、和它们之间的关系（抹掉一个人在这个世界上的所有痕迹？？？哈哈哈）