Shader描边

在视空中挤出或沿法线挤出一点就可以得到一个物体的描边，但是如果模犁很复杂,有些地方继续要按照法线方向挤出,有些方向却需要按照顶点方向挤出， 因些需要判定什么时候顶点方向指向几何中心,什么时候背离它，通过顶点和法线的点乘就可以知道指向还是背离几何中心

Shader "Custom/Outline" {
	Properties 
	{
		_OutlineColor ("OutlineColor", Color) = (1,1,1,1)
		_OutlineSize ("OutlineSize", range(0,2)) = 0.2
		_Factor ("Factor", range(0,1)) = 0.5
		_MainTex ("Albedo (RGB)", 2D) = "white" {}
	}
	SubShader 
	{
		Pass 
		{
			Tags { "LightMode" = "Always" }
			Cull Front
			ZWrite On
			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag 
			#include "UnityCG.cginc" 
			float4 _OutlineColor;
			float _OutlineSize;
			float _Factor;
			struct v2f
			{
				float4 pos : SV_POSITION;
				float2 uv : TEXCOORD0;
				float4 color : TEXCOORD1; 
			}; 

			v2f vert(appdata_base v)
			{
				v2f o;
				o.color = _OutlineColor;
				o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
				float3 dir = normalize(v.vertex.xyz);
				float3 dir2 = v.normal;
				float D = dot(dir, dir2);
				D = (D / _Factor + 1) / (1 + 1 / _Factor);
				dir = lerp(dir2, dir, D);
				dir = mul((float3x3)UNITY_MATRIX_IT_MV, dir);
				float2 offset = TransformViewToProjection(dir.xy);
				offset = normalize(offset);
				o.pos.xy += offset * _OutlineSize;
				return o;
			}

			fixed4 frag(v2f i):COLOR
			{
				return i.color;
			}
			ENDCG 
		}
		Pass 
		{
			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			#include "UnityCG.cginc"
			sampler2D _MainTex;
			float4 _MainTex_ST;
			struct v2f
			{
				float4 pos : SV_POSITION;
				float2 uv : TEXCOORD0; 
			};  

			v2f vert(appdata_base v)
			{
				v2f o;
				o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
				o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
				return o;
			}

			fixed4 frag(v2f i):COLOR
			{
				float4 c = tex2D(_MainTex, i.uv);
				return c;
			}

			ENDCG
		}
	} 
	FallBack "Diffuse"
}