Shader学习23——描边+辉光

研究了一下Post Processing，简单尝试了一下剑辉光效果

image.png

其实shader基本没啥变化，就是在描边的shader基础上加了点位置判断。
首先我们设置好Post Processing辉光效果。

image.png

如果Post Processing不会用的话可以去B站搜一下，Unity官方有发一个使用教程，基本两倍速看前面几分钟就会了。
然后随便找一把剑，把材质shader丢上去。

这里我们直接基于描边shader修改，增加了一个控制辉光范围的_OutlineHight，与模型自身的顶点去做比对，因此这里的数值会需要根据不同的模型调节，这里需要根据自己的模型调节以下代码的数值。
需要自己去尝试模型是v.vertex.y还是v.vertex.z(因为模型的方向不一样)
另外就是需要去尝试_OutlineHight的值和范围，这个多试试也就知道了

fixed width=_OutlineWidth*lerp(0, 1, step(v.vertex.z, _OutlineHight));

最终效果跟上面一样，也可以去调Bloom的值改变大小等：

image.png

需要给描边的颜色设置为[HDR]，并且加大亮度：

image.png

全部shader代码：

// Upgrade NOTE: replaced 'mul(UNITY_MATRIX_MVP,*)' with 'UnityObjectToClipPos(*)'

Shader "Unlit/辉光描边"
{
    Properties{
        _MainTex("Main Tex", 2D) = "white"{} // 纹理贴图
        _Color("Color", Color) = (1,1,1,1)   // 控制纹理贴图的颜色
        _Specular("Specular", Color) = (1,1,1,1) //镜面反射
        _Gloss("Gloss",Range(8.0,256)) = 20  //高光强度
        _NormalMap("Normal Map", 2D) = "bump"{} // 表示当该位置没有指定任何法线贴图时，就使用模型顶点自带的法线
        _BumpScale("Bump Scale", Float) = 1  // 法线贴图的凹凸参数。为0表示使用模型原来的发现，为1表示使用法线贴图中的值。大于1则凹凸程度更大。
        [HDR]
        _OutlineColor ("Outline Color", Color) = (1,0,1,1)
        _OutlineWidth ("Outline Width", Range(0, 0.1)) = 0.01
        //增加了一个参数_OutlineHight来控制光显示到的高度
        _OutlineHight ("Outline Hight", Range(0, 0.1)) = 1

    }
    SubShader{
        Tags { "RenderType"="Opaque" "Queue" = "Transparent-1"}
        LOD 200

        //第一个Pass用于描边
        Pass
        {
            ZWrite Off
            Cull Off

            CGPROGRAM
            #include "UnityCG.cginc"
            #pragma vertex vert
            #pragma fragment frag

            struct a2v
            {
                float4 vertex : POSITION;
                float3 normal : NORMAL;
            };

            struct v2f
            {
                float4 vertex : SV_POSITION;
            };

            fixed4 _OutlineColor;
            fixed _OutlineWidth;
            fixed _OutlineHight;
            v2f vert(a2v v)
            {
                v2f o;
                
                // fixed width;
                // if(v.vertex.z>_OutlineHight)
                // width=0;
                // else
                // width=_OutlineWidth*1;

                //这里与上面判断等价，优化了一下判断
                fixed width=_OutlineWidth*lerp(0, 1, step(v.vertex.z, _OutlineHight));

                // lerp(a, b, step(cx, cy));
                //顶点位置向法线方向移动一段距离，再转给世界坐标设置所有像素点_OutlineColor色
                v.vertex.xyz += v.normal * width;
                o.vertex = UnityObjectToClipPos(v.vertex);

                return o;
            }

            fixed4 frag(v2f i) : SV_Target
            {
                return _OutlineColor;
            }

            ENDCG
        }

        // 第二个Pass用于正常显示
        Pass {
            // 只有定义了正确的LightMode才能得到一些Unity的内置光照变量
            Tags { "RenderType"="Opaque" "LightMode"="ForwardBase"}
            LOD 200

            CGPROGRAM

            // 包含unity的内置的文件，才可以使用Unity内置的一些变量
            #include "Lighting.cginc" // 取得第一个直射光的颜色_LightColor0 第一个直射光的位置_WorldSpaceLightPos0(即方向)
            #pragma vertex vert
            #pragma fragment frag
            
            fixed4 _Color;
            sampler2D _MainTex;
            float4 _MainTex_ST; // 命名是固定的贴图名+后缀"_ST"，4个值前两个xy表示缩放，后两个zw表示偏移
            sampler2D _NormalMap;
            float4 _NormalMap_ST; // 命名是固定的贴图名+后缀"_ST"，4个值前两个xy表示缩放，后两个zw表示偏移
            float _BumpScale;    
            fixed4 _Specular;
            float _Gloss;

            struct a2v
            {
                float4 vertex : POSITION;    // 告诉Unity把模型空间下的顶点坐标填充给vertex属性
                float3 normal : NORMAL;        // 不再使用模型自带的法线。保留该变量是因为切线空间是通过(模型里的)法线和(模型里的)切线确定的。
                float4 tangent : TANGENT;    // tangent.w用来确定切线空间中坐标轴的方向的。
                float4 texcoord : TEXCOORD0; 
            };

            struct v2f
            {
                float4 uv : TEXCOORD0; // xy存储MainTex的纹理坐标，zw存储NormalMap的纹理坐标
                float4 vertex : SV_POSITION; // 声明用来存储顶点在裁剪空间下的坐标
                float3 normal : NORMAL;  
                float3 lightDir : TEXCOORD1;   // 切线空间下，平行光的方向
            };

            // 计算顶点坐标从模型坐标系转换到裁剪面坐标系
            v2f vert(a2v v)
            {
                v2f o;

                //顶点坐标转换
                // 该步骤用来把一个坐标从模型空间转换到剪裁空间
                o.vertex = UnityObjectToClipPos(v.vertex); 

                //获取法线(把法线方向从模型空间转换到世界空间)。
                o.normal = UnityObjectToWorldNormal(v.normal);

                //贴图的纹理坐标
                o.uv.xy = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw; 
                //法线贴图的纹理坐标
                o.uv.zw = v.texcoord.xy * _NormalMap_ST.xy + _NormalMap_ST.zw; 

                //调用这个宏会得到一个矩阵rotation，该矩阵用来把模型空间下的方向转换为切线空间下
                TANGENT_SPACE_ROTATION; 

                //切线空间下，平行光的方向
                o.lightDir = mul(rotation, ObjSpaceLightDir(v.vertex)); 

                return o;
            }

            // 要把所有跟法线方向有关的运算，都放到切线空间下。因为从法线贴图中取得的法线方向是在切线空间下的。
            fixed4 frag(v2f i) : SV_Target 
            {
                /**************************法线贴图处理******************************/
                //法线方向。从法线贴图中获取。法线贴图的颜色值 --> 法线方向
                fixed4 normalColor = tex2D(_NormalMap, i.uv.zw); // 在法线贴图中的颜色值

                fixed3 tangentNormal = UnpackNormal(normalColor); // 使用Unity内置的方法，从颜色值得到法线在切线空间的方向
                tangentNormal.xy = tangentNormal.xy * _BumpScale; // 控制凹凸程度
                tangentNormal = normalize(tangentNormal);

                //切线空间下的光照方向归一化
                fixed3 lightDir = normalize(i.lightDir);
                
                //兰伯特
                fixed3 diffuse = _LightColor0.rgb * _Color.rgb *saturate(dot(tangentNormal, lightDir)) ; // 颜色融合用乘法
                /********************************************************/

                /**************************灯光照明******************************/
                //获取场景光
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
                /********************************************************/

                /**************************贴图颜色******************************/
                //纹理坐标对应的纹理图片上的点的颜色
                fixed3 texColor = tex2D(_MainTex, i.uv) ;
                /********************************************************/
                

                //最终颜色叠加
                fixed3 color = diffuse + ambient;

                return fixed4(color*texColor, 1); //色彩叠加后与贴图颜色相乘
                // return _OutlineColor;

            }

            ENDCG
        }
        
    }
    FallBack "Diffuse"
}