IC验证学习笔记（AHB-RAM）08addr、bsize都随机，主要做地址偏移操作

已于 2023-05-15 20:45:47 修改
阅读量831 收藏 13
点赞数 4
文章标签： 学习 笔记
于 2023-05-15 17:02:43 首次发布
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/weixin_46403587/article/details/130632187
版权
代码示例展示了在内存模型测试中，针对地址未对齐的随机化写操作，可能导致scoreboard中的数据被覆盖。为了解决这个问题，需要在scoreboard中进行地址对齐处理，确保每个写入的数据都能正确存储。代码中通过调整存储地址并处理数据偏移来实现这一目标。
摘要由CSDN通过智能技术生成

rkv_ahbram_haddr_word_unaligned_virt_seq:

 对addr和bsize都随机化操作

`ifndef RKV_AHBRAM_HADDR_WORD_UNALIGNED_VIRT_SEQ_SV
`define RKV_AHBRAM_HADDR_WORD_UNALIGNED_VIRT_SEQ_SV


class rkv_ahbram_haddr_word_unaligned_virt_seq extends rkv_ahbram_base_virtual_sequence;
  `uvm_object_utils(rkv_ahbram_haddr_word_unaligned_virt_seq)

  function new (string name = "rkv_ahbram_haddr_word_unaligned_virt_seq");
    super.new(name);
  endfunction

  virtual task body();
    bit [31:0] addr, data;
    burst_size_enum bsize;
    super.body();
    `uvm_info("body", "Entered...", UVM_LOW)
    for(int i=0; i<100; i++) begin
      std::randomize(bsize) with {bsize inside {BURST_SIZE_8BIT, BURST_SIZE_16BIT, BURST_SIZE_32BIT};};
      std::randomize(addr) with {addr inside {['h1000:'h1FFF]};
                                 bsize == BURST_SIZE_16BIT -> addr[0] == 0;//为了地址对齐
                                 bsize == BURST_SIZE_32BIT -> addr[1:0] == 0;
                                };
      std::randomize(wr_val) with {wr_val == (i << 24) + (i << 16) + (i << 8) + i;};//使每一个byte位都有数据
      data = wr_val;
      `uvm_do_with(single_write, {addr == local::addr; data == local::data; bsize == local::bsize;})
      `uvm_do_with(single_read, {addr == local::addr; bsize == local::bsize;})
    end
    `uvm_info("body", "Exiting...", UVM_LOW)
  endtask

endclass


`endif

monitor获取过来原始数据给scb；但是scoreboard没有做地址对齐，需要修改

问题在于：按之前的情况如果存入`h10=`hFFAABBCC;

                  之后如果在`h11中存入`h11=`hEE;

                  则输出保存的结果为`h10`=`hFFAAEECC;会被覆盖掉

所以要做地址操作，保证传输过来的数据都被保存在scoreboard中：

`ifndef RKV_AHBRAM_SCOREBOARD_SV
`define RKV_AHBRAM_SCOREBOARD_SV

class rkv_ahbram_scoreboard extends rkv_ahbram_subscriber;

  // events of scoreboard
  bit [31:0] mem [int unsigned];

  // typedef enum {CHECK_LOADCOUNTER} check_type_e;
  `uvm_component_utils(rkv_ahbram_scoreboard)

  function new (string name = "rkv_ahbram_scoreboard", uvm_component parent);
    super.new(name, parent);
  endfunction

  function void build_phase(uvm_phase phase);
    super.build_phase(phase);
  endfunction

  task run_phase(uvm_phase phase);
    super.run_phase(phase);
    do_data_check();
  endtask

  virtual function void write(lvc_ahb_transaction tr);
    if(is_addr_valid(tr.addr)) begin
      case(tr.xact_type)
        WRITE : store_data_with_hburst(tr);
        READ  : check_data_with_hburst(tr);
      endcase
    end
  endfunction

  task do_listen_events();
  endtask

  virtual task do_data_check();
  endtask

  function bit is_addr_valid(bit [31:0] addr);
    if(addr >= cfg.addr_start && addr <= cfg.addr_end)
      return 1;
  endfunction

  function void store_data_with_hburst(lvc_ahb_transaction tr);
    // TODO implementation in child class
    case(tr.burst_type)
      SINGLE: begin 
                store_data_with_hsize(tr, 0);
              end
      INCR  : begin `uvm_error("TYPEERR", "burst type not supported yet") end
      WRAP4 : begin `uvm_error("TYPEERR", "burst type not supported yet") end
      INCR4 : begin `uvm_error("TYPEERR", "burst type not supported yet") end
      WRAP8 : begin `uvm_error("TYPEERR", "burst type not supported yet") end
      INCR8 : begin `uvm_error("TYPEERR", "burst type not supported yet") end
      WRAP16: begin `uvm_error("TYPEERR", "burst type not supported yet") end
      INCR16: begin `uvm_error("TYPEERR", "burst type not supported yet") end
      default: begin `uvm_error("TYPEERR", "burst type not defined") end
    endcase
  endfunction

  function bit check_data_with_hburst(lvc_ahb_transaction tr);
    // TODO implementation in child class
    case(tr.burst_type)
      SINGLE: begin 
                check_data_with_hburst = (check_data_with_hsize(tr, 0));
              end
      INCR  : begin `uvm_error("TYPEERR", "burst type not supported yet") end
      WRAP4 : begin `uvm_error("TYPEERR", "burst type not supported yet") end
      INCR4 : begin `uvm_error("TYPEERR", "burst type not supported yet") end
      WRAP8 : begin `uvm_error("TYPEERR", "burst type not supported yet") end
      INCR8 : begin `uvm_error("TYPEERR", "burst type not supported yet") end
      WRAP16: begin `uvm_error("TYPEERR", "burst type not supported yet") end
      INCR16: begin `uvm_error("TYPEERR", "burst type not supported yet") end
      default: begin `uvm_error("TYPEERR", "burst type not defined") end
    endcase
    if(check_data_with_hburst)
      `uvm_info("DATACHK", $sformatf("ahbram[%0x] hburst[%s] is as expected", tr.addr, tr.burst_type), UVM_HIGH)
    else
      `uvm_error("DATACHK", $sformatf("ahbram[%0x] hburst[%s] is NOT as expected", tr.addr, tr.burst_type))
  endfunction

  function void store_data_with_hsize(lvc_ahb_transaction tr, int beat);
    case(tr.burst_size)//1：0位不管补0，地址最少相差4字节往里写，不会有覆盖现象
      BURST_SIZE_8BIT   : mem[{tr.addr[31:2],2'b00}] = extract_current_beat_mem_data(tr, beat);//mem接收到偏移处理后的mdata
      BURST_SIZE_16BIT  : mem[{tr.addr[31:2],2'b00}] = extract_current_beat_mem_data(tr, beat);
      BURST_SIZE_32BIT  : mem[{tr.addr[31:2],2'b00}] = extract_current_beat_mem_data(tr, beat);
      BURST_SIZE_64BIT  : begin `uvm_error("TYPEERR", "burst size not supported") end
      default : begin `uvm_error("TYPEERR", "burst size not supported") end
    endcase
  endfunction

  function bit check_data_with_hsize(lvc_ahb_transaction tr, int beat);
    bit[31:0] tdata = extract_valid_data(tr.data[beat], tr.addr, tr.burst_size);
    bit[31:0] mdata = extract_valid_data(mem[{tr.addr[31:2],2'b00}],  tr.addr, tr.burst_size);
    check_data_with_hsize = tdata == mdata ? 1 : 0;
    cfg.scb_check_count++;
    if(check_data_with_hsize)
      `uvm_info("DATACHK", $sformatf("ahbram[%0x] data expected 'h%0x = actual 'h%0x", tr.addr, mdata, tdata), UVM_HIGH)
    else begin
      cfg.scb_check_error++;
      `uvm_error("DATACHK", $sformatf("ahbram[%0x] data expected 'h%0x != actual 'h%0x", tr.addr, mdata, tdata))
    end
  endfunction

  function bit [31:0] extract_current_beat_mem_data(lvc_ahb_transaction tr, int beat);//数据进行偏移处理
    bit [31:0] mdata = mem[{tr.addr[31:2],2'b00}];
    bit [31:0] tdata = tr.data[beat];//存入data
    case(tr.burst_size)	//8BIT mdata如果addr为0存放在7：0位，addr为1存放在15：8位，addr为2存放在23：16位，addr为3存放在31：24位
      BURST_SIZE_8BIT   : mdata[(tr.addr[1:0]*8 + 7) -:  8] = tdata >> (8*tr.addr[1:0]);//不管tdata多少位只拾取低八位
	  //16BIT mdata如果addr[1]为0tdata存放在16:0位，addr[1]为1存放在31：17位
      BURST_SIZE_16BIT  : mdata[(tr.addr[1]*16 + 15) -: 16] = tdata >> (16*tr.addr[1]);
      BURST_SIZE_32BIT  : mdata = tdata;
      BURST_SIZE_64BIT  : begin `uvm_error("TYPEERR", "burst size not supported") end
      default : begin `uvm_error("TYPEERR", "burst size not supported") end
    endcase
    return mdata;//输出mdata给mem
  endfunction

endclass

`endif

代码分解：write操作存入mem

 function void store_data_with_hsize(lvc_ahb_transaction tr, int beat);
    case(tr.burst_size)//1：0位不管补0，如195d和195e都写在同一地址195c，但是不同偏移量
      BURST_SIZE_8BIT   : mem[{tr.addr[31:2],2'b00}] = extract_current_beat_mem_data(tr, beat);//mem接收到偏移处理后的mdata
      BURST_SIZE_16BIT  : mem[{tr.addr[31:2],2'b00}] = extract_current_beat_mem_data(tr, beat);
      BURST_SIZE_32BIT  : mem[{tr.addr[31:2],2'b00}] = extract_current_beat_mem_data(tr, beat);
      BURST_SIZE_64BIT  : begin `uvm_error("TYPEERR", "burst size not supported") end
      default : begin `uvm_error("TYPEERR", "burst size not supported") end
    endcase
  endfunction

function bit [31:0] extract_current_beat_mem_data(lvc_ahb_transaction tr, int beat);//数据进行偏移处理
    bit [31:0] mdata = mem[{tr.addr[31:2],2'b00}];
    bit [31:0] tdata = tr.data[beat];//存入data
    case(tr.burst_size)	//8BIT mdata如果addr为0存放在7：0位，addr为1存放在15：8位，addr为2存放在23：16位，addr为3存放在31：24位
      BURST_SIZE_8BIT   : mdata[(tr.addr[1:0]*8 + 7) -:  8] = tdata >> (8*tr.addr[1:0]);//不管tdata多少位只拾取低八位
	  //16BIT mdata如果addr[1]为0tdata存放在16:0位，addr[1]为1存放在31：17位
      BURST_SIZE_16BIT  : mdata[(tr.addr[1]*16 + 15) -: 16] = tdata >> (16*tr.addr[1]);
      BURST_SIZE_32BIT  : mdata = tdata;
      BURST_SIZE_64BIT  : begin `uvm_error("TYPEERR", "burst size not supported") end
      default : begin `uvm_error("TYPEERR", "burst size not supported") end
    endcase
    return mdata;//输出mdata给mem
  endfunction

        为了防止出现覆盖，mem中存放的地址为写入地址的后两位取0，如195d和195e都在同一地址195c，但是具有不同偏移量。（先地址统一再进行偏移存放）

在8BIT中，如果后两位地址为0，则数据存放在mem的7：0位；

                  如果后两位地址位1，则数据存放在mem的15：8位；

                  如果后两位地址为2，则数据存放在mem的23：16位；

                  如果后两位地址为3，则数据存放在mem的31：24位；

在16BIT中，如果addr[1]为0，则数据存放在mem的15:0位；

                    如果addr[1]为1，则数据存放在mem的31：16位；

例子：

        195d 8BIT 数据02020202：

               地址统一为195c开始存放，后两位地址为1，则存放在15：8位，为00000200；

        195e 16BIT 数据03030303：

              地址统一为195c开始存放，后两位地址为3，则存放在31：16位，为03030200；

        113c 16BIT 数据04040404：

              地址统一为113c开始存放，后两位地址为0，则存放在15：0位，为00000404；

        17f3 8BIT   数据05050505：

              地址统一为17f0开始存放，后两位地址为3，则存放在31：24位，为05000000；

read：check_data

function bit check_data_with_hsize(lvc_ahb_transaction tr, int beat);
    bit[31:0] tdata = extract_valid_data(tr.data[beat], tr.addr, tr.burst_size);
    bit[31:0] mdata = extract_valid_data(mem[{tr.addr[31:2],2'b00}],  tr.addr, tr.burst_size);
    check_data_with_hsize = tdata == mdata ? 1 : 0;
    cfg.scb_check_count++;
    if(check_data_with_hsize)
      `uvm_info("DATACHK", $sformatf("ahbram[%0x] data expected 'h%0x = actual 'h%0x", tr.addr, mdata, tdata), UVM_HIGH)
    else begin
      cfg.scb_check_error++;
      `uvm_error("DATACHK", $sformatf("ahbram[%0x] data expected 'h%0x != actual 'h%0x", tr.addr, mdata, tdata))
    end
  endfunction
function bit [31:0] extract_valid_data([`LVC_AHB_MAX_DATA_WIDTH - 1:0] data
                                        ,[`LVC_AHB_MAX_ADDR_WIDTH - 1 : 0] addr
                                        ,burst_size_enum bsize);
  
    case(bsize)
      BURST_SIZE_8BIT   : return (data >> (8*addr[1:0])) & 8'hFF;
      BURST_SIZE_16BIT  : return (data >> (16*addr[1]) ) & 16'hFFFF;
      BURST_SIZE_32BIT  : return data & 32'hFFFF_FFFF;
      BURST_SIZE_64BIT  : begin `uvm_error("TYPEERR", "burst size not supported") end
      default : begin `uvm_error("TYPEERR", "burst size not supported") end
    endcase
  endfunction

将监测的读数据与mem的数据都进行函数extract_valid_data处理：

如读回来195d中的数据应为00000200；右移8位并&FF得到00000002；             

    mem中195d地址统一为195c，其中数据为03030200（有195e的16bit0303）；右移8位 并&FF得到00000002 

        最后两个数进行对比，结果相同；                       

林vv
关注
IP项目实践：AHB-SRAM设计与验证 （AMBA 2.0 AHB 可以写入简历）
03-07
AHB-SRAM IP核是一种连接高级高性能总线与静态随机存取存储器（SRAM）的接口，它的主要任务是提供高效的数据传输路径，使得CPU或其他AHB主设备能够快速读写SRAM中的数据。在AMBA 2.0 AHB协议中，AHB总线提供了多主...
AHB-SRAM
Hsykl的博客
09-26 2758
AHB-SRAM项目验证笔记
IC验证学习笔记（AHB-RAM）07diff-hsize、diff-haddr、diff-reset-w2r测试
weixin_46403587的博客
05-11 391
-----------------diff_haddr_virt_seq:相对于smoke_test把约束地址改为cfg.addr_start : cfg.addr_end。-----------------------建立rkv_ahbram_diff_hsize_virt_seq并添加到头文件。diff_addr_test与smoke_test类似，只是更换了virt_seq；做完vir_seq后建立diff_hsize_test与smoke_test相似。
基于UVM的APB slave RAM core的IC验证——1 协议、设计及时序
m0_62789966的博客
08-10 280
UVM 验证 APB slave SRAM verification IC验证
[UVM]UVM進階之Layer Sequence方案
元直的博客
06-06 1344
在UVM中，Layer Sequence算是比較高階的應用，合理的規劃Sequence，可以提高驗證平台的複用性和Configure的靈活性。下面就給出一個Layer Sequence的方案。 1、l0_base_vseq.sv，作用是從top_sequencer中get資源，例如拿到Configure的指針、Interface的值等等，如下面的例子： class l0...
【手撕AHB-APB Bridge】~ AHB地址总线的低两位为什么不用来表示地址呢？
qq_40549426的博客
07-31 3049
起初不是很了解为什么要进行限制，学习之后明白了，以下是我的个人理解，希望大家批评指正！！！
AHB-APB_Bridge_UVM_Env:AHB-APB UVM验证环境
05-17
AHB-APB桥接UVM验证环境是一个用于验证高级高性能总线（AHB）与先进外围总线（APB）之间桥接器功能的系统级验证解决方案。这个验证环境基于统一验证方法论（UVM），它利用了SystemVerilog语言的特性来实现高效、可...
AHB-SRAMC项目资料及代码
08-13
AHB-SRAMC项目资料及代码是针对高级总线接口（Advanced High-performance Bus，AHB）与静态随机访问存储器控制器（Static RAM Controller，SRAMC）设计的一个综合性学习资源。这个项目涵盖了从理论到实践的多个方面...
AHB-SRAM设计验证
04-04
"AHB-SRAM设计验证"涉及到的关键知识点包括AHB协议的理解、SRAM的设计原理、以及验证方法学的应用。 1. **AHB协议理解**： AHB协议是由ARM公司提出的，主要用于系统级的片上互连，它支持多主设备和多从设备的并行...
·IP项目实践：AHB-SRAM设计与验证 （AMBA 2.0 AHB 可以写入简历）
05-05
### IP项目实践：AHB-SRAM设计与验证 #### 背景介绍 在系统级芯片（SoC）设计领域，内存子系统的设计是至关重要的一个环节。内存接口的性能直接影响到整个系统的运行效率和可靠性。其中，高级微控制器总线架构...
动态内存分配函数
glowu的专栏
05-10 568
1. malloc()函数 声明：void * malloc(unsigned int size); 例如： int * p=NULL p=(int*) malloc(sizeof(int)); 2. calloc()函数 声明：void* calloc(unsigned int n, unsigned size); 例如： int* p=(int*) calloc(100, siz
中科大OJ Verilog 在线评测题解 100-105
最新发布
wangyonglongfeng的博客
12-09 2143
近跟着老师学习Verilog，做了中科大的练习题，将答案记录一下。
【STM32存储器映射-寄存器基地址-偏移】
Z小旋
03-08 1万+
可以看到各个部分详细的分类，映射其实就是对应的意思。事实上存储器本身不具备地址，所以把芯片内核所预先设定好的地址分配给寄存器，就是存储器映射。因为stm32把这个4G的虚拟存储空间和芯片内部外设进行一一对应，每个外设和其对应的寄存器都有一个确定的地址，也就是给存储器分配地址，即存储器映射。
(UVM验证学习8) 使用ahb vip对ahbram进行测试-测试拆分和scb实现
fenggang2333的博客
11-09 1908
虽然ahb vip有一些不足，但是暂时先使用它，考虑怎么对ahbram进行验证和测试。检查还是会在两个部分出现，对于简单的测试，check可以直接放置在seq中，如果测试内容较为复杂，就需要把check的位置移动到scoreboard处进行检测。在ahbram中，scoreboard通过使用mem关联数组模拟ahbram的行为，相当于一个简陋的参考模型，这样一来，每次检测到写操作时，就同样将内容写入到scb的关联数组中。如果是读操作，则将monitor传来的读得数据与关联数组中的内容进行比较就可以了scor
[SV]SystemVerilog中randomize() with{}注意事項
热门推荐
元直的博客
02-22 1万+
1、雙燈好左右兩邊的變量名不能相同。若果相同，求解器會認為兩邊是一樣的，導致約束不生效，例如： class dma_seq extends uvm_sequence #(dma_trans); bit [39:0] addr; `uvm_do_with(req, {req.addr == addr;}) endclass : dma_seq 2、假如要約束ad...
std::randomize用法
weixin_39662684的博客
09-20 7018
在使用sv编写验证环境的时候，在类中可以在变量的前面添加上rand，同时加上constraint，在randomize的时候随机.但是，有时候在task或者function中需要对一个临时变量做随机，此时便可以借助于std::randomize(a,b,c）with实现对变量的随机. ...
STM32 外设地址映射管理硬件基地址和偏移地址
ddz777751的博客
10-04 2361
片上外设区分为四条总线，根据外设速度的不同，不同总线挂载着不同的外设， APB1 挂载低速外设，APB2 和 AHB 挂载高速外设。相应总线的最低地址我们称为该总线的基地址，总线基地址也是挂载在该总线上的首个外设的地址。APB1 总线的地址最低，因此片上外设就从这这个地址开始，也称外设基地址。 （1）总线基地址 从存储器映射那张图的 Block2 可以看到，分为 4 大块，每块都有一...
AHB-Lite总线的地址总线的低两位的理解
weixin_46029080的博客
03-15 1871
AHB-Lite总线的地址总线的低两位的说明 AHB-Lite总线的低两位传递的信号不是用来表示数据的地址，表示数据地址的只有除去低两位的32位。如下表所示，低两位在地址阶段一起和HSIZE信号一起决定传输类型，是字、字节还是半字，分别存储在数据总线的哪些位置上，这在设计存储器RAM的时候，需要考虑这些问题。 一下代码描述了如何判断不同的传输类型，依据HSIZE和HADDR // Decode the bytes lanes depending on HSIZE & HADDR[1:0] w
关于AHB总线回环突发 wrap burst模式地址的理解
简单同学
06-17 1万+
评论 1
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值