【OpenCV 基础知识 14】漫水填充算法

void cvFloodFill (
    IplImage * img,        　// 输入图像
    CvPoint    seedPoint,    // 种子点
    CvScalar newVal,    　　 // 像素点被染色的值
    CvScalar loDiff = cvScalarAll(0),     // 染色边界判定
    CvScalar upDiff = cvScalarAll(0),     // 染色边界判定
    CvConnectedComp * comp = NULL,        // 填充区域统计属性
    int flags = 4,                        // 连通性，相关性等参数设置。
    CvArr * mask = NULL                   // 掩码区域
);

• image 【输入/输出】 1或者3通道、 8bit或者浮点图像。仅当参数flags的FLOODFILL_MASK_ONLY标志位被设置时image不会被修改，否则会被修改。
• mask 【输入/输出】 操作掩码，必须为单通道、8bit，且比image宽2个像素、高2个像素。使用前必须先初始化。Flood-filling无法跨越mask中的非0像素。例如，一个边缘检测的结果可以作为mask来阻止边缘填充。在输出中，mask中与image中填充像素对应的像素点被设置为1，或者flags标志位中设置的值(详见flags标志位的解释)。此外，该函数还用1填充了mask的边缘来简化内部处理。因此，可以在多个调用中使用同一mask，以确保填充区域不会重叠。
• seedPoint 起始像素点
• newVal 重绘像素区域的新的填充值(颜色)
• rect 可选输出参数，返回重绘区域的最小绑定矩形。
• loDiff 当前选定像素与其连通区中相邻像素中的一个像素，或者与加入该连通区的一个seedPoint像素，二者之间的最大下行差异值。
• upDiff 当前选定像素与其连通区中相邻像素中的一个像素，或者与加入该连通区的一个seedPoint像素，二者之间的最大上行差异值。
• flags flags标志位是一个32bit的int类型数据，其由3部分组成： 0-7bit表示邻接性(4邻接、8邻接)；8-15bit表示mask的填充颜色；16-31bit表示填充模式（详见填充模式解释）

program cv_FloodFill;

{$APPTYPE CONSOLE}
{$R *.res}

uses
  System.SysUtils,
  ocv.highgui_c,
  ocv.core_c,
  ocv.core.types_c,
  ocv.imgproc_c,
  ocv.imgproc.types_c,
  uResourcePaths;


// 填充函数，使用洪泛填充算法将指定的种子点开始的区域填充为指定颜色
procedure fill(src: pIplImage; seed: TCvPoint; color: TCvScalar); // = CV_RGB(255, 0, 0)
var
  comp: TCvConnectedComp;
begin
  // 使用洪泛填充算法进行填充，填充颜色为指定的颜色，相邻像素颜色差异在固定范围内
  cvFloodFill(src, seed, color, cvScalarAll(10),
    cvScalarAll(10),
    @comp, CV_FLOODFILL_FIXED_RANGE + 8, 0);

  // 输出填充区域的面积信息
  WriteLn(Format('[filled area] %.2f', [comp.area]));
end;

// 鼠标回调函数，用于处理鼠标事件
procedure myMouseCallback(event: Integer; x: Integer; y: Integer; flags: Integer; param: Pointer); cdecl;
Var
  img: pIplImage;
begin
  // 将传递的参数转换为图像类型
  img := pIplImage(param);

  // 根据鼠标事件类型处理不同的操作
  case event of
    CV_EVENT_MOUSEMOVE:
      ; // 鼠标移动时无操作
    CV_EVENT_LBUTTONDOWN:
      begin
        // 鼠标左键按下时输出坐标信息
        WriteLn(Format('%dx%d', [x, y]));

        // 调用填充函数，以鼠标点击位置为种子点进行填充
        fill(img, CvPoint(x, y), CV_RGB(255, 0, 0));
      end;
    CV_EVENT_LBUTTONUP:
      ; // 鼠标左键释放时无操作
  end;
end;

// 图片文件名常量
Const
  filename = cResourceMedia + 'cat2.jpg';

Var
  src: pIplImage = nil;
  dst: pIplImage = nil;
  c: Integer;

begin
  try
    // 加载图像
    src := cvLoadImage(filename);
    WriteLn(Format('[i] image: %s', [filename]));

    // 创建窗口并设置鼠标回调函数
    cvNamedWindow('original', 1);
    cvSetMouseCallback('original', myMouseCallback, src);

    // 进入主循环，显示图像，按下ESC键退出
    while true do
    begin
      cvShowImage('original', src);
      c := cvWaitKey(33);
      if (c = 27) then
        break;
    end;

    // 释放图像资源和关闭窗口
    cvReleaseImage(src);
    cvReleaseImage(dst);
    cvDestroyAllWindows;
  except
    on E: Exception do
      WriteLn(E.ClassName, ': ', E.Message);
  end;
end.