VB.NET线程同步之-给主线程反馈进度

给主线程反馈进度

一个进程内的所有线程都在同一个虚拟地址空间，理论上工作者线程访问主线程内的所有变量没有任何问题，所谓的同步就是两个线程之间互相协调谁先干什么谁在后干什么等协同工作。但是主线程有些特殊，因为主线程控制着界面，在工作者线程中不可以直接操作主线程内的控件，以我们的工作者线程想把执行进度反馈给主线程并显示到进度条上这个功能为例，工作者线程需要使用Invoke调用以保证访问控件的安全性，示例如下：

Imports System.Threading
Public Class Form1
    Private m_Thread As Thread
    Private Delegate Sub SetStep(ByVal stp As Integer)
    Private fn As SetStep
    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        fn = New SetStep(AddressOf SetProg)
        ProgressBar1.Maximum = 100
        ProgressBar1.Minimum = 0
    End Sub

    '工作者线程执行函数
    Private Sub ThreadRun()
        Dim i As Integer
        i = 0
        While (True)

            Thread.Sleep(1000)
            Invoke(fn, i)
            i += 5
            If i > 100 Then Exit While

        End While
    End Sub

    Private Sub SetProg(ByVal stp As Integer)
        ProgressBar1.Value = stp
    End Sub

    Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
        m_Thread = New Thread(AddressOf ThreadRun)
        ProgressBar1.Value = 0
        m_Thread.Start()
    End Sub

End Class

你需要定义一个委托并把操作控件的代码写到一个函数内并通过此委托Invoke方式调用，Invoke确保在创建控件的线程上执行委托指定的函数，以保证操作控件的安全性。

执行结果如下：