ANSYS_APDL——实例004-SOLID65环向布置钢筋

KEYOPT和R，RMORE都可以在help文件中查看，
KEYOPT第一个参数和R的第一个参数都是指实体编号，1就是指solid65

!* 
! 单元属性 
ET,1,SOLID65 	!单元类型
!* 
KEYOPT,1,1,0 	!solid65的keypot，可在help文件中查看
KEYOPT,1,5,0 
KEYOPT,1,6,0 
KEYOPT,1,7,1 
!* 
!实参数 1：不同方向配筋 
R,1,2,.001, , ,2, .01, 		!也是solid65,的实常数R1-6 ,Rmore 7-19
RMORE, 90, ,2,.005 ,90 ,90 , 
!材料属性 
!混凝土基本材料属性 
MPTEMP,,,,,,,, 
MPTEMP,1,0 
MPDATA,EX,1,,30E2 			!定义与温度相关联的属性数据
MPDATA,PRXY,1,,.2 
!屈服准则 
TB,MISO,1,1,5, 
TBTEMP,0 
TBPT,,0.0005,15 
TBPT,,0.001,21 
TBPT,,0.0015,24 
TBPT,,0.002,27 
TBPT,,0.003,24 
!破坏准则 
TB,CONC,1,1,9, 
TBTEMP,0 
TBDATA,,.5,.9,3,30,, 
!抗拉和抗压是 10 倍的关系 
TBDATA,,,,1,,, 

!进入材料2的定义
MPTEMP,,,,,,,, 
MPTEMP,1,0 
!钢材基本属性 
MPDATA,EX,2,,200E3 	!第2个实体的参数
MPDATA,PRXY,2,,.27 

!屈服准则 
TB,BISO,2,1,2, 
TBTEMP,0 
TBDATA,,310,2E3,,,, 

! 管道内径和外径 
CYL4,0,0,3000, , , ,10000 
!用法CYL4, XCENTER, YCENTER, RAD1, THETA1, RAD2, THETA2, DEPTH
CYL4,0,0,2000, , , ,10000 
VSBV, 1, 2 		!从1中减去2，对卷操作，

! 定义局部柱坐标 
CSWPLA,11,1,1,1, !编号必须大于10，所以从11开始，
! Defines a local coordinate system at the origin of the working plane. 

KWPAVE, 11 
!move to keypoint11 

WPRO,,-90.000000, 
VSBW, 3 
WPCSYS,-1,0 
!Defines the working plane location based on a coordinate system. 
KWPAVE, 1 
WPRO,,,-90.000000 
VSBW,ALL 
ESIZE,500,0, 
! 注意：设定单元局部坐标 
VATT, 1, 1, 1, 11 
!* 
VSWEEP,ALL 
/DEVICE,VECTOR,1 
/ESHAPE,1.0 
!Displays elements with shapes determined from the real constants or section 
/REPLO