lambert与half lambert模型逐顶点和逐片元的漫反射光照

兰伯特模型

逐顶点光照

// Upgrade NOTE: replaced '_World2Object' with 'unity_WorldToObject'

Shader "Unity Shaders Book/Chapter 6/Diffuse Vertex-Level"
{
    Properties{
		_Diffuse("Diffuse",Color)=(1,1,1,1)
	}

	SubShader{
		pass{
			Tags{"LightMode"="ForwardBase"}//光照模式 用于得到unity的一些内置变量

			CGPROGRAM

			#pragma vertex vert
			#pragma fragment frag 
			#include "Lighting.cginc"

			fixed4 _Diffuse;//材质的漫反射属性

			struct a2v{
				float4 vertex:POSITION;
				float3 normal:NORMAL;
			};

			struct v2f{
				float4 pos:SV_POSITION;
				fixed3 color:COLOR;//为了将顶点着色器计算的光照信息给fragment
			};

			v2f vert(a2v v){
				v2f o;

				o.pos=UnityObjectToClipPos(v.vertex);

				//得到环境光
				fixed3 ambient=UNITY_LIGHTMODEL_AMBIENT.xyz;

				//将模型空间下的法线转化为世界坐标
				fixed3 worldnormal=normalize(mul(v.normal,(float3x3)unity_WorldToObject));

				//得到光源方向
				fixed3 worldLight=normalize(_WorldSpaceLightPos0.xyz);

				//计算反射光
				fixed3 diffuse=_LightColor0.rgb*_Diffuse.rgb*saturate(dot(worldnormal,worldLight));
				o.color=ambient+diffuse;
				
				return o;
			}

			fixed4 frag(v2f i):SV_Target{
				return fixed4(i.color,1.0);
			}

			ENDCG
		}
	}
}

逐片元光照：

// Upgrade NOTE: replaced '_World2Object' with 'unity_WorldToObject'

Shader "Unity Shaders Book/Chapter 6/Diffuse Pixel-Level"
{
    Properties{
		_Diffuse("Diffuse",Color)=(1,1,1,1)
	}

	SubShader{
		pass{
			Tags{"LightMode"="ForwardBase"}//光照模式 用于得到unity的一些内置变量

			CGPROGRAM

			#pragma vertex vert
			#pragma fragment frag 
			#include "Lighting.cginc"

			fixed4 _Diffuse;//材质的漫反射属性

			struct a2v{
				float4 vertex:POSITION;
				float3 normal:NORMAL;
			};

			struct v2f{
				float4 pos:SV_POSITION;
				fixed3 worldNormal:TEXCOORD0;
			};

			v2f vert(a2v v){
				v2f o;

				o.pos=UnityObjectToClipPos(v.vertex);

				o.worldNormal=mul(v.normal,(float3x3)unity_WorldToObject);

				
				
				return o;
			}

			fixed4 frag(v2f i):SV_Target{
				
				//得到环境光
				fixed3 ambient=UNITY_LIGHTMODEL_AMBIENT.xyz;

				
				fixed3 worldnormal=normalize(i.worldNormal);

				//得到光源方向
				fixed3 worldLight=normalize(_WorldSpaceLightPos0.xyz);

				//计算反射光
				fixed3 diffuse=_LightColor0.rgb*_Diffuse.rgb*saturate(dot(worldnormal,worldLight));
				fixed3 color=ambient+diffuse;

				return fixed4(color,1.0);
			}

			ENDCG
		}
	}
}

效果对比：左边为逐片元光照。右边为逐顶点光照。右边明暗交界处有较明显的锯齿

半兰伯特光照模型

兰伯特模型的一个问题就是背光面只有一种颜色，缺乏立体感。Half Lambert用于解决这个问题

半兰伯特模型公式：

与兰伯特模型的差别主要在于不同于将背光面光都设为0，它将背光的光也即负值也映射到[0，1]区间。避免了背光的颜色只有0这一种值。需要注意的是，half lambert模型没有任何物理依据，只是一个视觉加强技术。在逐片元着色器稍微改一下就可以得到这个模型的结果：

fixed3 diffuse=_LightColor0.rgb*_Diffuse.rgb*(dot(worldnormal,worldLight)*0.5+0.5);

lambert和half lambert背光面对比