UnityShader入门精要第十章代码解析（菲涅尔效果）

菲涅尔效果：光线照射到物体表面时，一部分光发生反射，一部分光进入物体内部发生折射或者散射。

Schlick菲涅尔近似等式：

 

Empricial菲涅耳近似等式:

 v是视角方向，n是法线，bias、scale、power是控制项。

Shader "Custom/12"
{
	Properties
	{
		_Color("Color Tint",Color) = (1,1,1,1)
		_FresnelScale("Fresnel Scale",Range(0,1)) = 0.5
		_Cubemap("reflection Cubemap",Cube) = "_Skybox"{}

	}

	SubShader
	{
		Tags{"RenderType" =  "Opaque" "Queue" = "Geometry"}

		pass
		{
			Tags{"LightMode" = "ForwardBase"}

			CGPROGRAM

			#pragma multi_compile_fwdbase
			
			#pragma vertex vert 
			#pragma fragment frag

			#include "Lighting.cginc"
			#include "AutoLight.cginc"


			fixed4 _Color;
			fixed _FresnelScale;
			samplerCUBE _Cubemap;

			struct a2v
			{
				fixed4 vertex : POSITION;
				fixed3 normal : NORMAL;
			};

			struct v2f
			{
				fixed4 pos : SV_POSITION;
				fixed3 worldPos : TEXCOORD0;
				fixed3 worldNormal : TEXCOORD1;
				fixed3 worldViewDir : TEXCOORD2;
				fixed3 worldRefl : TEXCOORD3;

				SHADOW_COORDS(4)
			};

			v2f vert(a2v v)
			{
				v2f o;
				o.pos = UnityObjectToClipPos(v.vertex);
				o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;

				o.worldNormal = UnityObjectToWorldNormal(v.normal);
				o.worldViewDir = UnityWorldSpaceViewDir(o.worldPos);

				o.worldRefl = reflect(-o.worldViewDir,o.worldNormal);

				TRANSFER_SHADOW(o);
				return o;
			}

			fixed4 frag(v2f i) : SV_Target 
			{
				fixed3 worldNormal = normalize(i.worldNormal);
				fixed3 lightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
				fixed3 viewDir = normalize(i.worldViewDir);

				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * _Color.rgb;
				
				UNITY_LIGHT_ATTENUATION(atten,i,i.worldPos);

				fixed3 reflection = texCUBE(_Cubemap,i.worldRefl).rgb;

				fixed fresnel = _FresnelScale + (1 - _FresnelScale) * pow(1 - dot(viewDir , worldNormal),5);

				fixed3 diffuse = _LightColor0.rgb * _Color.rgb * max(0,dot(worldNormal,lightDir));

				fixed3 color = ambient + lerp(diffuse,reflection,saturate(fresnel)) * atten;

				return fixed4 (color,1.0);
			}

			ENDCG
		}
	}
	FallBack "Reflective/VertexLit"
}

fixed fresnel = _FresnelScale + (1 - _FresnelScale) * pow(1 - dot(viewDir , worldNormal),5);
 

此处单纯混合了漫反射和反射。