《计算机系统要素》学习笔记：第一章布尔逻辑

1.工具准备
本书需要的工具和资源下载址：http://www.nand2tetris.org/software.php
工具分为tools和project两个文件夹，打开tools文件夹，打开hardwaresimulator.bat，在project文件夹中，编辑hdl文件，写入代码，保存后在硬件仿真器中load chip,并load script(导入测试脚本)，运行查看结果是否正确。(可以在view下选择compare，导入.cmp文件，单步执行参看是否正确)

2.学习要点
（1）注意理解抽象思想在硬件设计中的应用，抽象的目的在于分解问题，降低问题的复杂度，本章具体体现为将基本电路封装为模块，然后调用模块构建抽象层次更高的模块。
（2）自底向上设计计算机，第一章中所有逻辑电路的实现基于与非门电路。
（3）本章涉及的内容属于数字电路的逻辑电路部分基本内容，难点在于数据选择器和译码器的构建。
（4）代码调用的逻辑门必须是自己已经实现过，否则会报错。

3.实现代码
实现本章所有出现的逻辑门。
1）基本逻辑门
或门

    CHIP Or {
      IN a, b;
      OUT out;

      PARTS:
      Nand(a=a,b=a,out=o1);
      Nand(a=b,b=b,out=o2);
      Nand(a=o1,b=o2,out=out);
    }

非门

    CHIP Not {
    IN in;
    OUT out;
    PARTS:
    Nand(a=in, b=in, out=out); 
    }

与门

    CHIP And {  
      IN a,b;  
      OUT out;  

      PARTS:  
      Nand(a=a, b=b, out=o1);  
      Nand(a=o1, b=o1, out=out); 
  } 

异或门

CHIP Xor  

    {
      IN a, b;
      OUT out;

    PARTS:
     Not(in=a,out=nota);
    Not(in=b,out=notb);
    And(a=a,b=notb,out=w1);
    And(a=nota,b=b,out=w2);
    Or(a=w1,b=w2,out=out);
  }

MUX（数据选择器）

CHIP Mux {
        IN a, b, sel;
        OUT out;

        PARTS:
        Not(in=sel,out=nsel);
        And(a=a,b=nsel,out=w1);
        And(a=b,b=sel,out=w2);
        Or(a=w1,b=w2,out=out);
    }

DMux

  CHIP DMux {
    IN in, sel;
    OUT a, b;

    PARTS:
    Not(in=sel,out=nots);  
    And(a=in,b=nots,out=a);  
    And(a=in,b=sel,out=b); 
}

2.多位基本门
多位not门

        CHIP Not16 {
            IN in[16];
            OUT out[16];

            PARTS:
            Not(in=in[0],out=out[0]);
            Not(in=in[1],out=out[1]);
            Not(in=in[2],out=out[2]);
            Not(in=in[3],out=out[3]);
            Not(in=in[4],out=out[4]);
            Not(in=in[5],out=out[5]);
            Not(in=in[6],out=out[6]);
            Not(in=in[7],out=out[7]);
            Not(in=in[8],out=out[8]);
            Not(in=in[9],out=out[9]);
            Not(in=in[10],out=out[10]);
            Not(in=in[11],out=out[11]);
            Not(in=in[12],out=out[12]);
            Not(in=in[13],out=out[13]);
            Not(in=in[14],out=out[14]);
            Not(in=in[15],out=out[15]);
        }

多位and门

        CHIP And16 {
            IN a[16], b[16];
            OUT out[16];

            PARTS:
            And(a=a[0],b=b[0],out=out[0]);
            And(a=a[1],b=b[1],out=out[1]);
            And(a=a[2],b=b[2],out=out[2]);
            And(a=a[3],b=b[3],out=out[3]);
            And(a=a[4],b=b[4],out=out[4]);
            And(a=a[5],b=b[5],out=out[5]);
            And(a=a[6],b=b[6],out=out[6]);
            And(a=a[7],b=b[7],out=out[7]);
            And(a=a[8],b=b[8],out=out[8]);
            And(a=a[9],b=b[9],out=out[9]);
            And(a=a[10],b=b[10],out=out[10]);
            And(a=a[11],b=b[11],out=out[11]);
            And(a=a[12],b=b[12],out=out[12]);
            And(a=a[13],b=b[13],out=out[13]);
            And(a=a[14],b=b[14],out=out[14]);
            And(a=a[15],b=b[15],out=out[15]);
        }

多位or门

        CHIP Or16 {
            IN a[16], b[16];
            OUT out[16];

            PARTS:
            Or(a=a[0],b=b[0],out=out[0]);
            Or(a=a[1],b=b[1],out=out[1]);
            Or(a=a[2],b=b[2],out=out[2]);
            Or(a=a[3],b=b[3],out=out[3]);
            Or(a=a[4],b=b[4],out=out[4]);
            Or(a=a[5],b=b[5],out=out[5]);
            Or(a=a[6],b=b[6],out=out[6]);
            Or(a=a[7],b=b[7],out=out[7]);
            Or(a=a[8],b=b[8],out=out[8]);
            Or(a=a[9],b=b[9],out=out[9]);
            Or(a=a[10],b=b[10],out=out[10]);
            Or(a=a[11],b=b[11],out=out[11]);
            Or(a=a[12],b=b[12],out=out[12]);
            Or(a=a[13],b=b[13],out=out[13]);
            Or(a=a[14],b=b[14],out=out[14]);
            Or(a=a[15],b=b[15],out=out[15]);
        }

多位mux

        CHIP Mux16 {
            IN a[16], b[16], sel;
            OUT out[16];

            PARTS:
            Mux(a=a[0],b=b[0],sel=sel,out=out[0]);
            Mux(a=a[1],b=b[1],sel=sel,out=out[1]);
            Mux(a=a[2],b=b[2],sel=sel,out=out[2]);
            Mux(a=a[3],b=b[3],sel=sel,out=out[3]);
            Mux(a=a[4],b=b[4],sel=sel,out=out[4]);
            Mux(a=a[5],b=b[5],sel=sel,out=out[5]);
            Mux(a=a[6],b=b[6],sel=sel,out=out[6]);
            Mux(a=a[7],b=b[7],sel=sel,out=out[7]);
            Mux(a=a[8],b=b[8],sel=sel,out=out[8]);
            Mux(a=a[9],b=b[9],sel=sel,out=out[9]);
            Mux(a=a[10],b=b[10],sel=sel,out=out[10]);
            Mux(a=a[11],b=b[11],sel=sel,out=out[11]);
            Mux(a=a[12],b=b[12],sel=sel,out=out[12]);
            Mux(a=a[13],b=b[13],sel=sel,out=out[13]);
            Mux(a=a[14],b=b[14],sel=sel,out=out[14]);
            Mux(a=a[15],b=b[15],sel=sel,out=out[15]);
        }

3.多通道逻辑门
多通道or

        CHIP Or8Way {
            IN in[8];
            OUT out;

            PARTS:
            Or(a=in[0],b=in[1],out=w1);
            Or(a=in[2],b=in[3],out=w2);
            Or(a=in[4],b=in[5],out=w3);
            Or(a=in[6],b=in[7],out=w4);
            Or(a=w1,b=w2,out=w5);
            Or(a=w3,b=w4,out=w6);
            Or(a=w5,b=w6,out=out);
        }

多通道/多位Mux

        CHIP Mux4Way16 {
            IN a[16], b[16], c[16], d[16], sel[2];
            OUT out[16];

            PARTS:    
            Mux16(a=a,b=b,sel=sel[0],out=w1);
            Mux16(a=c,b=d,sel=sel[0],out=w2);
            Mux16(a=w1,b=w2,sel=sel[1],out=out);
        }

        CHIP Mux8Way16 {
            IN a[16], b[16], c[16], d[16],
               e[16], f[16], g[16], h[16],
               sel[3];
            OUT out[16];

            PARTS:
            Mux4Way16(a=a,b=b,c=c,d=d,sel=sel[0..1],out=tp1);
            Mux4Way16(a=e,b=f,c=g,d=h,sel=sel[0..1],out=tp2);
            Mux16(a=tp1,b=tp2,sel=sel[2],out=out);
        }

多通道/多位Dmux

        CHIP DMux4Way {
            IN in, sel[2];
            OUT a, b, c, d;

            PARTS:
            Not(in=sel[0],out=nsel0);
            Not(in=sel[1],out=nsel1);

            And(a=in,b=nsel0,out=a1);
            And(a=a1,b=nsel1,out=a);

            And(a=in,b=sel[0],out=b1);
            And(a=b1,b=nsel1,out=b);

            And(a=in,b=nsel0,out=c1);
            And(a=c1,b=sel[1],out=c);

            And(a=in,b=sel[0],out=d1);
            And(a=d1,b=sel[1],out=d);
        }

        CHIP DMux8Way {
            IN in, sel[3];
            OUT a, b, c, d, e, f, g, h;

            PARTS:
            DMux4Way(in=in,sel=sel[0..1],a=a1,b=b1,c=c1,d=d1);
            DMux4Way(in=in,sel=sel[0..1],a=e1,b=f1,c=g1,d=h1);
            Not(in=sel[2],out=nsel2);
            And(a=a1,b=nsel2,out=a);
            And(a=b1,b=nsel2,out=b);
            And(a=c1,b=nsel2,out=c);
            And(a=d1,b=nsel2,out=d);
            And(a=e1,b=sel[2],out=e);
            And(a=f1,b=sel[2],out=f);
            And(a=g1,b=sel[2],out=g);
            And(a=h1,b=sel[2],out=h);
        }