7-汇编大小写字符互相转化+[bx+idata]+SI/DI

一、and和or指令

and指令：逻辑与指令，按位进行与运算

通过该指令可将操作对象的相应位设为0，其他位不变。

例如：
将al的第0位设为0的指令是and al,11111110

or指令：逻辑或指令，按位进行或运算

通过该指令可将操作对象的相应位设为1，其他位不变。

例如：
将al的第0位设为1的指令是or al,00000001B

二、字符数据

我们可以在汇编程序中，用’…'的方式指明数据是以字符的形式给出的，编译器会将它们转化为相对应的ASCⅡ码。

如下面的程序：

程序7.1

assume cs:code,ds:data

data segment
	db 'unIX'
	db 'fork'
data ends

code segment

start:	mov al,'a'
		mov bl,'b'
		mov ax,4c00h
		int 21h
		
code ends

end start

上面的程序中db 'unIX'相当于db 75H,6EH,49H,58H，“u”、“n”、“I”、“X”的ASCⅡ码分别为75H、6EH、49H、58H

mov al,'a'相当于mov al,61H，“a”的ASCⅡ码为61H

三、大小写互相转化

考虑这样一个问题，在codesg中填写代码，将dataseg中的第一个字符串转化为大写，第二个字符串转化为小写。

程序框架如下：

assume cs:codesg,ds:datasg

datasg segment
	db 'BaSiC'
	db 'iNfOrMaTiOn'
datasg ends

codesg segment

start:	

codesg ends

end start

需要了解的一个知识点是大写字母的ASCⅡ码比小写字母小32。而大写字母以41H开始表示，小写字母以61H开始表示（41H到61H中间有32个字符，其中包含26个大写字母和6个其他字符），所以表示大写字母的二进制ASCⅡ一定是这样的：0100XXXX或0101XXXX，而表示小写字母的二进制ASCⅡ一定是这样的：0110XXXX或0111XXXX，其中X可以是0或1。所以大写字母中ASCⅡ码中第5位（从第0位开始）一定是0，而小写字母一定是1，所以我们可以利用这一点，并利用and/or进行大小写字母的转换。

assume cs:codesg,ds:datasg

datasg segment
	db 'BaSiC'
	db 'iNfOrMaTiOn'
datasg ends

codesg segment

start:	mov ax,datasg
		mov ds,ax
		mov bx,0
		mov cx,5

	s:	mov al,[bx]
		and al,11011111B		；将al中存储的ASCⅡ码第5位变为0，变为大写字母
		mov [bx],al
		inc bx
		loop s

		mov cx,11
   s0:	mov al,[bx]
   		or al,00100000B
   		mov [bx],al
   		inc bx
   		loop s0

		mov ax,4c00h
		int 21h		

codesg ends

end start

四、[bx+idata]与数组数据处理

用[bx]可以指明一个内存单元，我们还可以用一种更为灵活的方式来指明内存单元：[bx+idata]，它的偏移地址为(bx)+idata。

以一个指令mov ax,[bx+200]为例来进行说明，这个指令的含义是将一个内存单元的内容送入ax，这个内存单元的长度为2个字节（字单元），存放一个字，偏移地址为bx中的数值加上200，段地址在ds中。

数学化的描述为：$(ax)=((ds)\times 16+(bx)+200)$

该指令也可以写成如下格式（常用）：

mov ax,[200+bx]
mov ax,200[bx]
mov ax,[bx].200

有了[bx+idata]这种表示内存单元的方式，我们就可以用更高级的结构来看待所要处理的数据。通过下面的例子来理解这一点：

在codesg中填写代码，将datasg中定义的第一个字符串转化为大写，第二个字符串转化为小写。

assume cs:codesg,ds:datasg

datasg segment
	db 'BaSiC'
	db 'MinIX'
datasg ends

codesg segment

start:

codesg ends

end start

如果使用[bx]的方式定位字符串中的字符。代码段中的程序如下：

	mov ax,datasg
	mov ds,ax
	mov bx,0
	mov cx,5
s:	mov al,[bx]
	and al,11011111b
	mov [bx],al
	inc bx
	loop s
	mov cx,5
s0:	mov al,[bx]
	or al,00100000b
	mov [bx],al
	inc bx
	loop s0

现在我们利用[bx+idata]的方式来简化上面的程序。观察datasg段中的两个字符串，一个起始地址为0，另一个的起始地址为5.我们可以将这两个字符串看作两个数组，一个从0地址开始存放，另一个从5开始存放。那么我们可以用[0+bx]和[5+bx]的方式在同一个循环中定位这两个字符串中的字符。在这里，0和5给定了两个字符串的起始偏移地址，bx中给出了从起始偏移地址开始的相对地址。这两个字符串在内存中的起始地址是不一样的，但是，他们中的每一个字符，从起始地址开始的相对地址的变化是相同的。改进的程序如下：

五、SI和DI

si和di是8086CPU中和bx功能相近的寄存器，si和di不能够分成两个8位寄存器来使用。下面的3组指令实现了相同的功能：

mov bx,0
mov ax,[bx]

mov si,0
mov ax,[si]

mov di,0
mov ax,[di]

下面的3组指令也实现了相同的功能：

mov bx,0
mov ax,[bx+123]

mov si,0
mov ax,[si+123]

mov di,0
mov ax,[di+123]

六、[bx+si]和[bx+di]

在前面，我们用[bx(si或di)]和[bx(si或di)+idata]的方式来指明一个内存单元，我们还可以用更为灵活的方式：[bx+si]和[bx+di]。

[bx+si]和[bx+di]的含义相似，以下以[bx+si]为例进行讲解。

[bx+si]表示一个内存单元，它的偏移地址为(bx)+(si)（即bx中的数值加上si中的数值）

指令mov ax,[bx+si]的含义如下：
将一个内存单元的内容送入ax，这个内存单元的长度为2字节（字单元），存放一个字，偏移地址为bx中的数值加上si中的数值，段地址在ds中。

该指令也可以写成如下格式（常用）：

mov ax,[bx][si]

七、[bx+si+idata]和[bx+di+idata]

[bx+si+idata]和[bx+di+idata]的含义相似，表示一个内存单元，偏移地址为(bx)+(si)+idata。

指令mov ax,[bx+si+idata]还可以写成：

mov ax,[bx+200+si]
mov ax,[200+bx+si]
mov ax,200[bx][si]
mov ax,[bx].200[si]
mov ax,[bx][si].200

八、不同寻址方式的灵活应用

总结一下，我们有如下的寻址方式：

• [idata]用一个常量来表示地址，可用于直接定位一个内存单元
• [bx]用一个变量来表示内存地址，可用于间接定位一个内存单元
• [bx+idata]用一个变量和常量表示地址，可在一个起始地址的基础上用变量间接定位一个内存单元
• [bx+si]用两个变量表示地址
• [bx+si+idata]用两个变量和一个常量表示地址

可以看到，从[idata]一直到[bx+si+idata]，我们可以用更加灵活的方式来定位一个内存单元的地址。这使我们可以从更加结构化的角度来看待所要处理的数据。

接下来通过一些例子，来体会下结构化寻址方式的好处：

例一：编程，将datasg段中每个单词的头一个字母改成大写字母

assume cs:codesg,ds:datasg

datasg segment
	db '1.file		'
	db '2.edit		'
	db '3.search	'
	db '4.view		'
	db '5.options	'
	db '6.help		'
datasg ends

codesg segment

start:

codesg ends

end start

分析：

datasg中，数据的存储结构如下：

可以看出，在datasg中定义了6个字符串，每个长度为16个字节（添加了空格来对齐）。

所以处理程序如下：

	mov ax,datasg
	mov ds,ax
	mov bx,0

	mov cx,6
	
s:	mov al,[bx+3]
	and al,11011111b
	mov [bx+3],al
	add bx,16
	loop s

例二：编程，将datasg段中每个单词改为大写字母

assume cs:codesg,ds:datasg

datasg segment
	db 'ibm			'
	db 'dec			'
	db 'dos         '
	db 'vax			'
datasg ends

codesg segment

start:

codesg ends

end start

分析：

datasg中的数据的存储结构如下所示：

程序如下：

assume cs:codesg,ds:datasg,ss:stacksg

datasg segment
	db 'ibm			'
	db 'dec			'
	db 'dos         '
	db 'vax			'
datasg ends

stacksg segment
	dw 0,0,0,0,0,0,0,0
stacksg ends

codesg segment

start:	mov ax,stacksg
		mov ss,ax
		mov sp,16
		mov ax,datasg
		mov ds,ax
		mov bx,0

		mov cx,4

   s0:	push cx
   		mov si,0
   		mov cx,3

	s:	mov al,[bx+si]
		and al,11011111b
		mov [bx+si],al
		inc si
		loop s
		add bx,16
		pop cx
		loop s0

		mov ax,4c00h
		int 21h


codesg ends

end start