单自由度面内柔性机械臂的APDL命令流建模（瞬态动力学求解）与动画演示

柔性单自由度机械臂瞬态动力学分析

单自由度柔性机械臂，靠末端电机驱动。电机转子具有一定的转动惯量，电机转子与臂杆末端用连接杆等效为线性扭簧，整个臂杆符合欧拉伯努利梁假设，端部具有负载，负载具有质量与转动惯量。

 

 

!说明：ANSYS APDL命令流计算板的瞬态动力学响应

!单自由度面内机械手臂
Finish
/clear
/Prep7
/units,SI
t1=1						!1求解时间1s
dt=0.001					!求解步长0.001

!单元建模

ET,1,beam188				!单元类型定义
KeyOpt,1,3,3				!单元类型.单元关键字.单元形函数（1~3次函数）
SecType,1,beam,rect			!单元类型.单元实常数
b1=0.06
h1=0.01
SecData,b1,h1				!单元截面.形状参数
Mp,EX,1,4.169e9				!弹性模量.4Gpa
Mp,Nuxy,1,0.3				!材料本构.泊松比.0.3
MP,dens,1,683.33			!材料本构.密度

k1=624.6
ET,2,combin14          		!弹簧单元（电机转子与臂杆前端连接处等效的线性扭簧）
keyopt,2,2,6         		!沿z轴转动的一维扭转弹簧
r,2,k1						!刚度

ET,3,Mass21,,,3				!单元类型的定义.mass21.3号关键字=3，表示具备ux&uy&uz三个方向的质量属性与z轴的转动惯量
P1=2						!端部负载质量
J1=0.1						!端部负载转动惯量
R,3,P1,J1					!单元类型.单元实常数

ET,4,Mass21,,,3				!单元类型的定义.mass21.3号关键字=3，表示具备ux&uy&uz三个方向的质量属性与z轴的转动惯量
P2=0						!电机转子质量可以不考虑
J2=0.1						!电机转子转动惯量
R,4,P2,J2					!单元类型.单元实常数


!定义节点坐标
L1=1     					!机械臂杆长为1m					
N,2,0,0,0					!笔者不爱定义1号节点
N,3,0,0,0					
N,103,L1,0,0
N,104,0,0.01,0

!填充节点
FILL,3,103					!将节点3~103填充满
*do,iii,3,103-1
	Type,1					!单元类型				
	Real,1					!实常数
	MAT,1   				!材料
	ESYS,0   				!单元坐标系号
	SECNUM,1 				!几面
	E,iii,iii+1,104			!单元1的属性赋予
*enddo	

Type,2								
Real,2	   					!单元2的属性赋予：2,3节点
E,2,3						

Type,3						!单元3的属性赋予：103节点			
Real,3	   					
E,103						

Type,4						!单元4的属性赋予：2节点			
Real,4	   					
E,2						 	








!位移边界条件

D,2,ux,0,,,,uy,uz,roty,rotx
D,3,ux,0,,,,uy,uz,roty,rotx 
*do,i,3,103
	D,i,uz
*enddo


/SOL						!瞬态动力学求解

ANTYPE,4
TRNOPT,FULL 
LUMPM,0 

NLGEOM,0          !1非线性(大变形)，0线性（小变形）
DELTIM,dt,0,0

OUTRES,ALL,ALL  
AUTOTS,0
TIME,t1
LNSRCH,1      
KBC,0  
TRNOPT,,,,,,HHT    
TINTP,LOSP
F,2,MZ,5  					!载荷为5n.m的扭矩

SOLVE   
FINISH 

/POST1  					!动画设置
/DSCALE,ALL,1.0 
/EFACET,1   
PLNSOL, U,SUM, 0,1.0  
ANDSCL,10,0.5   
FINISH