水流动效果Shader

【效果图】

 

【实现步骤】

1. 新建一个Shader，命名为WaterFlow，将下面的代码复制进去
2. 新建一个材质，命名为WaterFlow,选择刚才创建的shader
3. 给材质赋值下面的贴图

4.新建一个Plane，将刚才创建的材质赋值给这个平面

5.运行程序看效果，调节Magnitude,Frequency,Speed改效果

【shader代码详解】

Shader "Custom/WaterFlow"
{
	Properties{
		_MainTex("MainTex",2D) = "white"{}//存放贴图
		_Color("Color Tint",Color) = (1,1,1,1)//控制整体颜色
		_Magnitude("Magnitude",Float) = 0.1//控制波动频率
		_Frequency("Frequency",Float) = 0.5//控制波动幅度，参考正弦波的频率幅度来理解
		_Speed("Speed", Float) = 0.01//控制流动速度
	}

		SubShader{
		//指定透明度混合渲染队列、该Shader不受投影器影响、该Shader要使用透明度混合、顶点动画不能批处理
		Tags{"Queue" = "Transparent" "IgnoreProjector" = "True" "RenderType" = "Transparent" "DisableBatching" = "True"}

		Pass{
		//指定前向渲染模式
		Tags{"LightMode" = "ForwardBase"}

		ZWrite Off//关闭深度读写
		Blend SrcAlpha OneMinusSrcAlpha//开启混合模式
		Cull Off//关闭剔除功能

		CGPROGRAM

		#pragma vertex vert
		#pragma fragment frag
		#include "UnityCG.cginc"
        
		//定义Properties中的变量
		sampler2D _MainTex;
		float4 _MainTex_ST;//纹理的缩放和偏移值,TRANSFORM_TEX会调用
		fixed4 _Color;
		float _Magnitude;
		float _Frequency;
		float _Speed;

		struct a2v {
			float4 vertex:POSITION;
			float2 texcoord:TEXCOORD0;
		};

		struct v2f {
			float4 pos:SV_POSITION;
			float2 uv:TEXCOORD0;
		};

		v2f vert(a2v v) {
			v2f o;
			float4 offset = float4(0, 0, 0, 0);//顶点偏移
			offset.y = sin(_Frequency *_Time.y+ v.vertex.x+ v.vertex.y+ v.vertex.z)*_Magnitude;//顶线Y坐标随时间偏移
			o.pos = UnityObjectToClipPos(v.vertex + offset);//顶点从模型空间到裁剪空间
			o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);//传递UV坐标
			o.uv += float2(0, _Time.y*_Speed);//纹理动画，水平方向上的移动
			return o;
		}

		fixed4 frag(v2f i) :SV_Target{
			fixed4 c = tex2D(_MainTex,i.uv);//根据UV坐标进行纹理采样
			c.rgb *= _Color.rgb;
			return c;
		}

		ENDCG
		 }
		 }
	FallBack "Transparent/VertexLit"
}

【其他】

• 可以修改顶点坐标和UV坐标实现合适的移动
• 最好选择合适的贴图配合

【参考】

《shader入门精要》