二维测量--血管的分割与测量

对应示例程序：
      vessel.hdev

目标：对图像中的血管进行定位和测量直径

思路为：
      1.窗口初始化
      2.读入图像，使用Laws纹理过滤器过滤图像
      3.对过滤后的图像Blob分析，得到包含血管区域的二值化图像
      4.取图像的边缘，并获得它的边缘点坐标
      5.计算边缘的最小外接矩形，然后将矩形的左边缘一直平移，再求与边缘的交集（其实就是将左边缘连成的直线一直平移，计算直线与边缘的交点，交点间的距离就是直径的大小）
      6.将得到的直径数组求平均值 就是血管的平均直径 最小值就是最小直径。
图像：
*                                                                                                       原图：

*                                                                             使用Laws纹理过滤器过滤后的图像

*                                                                                 二值化后得到的血管区域图像

*                                                                                  直线与边缘的交点做差 计算直径的大小

*                                                                                                      测量结果：

代码：

dev_update_window ('off')
dev_close_window ()
dev_open_window (0, 0, 512, 512, 'black', WindowID)
set_display_font (WindowID, 14, 'mono', 'true', 'false')
read_image (Image, 'vessel')
dev_display (Image)
disp_continue_message (WindowID, 'black', 'true')
stop ()
dev_set_draw ('fill')
dev_set_color ('green')
dev_set_line_width (3)
*使用Laws纹理过滤器过滤图像
texture_laws (Image, Texture, 'el', 2, 5)
dev_display (Texture)
disp_continue_message (WindowID, 'black', 'true')
stop ()
*对图像进行均值滤波
mean_image (Texture, Energy, 211, 61)
dev_display (Energy)
disp_continue_message (WindowID, 'black', 'true')
stop ()
dev_display (Image)
*使用二值化阈值分割图像
binary_threshold (Energy, Vessel, 'smooth_histo', 'dark', UsedThreshold)
dev_display (Vessel)
disp_continue_message (WindowID, 'black', 'true')
stop ()
dev_set_draw ('margin')
get_region_contour (Vessel, VesselRows, VesselColumns)
gen_region_points (VesselBoundary, VesselRows, VesselColumns)
dev_display (Image)
clip_region (VesselBoundary, Boundaries, 0, 2, 511, 509)  //用一个矩形 把边缘轮廓裁剪出来
dev_display (Boundaries)
smallest_rectangle1 (Boundaries, UpperRow, Column1, LowerRow, Column2) //计算包含边缘的最小外接矩形
disp_continue_message (WindowID, 'black', 'true')
stop ()
* 
* Measurement of Diameter
* 测量直径
Diameter := []
dev_set_color ('red')
dev_update_var ('off')
dev_update_time ('off')
dev_update_pc ('off')
for i := 2 to 509 by 1
    gen_region_line (ScanLine, UpperRow, i, LowerRow, i) ///将输入行存储为区域
    dev_display (ScanLine)
    intersection (Boundaries, ScanLine, BoundaryPoints) //计算两个区域的交集
    get_region_points (BoundaryPoints, Rows, Columns)
    Diameter := [Diameter,abs(Rows[|Rows| - 1] - Rows[0])]
endfor
dev_update_pc ('on')
dev_update_time ('on')
dev_update_var ('on')
Diameter := Diameter
* 
* statistics
* 分析并 显示数据
meanDiameter := sum(Diameter) / |Diameter|  //平均直径
minDiameter := min(Diameter)              //最小直径
dev_set_color ('green')
dev_display (Image)
dev_display (Boundaries)
dev_set_color ('yellow')
get_image_size (Image, Width, Height)
get_string_extents (WindowID, 'meanDiam: ' + meanDiameter + ', minDiameter: ' + minDiameter, Ascent, Descent, TxtWidth, TxtHeight)
disp_message (WindowID, 'meanDiam: ' + meanDiameter + ', minDiameter: ' + minDiameter, 'image', (UpperRow + LowerRow) / 2, (Width - TxtWidth) / 2, 'yellow', 'false')
* get_mbutton (WindowID, Row, Column, Button)
dev_set_draw ('fill')
dev_set_line_width (1)
dev_update_window ('on')

用到的几个算子：
    texture_laws–使用Laws纹理过滤器过滤图像
    clip_region–用一个矩形裁剪一个Region
    get_region_contour–获取一个区域的contour