Halcon 二维码识别QR

图片资料
链接：https://pan.baidu.com/s/1JSl0mIWW_IvRacywpp4hHg
提取码：93mf

二维码识别过程

1、创建二维码模型

create_data_code_2d_model

2、设置搜索参数

set_bar_code_param

3、搜索二维码并解码

find_data_code_2d
* 解码字符串DecodedDataStrings 

4、清除条形码模型 （清除内存）

clear_data_code_2d_model

代码

* 窗口设置
dev_update_off ()
dev_close_window ()

* 图片文件夹 以及文件名
ImageFiles := './micro_qr_img/micro_qr_board_'
ImageNum := 6

* 读取并显示第一张图片
read_image (Image, ImageFiles + '01')
dev_open_window_fit_image (Image, 0, 0, -1, -1, WindowHandle)
dev_display (Image)

* 设置字体与颜色
set_display_font (WindowHandle, 16, 'mono', 'true', 'false')
dev_set_line_width (3)
dev_set_color ('green')


* 1、创建二维码模型对象 需要设置 Micro QR Code为二维码类型
create_data_code_2d_model ('Micro QR Code', [], [], DataCodeHandle)


* 循环读取图片
for Index := 1 to ImageNum by 1
    * 读取图片
    read_image (Image, ImageFiles + Index$'.2d')
    
    * 2、识别二维码 SymbolXLDs 区域  DecodedDataStrings 识别结果
    find_data_code_2d (Image, SymbolXLDs, DataCodeHandle, [], [], ResultHandles, DecodedDataStrings)
    
    * 显示图片与二维码区域
    dev_display (Image)
    dev_display (SymbolXLDs)
    
    * 显示序号与识别结果
    disp_message (WindowHandle, 'Image ' + Index + ' of ' + ImageNum, 'window', 12, 12, 'black', 'true')
    disp_message (WindowHandle, DecodedDataStrings, 'window', 40, 12, 'black', 'true')

    * 识别失败
    if (|DecodedDataStrings| == 0)
        disp_message (WindowHandle, 'No data code found.\nPlease adjust the parameters.', 'window', 40, 12, 'red', 'true')
    endif

    * 识别一张后停顿
    if (Index < ImageNum)
        disp_continue_message (WindowHandle, 'black', 'true')
        stop ()
    endif
endfor