如果场景中最重要的平行光开启了阴影，UNity会为该光源计算ShadowMap。
ShadowMap本质上是一个深度图，将摄像机放置在光源处，记录距离它最近的表面位置（深度信息）
因为base和additional中含有很多关于光线的计算，所以unity中使用一个额外的pass ShadowCaster来专门更新光源的ShadowMap。当开启了阴影，unity会寻找这个pass，若寻找不到则会在FallBack中寻找。下面代码的FallBack Specular中不含有ShadowCaster，但是它的FallBack调用了VertexLit，所以会继续回调。
默认情况下，光源计算阴影映射纹理时会剔除掉物体的背面，对于内置的平面来说只有一个面。
Two Sided允许对物体所有面都计算阴影结果
Shader "Custom/7"
{
Properties
{
_Color("Color Tint",Color) = (1,1,1,1)
_MainTex("Main Tex",2D) = "white"{}
_Specular("Specular",Color) = (1,1,1,1)
_Gloss("Gloss",Range(8.0,256)) = 20
_BumpMap("Bump Map",2D) = "Bump"{}
}
SubShader
{
Tags{"RenderType" = "Opaque" "Queue" = "Geometry"}
//RenderType的类型名称实际上是一种约定，并无实际意义，用于配合替代渲染方法
//QueueQueue渲染队列，用来指定当前shader作用的对象的渲染顺序：
//Unity中的几种内置的渲染队列，按照渲染顺序，从先到后进行排序，队列数越小的，越先渲染，队列数越大的，越后渲染。
//Background（1000）最早被渲染的物体的队列。
//Geometry（2000）不透明物体的渲染队列。大多数物体都应该使用该队列进行渲染，也是UnityShader中默认的渲染队列。
//AlphaTest （2450）有透明通道，需要进行Alpha Test的物体的队列，比在Geomerty中更有效。
//Transparent（3000）半透物体的渲染队列。一般是不写深度的物体，Alpha Blend等的在该队列渲染。
//Overlay （4000）最后被渲染的物体的队列，一般是覆盖效果，比如镜头光晕，屏幕贴片之类的
Pass
{
Tags{"LightMode" = "ForwardBase"}
CGPROGRAM
#pragma multi_compile_fwdbase
//在编译的时候，shader会识别到#pragma multi_compile这个指令，然后通过下面的#if 预编译指令，把shader编译成 多个版本（multi_compile 中有多少种情况就有多少种）的变体，这样就不存在我们使用if语句时，出现的多分支都会执行的性能问题了。
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
#include "Lighting.cginc"
#include "AutoLight.cginc"
fixed4 _Color;
sampler2D _MainTex;
float4 _MainTex_ST;
sampler2D _BumpMap;
float4 _BumpMap_ST;
fixed4 _Specular;
float _Gloss;
struct a2v
{
float4 vertex : POSITION;
float3 normal : NORMAL;
float4 tangent : TANGENT;
//切线
float4 texcoord : TEXCOORD0;
};
struct v2f
{
float4 pos : SV_POSITION;
float4 uv : TEXCOORD0;
//按世界空间坐标系计算光照
float4 TtoW0 : TEXCOORD1;
float4 TtoW1 : TEXCOORD2;
float4 TtoW2 : TEXCOORD3;
//声明阴影坐标
//#define SHADOW_COORDS(idx1) unityShadowCoord4 _ShadowCoord : TEXCOORD##idx1;
SHADOW_COORDS(4)
};
v2f vert(a2v v)
{
v2f o;
o.pos = UnityObjectToClipPos(v.vertex);
o.uv.xy = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;
o.uv.zw = v.texcoord.xy * _BumpMap_ST.xy + _BumpMap_ST.zw;
TANGENT_SPACE_ROTATION;
float3 worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
fixed3 worldNormal = UnityObjectToWorldNormal(v.normal);
fixed3 worldTangent = UnityObjectToWorldDir(v.tangent.xyz);
//为什么还要乘个切线的w分量？
fixed3 worldBinormal = cross(worldNormal, worldTangent) * v.tangent.w;
o.TtoW0 = float4(worldTangent.x, worldBinormal.x, worldNormal.x, worldPos.x);
o.TtoW1 = float4(worldTangent.y, worldBinormal.y, worldNormal.y, worldPos.y);
o.TtoW2 = float4(worldTangent.z, worldBinormal.z, worldNormal.z, worldPos.z);
//计算并向片元着色器传递阴影坐标
TRANSFER_SHADOW(o);
return o;
}
fixed4 frag(v2f i) : SV_Target
{
float3 worldPos = float3(i.TtoW0.w, i.TtoW1.w, i.TtoW2.w);
fixed3 lightDir = normalize(UnityWorldSpaceLightDir(worldPos));
fixed3 viewDir = normalize(UnityWorldSpaceViewDir(worldPos));
fixed3 bump = UnpackNormal(tex2D(_BumpMap,i.uv.zw));
bump = normalize(half3(dot(i.TtoW0.xyz, bump),dot(i.TtoW1.xyz, bump),dot(i.TtoW2.xyz, bump)));
fixed3 albedo = _Color.rgb * tex2D(_MainTex,i.uv.xy).rgb;
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * _Color.rgb;
fixed3 diffuse = albedo * _LightColor0.rgb * max(0,dot(lightDir, bump));
fixed3 halfDir = normalize(lightDir + viewDir);
fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0,dot(bump,halfDir)),_Gloss);
UNITY_LIGHT_ATTENUATION(atten, i, worldPos);
return fixed4(ambient + (diffuse + specular) * atten ,1.0);
}
ENDCG
}
Pass
{
Tags{"LightMode" = "ForwardAdd"}
Blend One One
CGPROGRAM
#pragma multi_compile_fwdadd
//在编译的时候，shader会识别到#pragma multi_compile这个指令，然后通过下面的#if 预编译指令，把shader编译成 多个版本（multi_compile 中有多少种情况就有多少种）的变体，这样就不存在我们使用if语句时，出现的多分支都会执行的性能问题了。
#pragma vertex vert
#pragma fragment frag
#include "Lighting.cginc"
#include "AutoLight.cginc"
fixed4 _Color;
sampler2D _MainTex;
float4 _MainTex_ST;
sampler2D _BumpMap;
float4 _BumpMap_ST;
float _BumpScale;
fixed4 _Specular;
float _Gloss;
struct a2v
{
float4 vertex : POSITION;
float3 normal : NORMAL;
float4 tangent : TANGENT;
//切线
float4 texcoord : TEXCOORD0;
};
struct v2f
{
float4 pos : SV_POSITION;
float4 uv : TEXCOORD0;
//按世界空间坐标系计算光照
float4 TtoW0 : TEXCOORD1;
float4 TtoW1 : TEXCOORD2;
float4 TtoW2 : TEXCOORD3;
//这个宏的作用，就是声明一个用于对阴影纹理采样的坐标，也就是我们要在顶点着色器内计算阴影纹理采样坐标
//这个宏有一个参数，就是下一个可用的插值寄存器的索引值，这里之前已经占用4个了(TEXCOORD0，TEXCOORD1...)，所以下面就是4
SHADOW_COORDS(4)
};
v2f vert(a2v v)
{
v2f o;
o.pos = UnityObjectToClipPos(v.vertex);
o.uv.xy = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;
o.uv.zw = v.texcoord.xy * _BumpMap_ST.xy + _BumpMap_ST.zw;
TANGENT_SPACE_ROTATION;
float3 worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
fixed3 worldNormal = UnityObjectToWorldNormal(v.normal);
fixed3 worldTangent = UnityObjectToWorldDir(v.tangent.xyz);
//为什么还要乘个切线的w分量？
fixed3 worldBinormal = cross(worldNormal, worldTangent) * v.tangent.w;
o.TtoW0 = float4(worldTangent.x, worldBinormal.x, worldNormal.x, worldPos.x);
o.TtoW1 = float4(worldTangent.y, worldBinormal.y, worldNormal.y, worldPos.y);
o.TtoW2 = float4(worldTangent.z, worldBinormal.z, worldNormal.z, worldPos.z);
//在顶点着色器内计算阴影的纹理坐标，也就是对顶点坐标进行空间的转换
//并向片元着色器传递阴影坐标
TRANSFER_SHADOW(o);
return o;
}
fixed4 frag(v2f i) : SV_Target
{
float3 worldPos = float3(i.TtoW0.w, i.TtoW1.w, i.TtoW2.w);
fixed3 lightDir = normalize(UnityWorldSpaceLightDir(worldPos));
fixed3 viewDir = normalize(UnityWorldSpaceViewDir(worldPos));
fixed3 bump = UnpackNormal(tex2D(_BumpMap,i.uv.zw));
bump = normalize(half3(dot(i.TtoW0.xyz, bump),dot(i.TtoW1.xyz, bump),dot(i.TtoW2.xyz, bump)));
fixed3 albedo = _Color.rgb * tex2D(_MainTex,i.uv.xy).rgb;
fixed3 diffuse = albedo * _LightColor0.rgb * max(0,dot(lightDir, bump));
fixed3 halfDir = normalize(lightDir + viewDir);
fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0,dot(bump,halfDir)),_Gloss);
//光照衰减和阴影对物体最终的渲染效果的影响是相同的，我们都是把光照衰减因子和阴影值及光照结果相乘得到最终的渲染效果。
//unity提供了UNITY_LIGHT_ATTENUATION宏可以用来同时计算两个信息。
UNITY_LIGHT_ATTENUATION(atten, i, worldPos);
return fixed4((diffuse + specular) * atten ,1.0);
}
ENDCG
}
}
FallBack "Specular"
//FallBack中含有ShadowCaster的pass
}
TRANSFER_SHADOW会使用v.vertex和a.pos来计算坐标，必须保证a2f结构体中顶点坐标变量名必须为vertex，顶点着色器的输出结构体v2f必须命名为v，v2f中的顶点位置变量必须命名为pos。
UNITY_LIGHT_ATTENUATION 宏定义源码
衰减和阴影一起计算
效果：
3750
被折叠的 条评论
为什么被折叠?
到【灌水乐园】发言
