awk的使用

今天学习了一下awk，因为需要对两个文件打下diff。这两个文件每一行的$1和$2都是一样的，只有$3是不一样的。我们需要把这两个文件中$3不同的行取出来，输出到一个叫做diff.txt的文件。

当时所看的中文资料是陈浩写的awk入门http://coolshell.cn/articles/9070.html和http://www.361way.com/comm-diff-awk-file/2112.html中的awk部分，不得不说陈浩的教程写得真好，很简单、实用、易懂。

当时的代码如下：

#运行前
BEGIN {
        num_lines = 0
        diff_lines = 0
        pvs = 0
        diff_pvs = 0
        printf "start to calculate how many queries and pv will be effected \n"
        printf "------------------------------------------------------------ \n"
}
#运行中
{
        if(NR == FNR) {
                a[NR] = $3
                num_lines++
                pvs += $2
        } else if(NR > FNR && a[FNR] != $3) {
                diff_lines++
                diff_pvs += $2
                print > "diff.txt"
        }
}
#运行后
END {
        printf "the number of query is %10d \n", num_lines
        printf "%10d queries will be effected. The ratio is %10.2f \n", diff_lines, diff_lines/num_lines
        printf "the number of pv is %10d \n", pvs
        printf "%10d pvs will be effected. The ratio is %10.2f \n", diff_pvs, diff_pvs/pvs
}

上述代码保存到文件stat.awk中，可以通过命令行awk -f stat.awk new.txt old.txt运行。

另外通过awk统计一个文件的行数，可以使用awk '{count++}END{print count}'  filename