凹凸映射

凹凸映射的目的是使用一张纹理来修改模型表面的法线，以便为模型提供更多的细节。

这个方法不会真的改变模型的顶点位置。

凹凸映射的两种方式：

1.高度映射：使用一张高度纹理来模拟表面位移，然后得到一个修改后的法线值。

2.法线映射：使用一张法线纹理来直接存储表面法线。

我们通常使用 高度图和发现映射一起使用，来修改光照。

法线纹理：

存储的是表面的法线方向，法线方向的分量范围在[-1,1],而像素的分量为[0,1]，因此我们需要一个映射 pixel= (normal+1)/2

这样我们在shader中对法线纹理采样后，还需要来一次反映射，得到原先法线方向。

normal=pixel*2-1

由于法线方向是根据坐标空间来的，那么法线纹理又分为：模型空间的法线纹理 和 切线空间的法线纹理。

模型空间法线纹理：模型顶点自带的法线，此纹理看起来 比较五颜六色

切线空间法线纹理：模型的每个顶点都有一个属于自己的切线空间，该空间的原点 就是顶点自身，z轴 顶点的法线方向，x轴顶点的切线方向，y轴 是由 法线和切线的叉积得到的，也叫做 副切线 或者副法线。此纹理看起来 颜色单一。

 

模型空间法线优点：

1. 实现简单，更加直观

2.可以提供平滑的边界

 

切线空间法线优点：

1.自由度高，记录的是相对法线信息，可以应用到完全不同的网格上。

2.可以进行uv动画。水或者火山熔岩上面

3.可以重用法线纹理

4.可压缩，切线空间下的法线z方向总是正方向，可以仅存储xy，推出z。

所以一般美术 都会使用切线空间下的 法线纹理。

 

由于在计算光照模型的时候，需要统一所在的坐标空间。所以这里有两种方法：

1.在切线空间下进行光照计算，这时需要把光照方向，视角方向变换到切线空间下。

2. 在世界空间下进行光照计算，我们需要把切线空间下的法线方向变换到世界空间，再和世界空间下的光照方向视角方向进行计算。

• 切线空间下

Shader "Custom/TangentOT"
{
    Properties
    {
        _Color("Color",Color)=(1,1,1,1)
        _MainTex("Main Tex",2D)="white" {}
        _BumpMap("Normal Map",2D)="bump" {}
        _BumpScale("Bump Scale",float)=1
        _Specular("Specular",Color)=(1,1,1,1)
        _Gloss("Gloss",Range(8,256))=20
    }

    SubShader
    {
        pass
        {
            Tags{"LightMode"="ForwardBase"}

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "Lighting.cginc"
            fixed4 _Color;
            sampler2D _MainTex;
            float4 _MainTex_ST;
            sampler2D _BumpMap;
            float4 _BumpMap_ST;
            //控制凹凸 度
            float _BumpScale;
            fixed4 _Specular;
            float _Gloss;

            struct a2v
            {
                float4 vertex:POSITION;
                float3 normal:NORMAL;
                float4 texcoord:TEXCOORD0;
                //顶点的切线信息
                float4 tangent:TANGENT;
            };

            struct v2f
            {
                float4 pos:SV_POSITION;
                //存储两套纹理坐标的变量float4
                float4 uv:TEXCOORD0;
                float3 lightDir:TEXCOORD1;
                float3 viewDir:TEXCOORD2;
            };

            v2f vert(a2v v)
            {
                v2f o;
                o.pos=UnityObjectToClipPos(v.vertex);
                //这两个纹理使用同一组纹理坐标，为节省插值寄存器的使用数目
                o.uv.xy=v.texcoord.xy*_MainTex_ST.xy+_MainTex_ST.zw;
                o.uv.zw=v.texcoord.xy*_BumpMap_ST.xy+_BumpMap_ST.zw;
                
                // float3 binormal=cross(normalize(v.normal),normalize(v.tangent.xyz))*v.tangent.w;
                // float3x3 rotation=float3x3(v.tangent.xyz,binormal,v.normal);
                //模型空间到切线空间的变换矩阵
                TANGENT_SPACE_ROTATION;
                
                //转换到切线空间 中 变换矩阵rotation
                o.lightDir=mul(rotation,ObjSpaceLightDir(v.vertex)).xyz;
                o.viewDir=mul(rotation,ObjSpaceViewDir(v.vertex)).xyz;
                return o;              
            }

            fixed4 frag(v2f i):SV_Target
            {
                fixed3 tangentLightDir=normalize(i.lightDir);
                fixed3 tangentViewDir=normalize(i.viewDir);
                //对法线纹理进行采样
                fixed4 packedNormal=tex2D(_BumpMap,i.uv.zw);
                fixed3 tangentNormal;
                
                // tangentNormal.xy=(packedNormal.xy*2-1)*_BumpScale;
                // tangentNormal.z=sqrt(1-saturate(dot(tangentNormal.xy,tangentNormal.xy)));

                tangentNormal=UnpackNormal(packedNormal);  //得到正确的法线方向
                tangentNormal.xy*=_BumpScale;
                tangentNormal.z=sqrt(1-saturate(dot(tangentNormal.xy,tangentNormal.xy)));

                //对纹理进行采样，与颜色属性乘积 来作为材质的反光率albedo
                fixed3 albedo=tex2D(_MainTex,i.uv).rgb*_Color.rgb;
                fixed3 ambient=UNITY_LIGHTMODEL_AMBIENT.xyz*albedo;
                //使用 albedo 来计算漫反射
                fixed3 diffuse=_LightColor0.rgb*albedo*max(0,dot(tangentNormal,tangentViewDir));
                fixed3 halfDir=normalize(tangentLightDir+tangentViewDir);
                fixed3 specular=_LightColor0.rgb*_Specular.rgb*pow(max(0,dot(tangentNormal,halfDir)),_Gloss);
                fixed3 scolor=ambient+diffuse+specular;
                return fixed4(scolor,1);
            }

            ENDCG
        }
    }
    FallBack "Diffuse"
}

• 世界空间下计算光照

Shader "Custom/WorldSpaceOT"
{
     Properties
    {
        _Color("Color",Color)=(1,1,1,1)
        _MainTex("Main Tex",2D)="white" {}
        _BumpMap("Normal Map",2D)="bump" {}
        _BumpScale("Bump Scale",float)=1
        _Specular("Specular",Color)=(1,1,1,1)
        _Gloss("Gloss",Range(8,256))=20
    }

    SubShader
    {
        pass
        {
            Tags{"LightMode"="ForwardBase"}

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "Lighting.cginc"
            fixed4 _Color;
            sampler2D _MainTex;
            float4 _MainTex_ST;
            sampler2D _BumpMap;
            float4 _BumpMap_ST;
            //控制凹凸 度
            float _BumpScale;
            fixed4 _Specular;
            float _Gloss;

            struct a2v
            {
                float4 vertex:POSITION;
                float3 normal:NORMAL;
                float4 texcoord:TEXCOORD0;
                float4 tangent:TANGENT;
            };

            struct v2f
            {
                float4 pos:SV_POSITION;
                //存储两套纹理坐标的变量float4
                float4 uv:TEXCOORD0;
                //存储从切线空间到世界空间的变换矩阵
                float4 Ttow0:TEXCOORD1;
                float4 Ttow1:TEXCOORD2;
                float4 Ttow2:TEXCOORD3;
            };

            v2f vert(a2v v)
            {
                v2f o;
                o.pos=UnityObjectToClipPos(v.vertex);
                o.uv.xy=v.texcoord.xy*_MainTex_ST.xy+_MainTex_ST.zw;
                o.uv.zw=v.texcoord.xy*_BumpMap_ST.xy+_BumpMap_ST.zw;
                
                float3 worldPos=mul(unity_ObjectToWorld,v.vertex).xyz;
                fixed3 worldNormal=UnityObjectToWorldNormal(v.normal);
                fixed3 worldTangent=UnityObjectToWorldDir(v.tangent.xyz);
                fixed3 worldBinormal=cross(worldNormal,worldTangent)*v.tangent.w;

                o.Ttow0=float4(worldTangent.x,worldBinormal.x,worldNormal.x,worldPos.x);
                o.Ttow1=float4(worldTangent.y,worldBinormal.y,worldNormal.y,worldPos.y);
                o.Ttow2=float4(worldTangent.z,worldBinormal.z,worldNormal.z,worldPos.z);

                return o;               
            }

            fixed4 frag(v2f i):SV_Target
            {
                float3 worldPos=float3(i.Ttow0.w,i.Ttow1.w,i.Ttow2.w);
                fixed3 lightDir=normalize(UnityWorldSpaceLightDir(worldPos));
                fixed3 viewDir=normalize(UnityWorldSpaceViewDir(worldPos));

                fixed3 bump=UnpackNormal(tex2D(_BumpMap,i.uv.zw));
                bump.xy*=_BumpScale;
                bump.z=sqrt(1-saturate(dot(bump.xy,bump.xy)));
                bump=normalize(half3(dot(i.Ttow0.xyz,bump),dot(i.Ttow1.xyz,bump),dot(i.Ttow2.xyz,bump)));

                //对纹理进行采样，与颜色属性乘积 来作为材质的反光率albedo
                fixed3 albedo=tex2D(_MainTex,i.uv).rgb*_Color.rgb;
                fixed3 ambient=UNITY_LIGHTMODEL_AMBIENT.xyz*albedo;
                //使用 albedo 来计算漫反射
                fixed3 diffuse=_LightColor0.rgb*albedo*max(0,dot(bump,lightDir));
                fixed3 halfDir=normalize(lightDir+viewDir);
                fixed3 specular=_LightColor0.rgb*_Specular.rgb*pow(max(0,dot(bump,halfDir)),_Gloss);
                fixed3 scolor=ambient+diffuse+specular;
                return fixed4(scolor,1);
            }
            ENDCG
        }
    }
    FallBack "Specular"
}

通过改变凹凸系数 可以看出模型表现效果