期货量化软件：赫兹量化中模拟器的诞生

规划
许多人可能认为规划很容易，特别是，由于它事关转换柱线，即始终把 1-分钟柱线转换为票据（我们稍后会解释）。 然而，模拟比表面看要复杂得多。 主要问题在于我们尚未清晰地理解票据的实际行为，就去创建 1-分钟柱线。 我们只有柱线，和一些它的有关信息，但我们并不知道柱线是如何形成的。 我们将采用 1-分钟柱线，因为它们所需的难度最小。 如果您能创造一个与真实事物非常相似的复杂走位，那么您就能够再现一些非常接近真实事物的东西。

这个细节似乎并不那么重要，因为我们通常会在市场上看到锯齿形的走位。 无论走位如何复杂，这一切都归结为在 OHCL 点之间创建锯齿形。 它始自柱线的开盘那一刻，且需不少于 9 个走位来创造这个内部的锯齿形。 它总是在柱线收盘时结束，并在下一根柱线上重复该过程。 MetaTrader 5 策略测试器采用相同的逻辑。 更多详细信息，请参阅真实与生成的基差：算法交易。 我们将从这个策略开始。 虽然对于我们的目的来说并不理想，但它将为开拓更多适合的方式提供一个起点。

就我而言，测试策略器不太适合回放/模拟系统，因为在策略测试器中，时间问题并不是最重要的。 这就是，没必要以这种方式创建和复现 1-分钟柱线，因为其长度本来就是 1-分钟。 事实上，它甚至更简略，在于它与现实时间并不对应。 如果是这样的话，那么测试策略就变得不可能。 想象一下，依据跨越几天甚至几年的柱运行测试，如果每根柱线复现时间与实际不同。 这将是一项不可能完成的任务。 然而，对于回放/模拟系统，我们正在寻找一种不同的行动。 我们希望按照 1-分钟间隔创建一根 1-分钟柱线，尽可能接近这个目标。

准备奠基
我们的重点将完全放在回放/模拟服务代码上。 此时无需担心其它方面。 故此，我们将开始修改 C_Replay 类的代码，尝试尽可能地优化我们已经开发完成并测试过的东西。 下面是类中出现的第一个过程：

inline bool CheckFileIsBar(int &file, const string szFileName)
                        {
                                string  szInfo = "";
                                bool    bRet;
                                
                                for (int c0 = 0; (c0 < 9) && (!FileIsEnding(file)); c0++) szInfo += FileReadString(file);
                                if ((bRet = (szInfo == def_Header_Bar)) == false)
                                {
                                        Print("File ", szFileName, ".csv is not a file with bars.");
                                        FileClose(file);
                                }
                                
                                return bRet;
                        }

此处的目标是柱线读取函数，这些测试是为了判定指定文件是否为预览柱线文件。 这是必要的，当使用相同代码来判定柱线文件是否符合我们所需时，如此可避免重复代码。 在此状况下，这些柱线将不会用作预览柱线。 它们将被转换为模拟票据，以便在交易系统中使用。 有基于此，我们引入了另一个函数：

inline void FileReadBars(int &file, MqlRates &rate[])
                        {
                                rate[0].time = StringToTime(FileReadString(file) + " " + FileReadString(file));
                                rate[0].open = StringToDouble(FileReadString(file));
                                rate[0].high = StringToDouble(FileReadString(file));
                                rate[0].low = StringToDouble(FileReadString(file));
                                rate[0].close = StringToDouble(FileReadString(file));
                                rate[0].tick_volume = StringToInteger(FileReadString(file));
                                rate[0].real_volume = StringToInteger(FileReadString(file));
                                rate[0].spread = (int) StringToInteger(FileReadString(file));
                        }

它将从指定文件里逐行读取已有柱线的数据。 我想您在理解这段代码时不会遇到任何困难。 继续这个准备阶段，此处是另一个函数：

inline bool OpenFileBars(int &file, const string szFileName)
                        {
                                if ((file = FileOpen("Market Replay\\Bars\\" + szFileName + ".csv", FILE_CSV | FILE_READ | FILE_ANSI)) != INVALID_HANDLE)
                                {
                                        if (!CheckFileIsBar(file, szFileName))
                                                return false;
                                        return true;
                                }
                                Print("Falha ao acessar ", szFileName, ".csv de barras.");
                                
                                return false;
                        }

我们的系统现在已经完全集中化，能提供对柱线的标准访问：我们即可把它们用作预览柱线时，亦可把它们用于模拟，并转换为票据表示。 因此，之前加载预览柱线的函数也必须修改，如下所示：

bool LoadPrevBars(const string szFileNameCSV)
        {
                int     file,
                        iAdjust = 0;
                datetime dt = 0;
                MqlRates Rate[1];
                                
                if (OpenFileBars(file, szFileNameCSV))
                {
                        Print("Loading preview bars for Replay. Please wait....");
                        while ((!FileIsEnding(file)) && (!_StopFlag))
                        {
                                FileReadBars(file, Rate);
                                iAdjust = ((dt != 0) && (iAdjust == 0) ? (int)(Rate[0].time - dt) : iAdjust);
                                dt = (dt == 0 ? Rate[0].time : dt);
                                CustomRatesUpdate(def_SymbolReplay, Rate, 1);
                        }
                        m_dtPrevLoading = Rate[0].time + iAdjust;
                        FileClose(file);
                        
                        return (!_StopFlag);
                }
                m_dtPrevLoading = 0;
                        
                return false;
        }

这个下载函数的工作方式并无变化，尽管现在有更多的调用。 从以前的函数中提取一部分，并在新位置加以运用，为我们提供了更高的安全性，因为所有代码都已经过测试。 以这种方式，我们只需要担心新函数。 现在地基已经准备就绪，我们需要在配置文件中添加新内容呢。 该函数旨在判定哪些柱线文件可用于模拟票据。 为此，我们需要添加一个新定义：

#define def_STR_FilesBar        "[BARS]"
#define def_STR_FilesTicks      "[TICKS]"
#define def_STR_TicksToBars     "[TICKS->BARS]"
#define def_STR_BarsToTicks     "[BARS->TICKS]"

这样我们就可以运行一个简单的测试，这正是我们开始进行模拟所需要的。