60.以太网数据回环实验（3）以太网数据收发器接收模块

于 2024-09-05 11:12:27 发布
阅读量750 收藏 5
点赞数 20
分类专栏： 升腾A7-FPGA 文章标签： fpga开发
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/2301_80417284/article/details/141860121
版权

        （1）状态设计：

  • ST_IDLE        :空闲状态
  • ST_PREAMBLE     :前导码+帧起始界定符
  • ST_ETH_HEAD     :以太网帧头：目标MAC地址+源MAC地址+类型/长度
  • ST_IP_HEAD         :IP首部
  • ST_UDP_HEAD     :UDP首部（8个字节）
  • ST_RX_DATA        :接收数据状态
  • ST_RX_DONE      :接收完成状态

        （2）状态转移图： 

        （3）以太网帧头：目标MAC地址（6个字节）+源MAC地址（6个字节）+ 类型/长度（2个字节）（08 00 表示基于IP协议）      目标MAC地址需要使用一个寄存器寄存起来。

        （4）IP首部：目的 IP 地址在首部的第 17 至 20字节，需要使用一个寄存器寄存起来。

        比如第一个字节为45，则IP地址长度对应5左移两位（010100），即长度为20

       （5）UDP首部：第五个字节和第六个字节包含了UDP长度信息，例如：0028（40），有效数据长度等于UDP长度-首部长度（8个字节）

        （6）UDP接收模块代码：

//UDP接收模块设计

module udp_rx(

    input   wire                gmii_rxc            ,
    input   wire                reset_n             ,
    input   wire                gmii_rx_dv          ,   //GMII输入数据有效信号
    input   wire    [7:0]       gmii_rxd            ,   //GMII输入数据
    output  reg     [31:0]      rec_data            ,   //以太网接收后转化为32位的数据
    output  reg                 rec_en              ,   //以太网接收的数据使能信号
    output  reg                 rec_pkt_done        ,   //以太网单包数据接收完成信号 
    output  reg     [15:0]      rec_byte_num            //以太网接收的有效数据字节数

);

/*--------------参数定义，parameter全局变量，可以在上层进行修改，而localparam则是局部变量，仅在该模块使用-----------*/
//开发板MAC地址（48位）
parameter BOARO_MAC     =   48'hff_ff_ff_ff_ff_ff       ;
 
//开发板IP地址（32位）
parameter BOARO_IP      =   {8'd0,8'd0,8'd0,8'd0}       ;
 
//状态机状态定义 独热吗编码
localparam ST_IDLE      =   7'b000_0001     ;           //空闲状态，等待接收前导码
localparam ST_PREAMBLE  =   7'b000_0010     ;           //接收前导码和帧起始界定符状态
localparam ST_ETH_HEAD  =   7'b000_0100     ;           //接收以太网帧头状态
localparam ST_IP_HEAD   =   7'b000_1000     ;           //接收IP首部状态
localparam ST_UDP_HEAD  =   7'b001_0000     ;           //接收UDP首部
localparam ST_RX_DATA   =   7'b010_0000     ;           //接收有效数据状态
localparam ST_RX_DONE   =   7'b100_0000     ;           //接收完成状态
    
//以太网协议类型定义  IP协议
localparam ETH_TYPE     =   16'h0800        ;

/*--------------寄存器变量定义-----*/
reg     [6:0]       cur_state       ;           //当前状态
reg     [6:0]       next_state      ;           //下一个状态

reg                 sw_en           ;           //下一个状态跳转标志信号
reg                 error_en        ;           //接收错误标志信号  
reg     [4:0]       cnt_byte        ;           //字节计数器
reg     [47:0]      des_mac         ;           //目标MAC地址，在本模块中及开发板MAC地址
reg     [15:0]      eth_type        ;           //以太网类型
reg     [31:0]      des_ip          ;           //目标IP地址，在本模块中及开发板IP地址
reg     [5:0]       ip_len          ;           //IP首部长度
reg     [15:0]      udp_len         ;           //UDP长度
reg     [15:0]      cnt_data        ;           //数据长度计算    
reg     [15:0]      data_len        ;           //UDP有效数据长度
reg     [1:0]       cnt_rec_data    ;           //8位转32位计数器

/*--------------三段式状态机编写主程序--------*/
//第一段：时序逻辑描述状态转移
always@(posedge gmii_rxc or negedge reset_n)begin
    if(!reset_n)
        cur_state <=  ST_IDLE   ;
    else 
        cur_state <= next_state ;
end

//第二段：组合逻辑判断状态机转移条件
always@(*)begin
    next_state = ST_IDLE  ;
    case(cur_state)
        ST_IDLE :
            if(sw_en)
                next_state = ST_PREAMBLE;
            else 
                next_state = ST_IDLE;
        ST_PREAMBLE :
            if(sw_en)
                next_state = ST_ETH_HEAD;
            else if(error_en)
                next_state = ST_RX_DONE;
            else 
                next_state = ST_PREAMBLE;
        ST_ETH_HEAD :
            if(sw_en)
                next_state = ST_IP_HEAD;
            else if(error_en)
                next_state = ST_RX_DONE;
            else 
                next_state = ST_ETH_HEAD;
        ST_IP_HEAD  :
            if(sw_en)
                next_state = ST_UDP_HEAD;
            else if(error_en)
                next_state = ST_RX_DONE;
            else 
                next_state = ST_IP_HEAD;
        ST_UDP_HEAD :
            if(sw_en)
                next_state = ST_RX_DATA;
            else 
                next_state = ST_UDP_HEAD;
        ST_RX_DATA :
            if(sw_en)
                next_state = ST_RX_DONE;
            else 
                next_state = ST_RX_DATA;
        ST_RX_DONE :
            if(sw_en)
                next_state = ST_IDLE;
            else 
                next_state = ST_RX_DONE;
        default:next_state = ST_IDLE  ;
    endcase           
end
  
//第三段：时序逻辑描述寄存器变量和状态输出
always@(posedge gmii_rxc or negedge reset_n)begin
    if(!reset_n)begin
        sw_en         <= 1'd0;        
        error_en      <= 1'd0;   
        cnt_byte      <= 5'd0;   
        des_mac       <= 48'd0;   
        eth_type      <= 16'd0;   
        des_ip        <= 32'd0;
        ip_len        <= 6'd0;
        udp_len       <= 16'd0;   
        cnt_data      <= 16'd0;   
        data_len      <= 16'd0;   
        cnt_rec_data  <= 2'd0;   
        rec_data      <= 32'd0;
        rec_en        <= 1'd0;
        rec_pkt_done  <= 1'd0;
        rec_byte_num  <= 16'd0;   
    end
    else begin
        sw_en         <= 1'd0;        
        error_en      <= 1'd0;
        rec_en        <= 1'd0;
        rec_pkt_done  <= 1'd0;
        case(next_state)
            ST_IDLE :begin                      //GMII输入有效信号拉高，接收到0x55，跳转至下一个状态
                if((gmii_rx_dv == 1'd1) && (gmii_rxd == 8'h55))
                    sw_en <= 1'd1;
            end              
            ST_PREAMBLE :begin
                if(gmii_rx_dv == 1'd1)begin
                    cnt_byte <= cnt_byte + 5'd1;                    
                    if((cnt_byte < 5'd6) && (gmii_rxd != 8'h55))    //如果正确，0，1，2，3，4，5 再加上空闲跳转到该状态的一个0x55，总共7个0x55  
                        error_en <= 1'd1;
                    else if(cnt_byte == 5'd6)begin
                        cnt_byte <= 5'd0;
                            if(gmii_rxd == 8'hd5)           //一个0xd5
                                sw_en <= 1'd1;
                            else    
                                error_en <= 1'd1;
                    end
                end
            end    
            ST_ETH_HEAD :begin
                if(gmii_rx_dv == 1'd1)begin
                    cnt_byte <= cnt_byte + 5'd1;
                    if(cnt_byte < 5'd6)                      //0，1，2，3，4，5  6个8位数据，并凑出一个48位的MAC地址
                        des_mac <= {des_mac[39:0],gmii_rxd};
                    else if(cnt_byte == 5'd12)               //6，7，8，9，10，11 6个8位数据，是源MAC地址，12，13位为协议类型
                        eth_type[15:8]  <= gmii_rxd;
                    else if(cnt_byte == 5'd13)begin
                        eth_type[7:0]   <= gmii_rxd;
                        cnt_byte        <= 5'd0;
                        if(((des_mac == BOARO_MAC) || (des_mac == 48'hff_ff_ff_ff_ff_ff))
                            && eth_type[15:8] == ETH_TYPE[15:8]
                            && gmii_rxd == ETH_TYPE[7:0])
                                sw_en <= 1'd1;
                        else 
                            error_en <= 1'd1;
                    end
                end
            end
            ST_IP_HEAD :begin
                if(gmii_rx_dv == 1'd1)begin
                    cnt_byte <= cnt_byte + 5'd1;            
                    if(cnt_byte == 5'd0)            //IP首部第一个字节的后四位左移2位 代表IP首部的长度
                        ip_len <= {gmii_rxd[3:0],2'd0};           
                    else if((cnt_byte >= 5'd16) && (cnt_byte <= 5'd18))      //IP首部的后四个字节组成目标IP地址
                        des_ip <= {des_ip[23:0],gmii_rxd};
                    else if(cnt_byte == 5'd19)begin
                        des_ip <= {des_ip[23:0],gmii_rxd};
                        if((des_ip[23:0] == BOARO_IP[31:8])
                            &&(gmii_rxd == BOARO_IP[7:0]))
                                if(cnt_byte == ip_len - 1'b1)begin
                                    sw_en <= 1'd1;
                                    cnt_byte <= 5'd0;                                
                                end
                                else begin
                                    error_en <= 1'd1;
                                    cnt_byte <= 5'd0;
                                end
                    end
                    else if(cnt_byte == ip_len - 1'b1)begin
                        sw_en <= 1'd1;
                        cnt_byte <= 5'd0;  
                    end
                end
            end 
            /*------UDP首部(8个字节)：第五个字节和第六个字节包含了UDP长度信息，
            例如：0028（40），有效数据长度等于UDP长度-首部长度（8个字节）----*/
            ST_UDP_HEAD :begin
                if(gmii_rx_dv == 1'd1)begin
                    cnt_byte <= cnt_byte + 5'd1;
                    if(cnt_byte == 5'd4)
                        udp_len[15:8]   <= gmii_rxd;
                    else if(cnt_byte == 5'd5)
                        udp_len[7:0]    <= gmii_rxd;
                    else if(cnt_byte == 5'd7)begin
                        data_len <= udp_len - 16'd8;
                        sw_en   <= 1'd1;
                        cnt_byte <= 5'd0;
                    end 
                end
            end
            ST_RX_DATA  :begin
                if(gmii_rx_dv == 1'd1)begin
                    cnt_data <= cnt_data + 16'd1;
                    cnt_rec_data <= cnt_rec_data + 2'd1;
                    if(cnt_data == data_len - 16'd1)begin
                        sw_en <= 1'd1;
                        cnt_data <= 16'd0;
                        cnt_rec_data <= 2'd0;
                        rec_pkt_done <= 1'd1;
                        rec_en <= 1'd1;
                        rec_byte_num <= data_len;                   
                    end
                    if(cnt_rec_data == 2'd0)
                        rec_data[31:24] <= gmii_rxd;
                    else if(cnt_rec_data == 2'd1)
                        rec_data[23:16] <= gmii_rxd;
                    else if(cnt_rec_data == 2'd2)
                        rec_data[15:8]  <= gmii_rxd;
                    else if(cnt_rec_data == 2'd3)begin
                        rec_en <= 1'd1;
                        rec_data[7:0] <= gmii_rxd;
                    end
                end
            end
            ST_RX_DONE  :begin       //单包数据接收完成
                if((gmii_rx_dv == 1'd0) && (sw_en == 1'd0))
                    sw_en <= 1'd1;
            end
            default:   ;      
        endcase
    end
end
    
endmodule

        （7）仿真代码：

`timescale 1ns / 1ps

module tb_udp_rx;

 reg                gmii_rxc        ;        
 reg                reset_n         ;  
 reg                start_flag      ;
 reg                gmii_rx_dv      ;
 reg    [7:0]       cnt             ;
 reg    [7:0]       data_mem[85:0]  ;
 
 wire   [7:0]       gmii_rxd        ; 
 wire   [31:0]      rec_data        ;     
 wire               rec_en          ;     
 wire               rec_pkt_done    ;     
 wire   [15:0]      rec_byte_num    ;


initial gmii_rxc = 1'd1;
always #10 gmii_rxc = ~gmii_rxc;

initial begin
    reset_n <= 1'd0;
    start_flag <= 1'd0;
    #200
    reset_n <= 1'd1;
    #200
    start_flag <= 1'd1;
    #40
    start_flag <= 1'd0;
    #3000
    $stop;
end 

initial $readmemh("D:/FPGA/35_eth_udp_loop/vivado_prj/project_1.srcs/sim_1/new/data.txt",data_mem);

assign gmii_rxd = (gmii_rx_dv == 1'd1)? data_mem[cnt] : 8'd0;

always@(negedge gmii_rxc or negedge reset_n)
    if(!reset_n)
        cnt <= 1'd0;
    else if(gmii_rx_dv == 1'd1)
        cnt <= cnt + 1'b1;
    else 
        cnt <= cnt;
        
always@(negedge gmii_rxc or negedge reset_n)
    if(!reset_n)
        gmii_rx_dv <= 1'd0;
    else if(cnt == 8'd85)                   //8 + 14 + 20 + 8 + 32 + 4 = 86
        gmii_rx_dv <= 1'd0;
    else if(start_flag)
        gmii_rx_dv <= 1'd1;
    else 
        gmii_rx_dv <= gmii_rx_dv;
    

defparam udp_rx_inst.BOARO_MAC  = 48'h12_34_56_78_9a_bc;
defparam udp_rx_inst.BOARO_IP   = 32'ha9_fe_01_17 ;

udp_rx  udp_rx_inst(

    .gmii_rxc            (gmii_rxc       ),
    .reset_n             (reset_n        ),
    .gmii_rx_dv          (gmii_rx_dv     ),   
    .gmii_rxd            (gmii_rxd       ),   
    .rec_data            (rec_data       ),   
    .rec_en              (rec_en         ),   
    .rec_pkt_done        (rec_pkt_done   ),   
    .rec_byte_num        (rec_byte_num   )    

);






endmodule

        （8）仿真波形：

∑狸猫不是猫
关注
专栏目录
基于FPGA的以太网回环测试：Verilog实现UDP协议在嵌入式系统中
CyberSphinx的博客
08-14 380
本文介绍了基于FPGA的以太网回环测试的Verilog实现，并使用UDP协议进行通信。通过此实现，可以验证嵌入式系统的以太网硬件和协议栈的正确性。本文将详细介绍基于FPGA的以太网回环测试的Verilog实现，并使用UDP协议进行通信。以太网回环测试旨在验证嵌入式系统的以太网硬件和协议栈的正确性。回环测试的原理是将发送的数据通过以太网接口发送出去，然后再通过相同的接口接收回来，最后对接收到的数据进行比较，以验证数据的完整性和准确性。基于FPGA的以太网回环测试：Verilog实现UDP协议在嵌入式系统中。
Network 之二 Ethernet（以太网）中的 MAC、MII、PHY 详解
热门推荐
技术干货
04-26 16万+
结构   从硬件的角度看，以太网接口电路主要由MAC（Media Access Control）控制器和物理层接口PHY（Physical Layer，PHY）两大部分构成。如下图所示   但是，在实际的设计中，以上三部分并不一定独立分开的。 由于，PHY整合了大量模拟硬件，而MAC是典型的全数字器件。考虑到芯片面积及模拟/数字混合架构的原因，通常，将MAC集成进微控制器而将PHY留在片外...
以太网UDP数据回环实验
STATEABC的博客
10-16 1979
上位机通过网口调试助手发送数据给FPGA，FPGA通过以太网接口接收数据并将收到的数据发送给上位机，完成以太网UDP数据的回环。
【以太网通信】PHY 芯片回环测试
洋洋Young的博客
10-09 1万+
PHY 芯片通常带有回环（Loopback）功能，用于 PHY 通信链路的测试。本文主要讨论三种常用 PHY 芯片的回环功能，并使用 Broadcom 的 B50612D 芯片进行 PHY 回环测试。
基于FPGA的以太网TCP协议的数据回环实验
janfanzy的博客
12-02 5962
FPGA关于tcp的数据回环实现
以太网通信的回环测试
mochenbaobei的博客
06-25 4047
RTL8211Dx，RTL8211E(G)，RTL8211Fx 芯片只支持 PCS loopback 模式，类似前述 KSZ9031 芯片的本地 (数字) 回环模式，通过配置 Basic Mode Control 寄存器的 bit14 开启。线回环模式主要用于测试 MDI 接口的工作情况，在这种模式下，PHY PCS 层可以配置为三态输出，也可以驱动 RGMII RXD 端。对于外回环模式，MAC 向 PHY 发送的数据包经过 RJ45 连接器，重新发回 PHY，然后进入 MAC 端。
以太网RGMII/MII/RMII接口回环测试方案
weixin_46664817的博客
12-15 1779
1、模组的MAC通过RGMII/MII/RMII接口与PHY连接2、MAC层数据经过RGMII到达PHY的PCS层3、设置PHY的PCS层回环，使PCS层数据回到MAC层4、判断MAC层TX与RX接收的数据。如果MAC能接收到数据，测试PASS，否则失败。
58.以太网数据回环实验（1）理论知识
最新发布
2301_80417284的博客
08-30 859
以太网数据回环实验（1） 理论知识
基于光口的以太网 udp 回环实验
小王在努力...的博客
01-18 1889
本章实验我们通过网络调试助手发送数据给 FPGA,FPGA通过光口接收数据并将数据使用 UDP 协议发送给电脑。
RTL8201BL快速以太网物理层收发器中文数据手册
RTL8201BL是一款单芯片单端口10/100M快速以太网物理层(PHY)收发器，由Realtek公司生产。该芯片设计用于实现以太网通信，支持10Mbps和100Mbps两种传输速率。数据手册Rev.1.326提供了详细的技术规格和操作指南。 在...
千兆以太网传输层 UDP 协议原理与 FPGA 实现（UDP接收）
小王在努力...的博客
10-08 1631
在前面我们对以太网 UDP 帧格式做了讲解，UDP 帧格式包括前导码+帧界定符、以太网头部数据、IP 头部数据、UDP 头部数据、UDP 数据、FCS 数据，以太网接收模块同样是按照该格式接收数据。
Linux 串口回环自发自收测试程序
09-21
linux下串口驱动的自发自收测试程序。测试可用。操作方便，运行平台在linux系统平台下，操作也很简单。可以当做串口通用模板。
STM32F107以太网TCP客户端收发数据实验
12-03
STM32F107以太网TCP客户端收发数据实验
愤怒_STM32F107以太网UDP服务器收发数据实验
09-04
一旦服务器启动并监听特定端口，它就可以开始接收数据。在STM32中，这通常通过中断服务程序实现，当有新的数据包到达时，中断服务程序会被触发。然后，我们可以调用`udp_recv()`或类似函数来读取数据。同时，我们还...
基于EP4CE10F17C8的以太网数据回环（UDP）
xianyudewo的博客
04-07 5594
目录一、理论知识（部分来自野火、正点原子资料）（一）TCP/IP五层模型（二）以太网（自底向上描述）1.物理层2.MAC子层3.网络层（IP、ICMP、ARP）4.传输层（TCP、UDP）二、编程实现（一）思路（二）设计（自顶向下）1. 顶层2. 接收模块3. 发送模块3. CRC校验模块（三）注意事项 一、理论知识（部分来自野火、正点原子资料） （一）TCP/IP五层模型 TCP/IP（Transmission Control Protocol/Internet Protocol），供已连接网络的计算机进
RGMII以太网测试方案
gtychuashuiwang的博客
10-08 1637
以太网回环测试
双网卡的回环测试
hulifox008的专栏
09-30 7647
<br />最近碰到这样一个问题，一台linux机器上装有两个网卡，分别为eth0和eth1，将这两个网卡用网线直接连接起来，要进行回环测试，也就是从eth1发数据从eth0收到，从eth0发数据从eth1收到。<br />本来，通过原始套接字，直接绑定到指定的网卡上进行接收和发送数据，是很容易完成任务。但要求是要用基于IP的协议，TCP或UDP完成测试。Linux的内核对从一个网络地址发往另一个网络地址的数据包，如果这两个网络地址同属一个host，则这个数据包会直接在内部转发，根本不会放到网络设备上。后来
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值