【FPGA零基础学习之旅#12】三线制数码管驱动（74HC595）串行移位寄存器驱动

已于 2023-09-10 13:11:11 修改
阅读量1.5k 收藏 26
点赞数 18
分类专栏： FPGA学习之旅 文章标签： fpga开发 学习 Vrilog HDL 74HC595 三线制数码管 FPGA
于 2023-09-03 22:52:03 首次发布
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/m0_56262476/article/details/132655030
版权

🎉欢迎来到FPGA专栏~三线制数码管驱动

  • ☆* o(≧▽≦)o *☆嗨~我是小夏与酒🍹
  • ✨博客主页：小夏与酒的博客
  • 🎈该系列文章专栏：FPGA学习之旅
  • 文章作者技术和水平有限，如果文中出现错误，希望大家能指正🙏
  • 📜 欢迎大家关注！ ❤️
    FPGQ2

CSDN

🎉 目录-三线制数码管驱动

遇见未来

一、效果演示

🥝ISSP调试演示：
程序配置完成：
程序配置

调试：
测试结果

🥝按键控制演示：
按键控制

二、电路结构

在三线制的数码管驱动中，使用74HC595芯片来减少FPGA的管脚数量使用。

关于74HC595芯片的介绍和时序图，参考文章：74HC595介绍 和 74HC595 驱动。

在AC620开发板上的数码管驱动电路：
电路1
AC620开发板使用的是74HC595芯片的级联来驱动显示：
电路2

三、代码详解

3.1 总体结构设计

先上RTL视图：
RTL
HEX8模块将seg和sel信号传给m74HC595_Driver模块，然后将接收到的信号转换为DS、SH_CP和ST_CP信号；ISSP模块用于调试。

3.2 驱动74HC595芯片

关于74HC595芯片的驱动，主要参考该时序图进行代码编写：
时序图

74HC595是8位串行移位寄存器，带有存储寄存器和三态寄存器，其中移位寄存器和存储寄存器分别采用不同的时钟。其可以把串行的信号转为并行的信号，因此常用做各种数码管以及点阵屏的驱动芯片。

该芯片的主要IO：

IO名称功能
DS / SER串行数据输入端
STCP / RCK存储寄存器的时钟输入。上升沿时移位寄存器中的数据进入存储寄存器，下降沿时存储寄存器中的数据保持不变。应用时通常将 ST_CP 置为低点平，移位结束后再在 ST_CP 端产生一个正脉冲更新显示数据。
SHCP / SCK移位寄存器的时钟输入。上升沿时移位寄存器中的数据依次移动一位，即 Q0 中的数据移到 Q1 中，Q1 中的数据移到 Q2 中，依次类推；下降沿时移位寄存器中的数据保持不变。

由于在AC620开发板中芯片采用3.3V供电，这样在设计74HC595工作频率时，直接使用50M晶振四分频后的时钟作为其工作时钟。

74HC595的驱动代码，由于模块命名不能以数字开头，所以加了个m：

m74HC595_Driver.v：

module m74HC595_Driver(
		Clk,
		Rst_n,
		Data,
		S_EN,
		SH_CP,	//SCK
		ST_CP,	//RCK
		DS		//Data
	);

	parameter DATA_WIDTH = 16;

	input 		Clk;
	input 		Rst_n;
	input 		[DATA_WIDTH-1 : 0] Data;	//data to send
	input 		S_EN;						//send en
	output reg 	SH_CP;						//shift clock
	output reg 	ST_CP;						//latch data clock
	output reg 	DS;							//shift serial data
	
	parameter CNT_MAX = 4;
		
	reg [15:0] divider_cnt;//分频计数器
	wire sck_pluse;
	
	reg [4:0]SHCP_EDGE_CNT;//SH_CP EDGE counter
	
	reg [15:0]r_data;
	
	always@(posedge Clk or negedge Rst_n)begin
		if(!Rst_n)
			r_data <= 16'd0;
		else if(S_EN)
			r_data <= Data;
		else
			r_data <= r_data;
	end
		
	//clock divide
	always@(posedge Clk or negedge Rst_n)begin
		if(!Rst_n)
			divider_cnt <= 16'd0;
		else if(divider_cnt == CNT_MAX)
			divider_cnt <= 16'd0;
		else
			divider_cnt <= divider_cnt + 1'b1;
	end
	
	assign sck_pluse = (divider_cnt == CNT_MAX);
	
	always@(posedge Clk or negedge Rst_n)begin
		if(!Rst_n)
			SHCP_EDGE_CNT <= 5'd0;
		else if(sck_pluse)begin
			if(SHCP_EDGE_CNT ==  5'd31)
				SHCP_EDGE_CNT <= 5'd0;
			else
				SHCP_EDGE_CNT <= SHCP_EDGE_CNT + 1'b1;
		end
		else
			SHCP_EDGE_CNT <= SHCP_EDGE_CNT;
	end	
		
	always@(posedge Clk or negedge Rst_n)begin
		if(!Rst_n)begin
			SH_CP <= 1'b0;
			ST_CP <= 1'b0;
			DS <= 1'b0;	
		end
		else begin
			case(SHCP_EDGE_CNT)
				5'd0: begin SH_CP <= 1'b0; ST_CP <= 1'b1; DS <= r_data[15]; end
				5'd1: begin SH_CP <= 1'b1; ST_CP <= 1'b0;end
				5'd2: begin SH_CP <= 1'b0; DS <= r_data[14];end
				5'd3: begin SH_CP <= 1'b1; end
				5'd4: begin SH_CP <= 1'b0; DS <= r_data[13];end
				5'd5: begin SH_CP <= 1'b1; end
				5'd6: begin SH_CP <= 1'b0; DS <= r_data[12];end
				5'd7: begin SH_CP <= 1'b1; end
				5'd8: begin SH_CP <= 1'b0; DS <= r_data[11];end
				5'd9: begin SH_CP <= 1'b1; end
				5'd10:begin SH_CP <= 1'b0; DS <= r_data[10];end
				5'd11:begin SH_CP <= 1'b1; end
				5'd12:begin SH_CP <= 1'b0; DS <= r_data[9];end
				5'd13:begin SH_CP <= 1'b1; end
				5'd14:begin SH_CP <= 1'b0; DS <= r_data[8];end
				5'd15:begin SH_CP <= 1'b1; end
				5'd16:begin SH_CP <= 1'b0; DS <= r_data[7];end
				5'd17:begin SH_CP <= 1'b1; end
				5'd18:begin SH_CP <= 1'b0; DS <= r_data[6];end
				5'd19:begin SH_CP <= 1'b1; end
				5'd20:begin SH_CP <= 1'b0; DS <= r_data[5];end
				5'd21:begin SH_CP <= 1'b1; end
				5'd22:begin SH_CP <= 1'b0; DS <= r_data[4];end
				5'd23:begin SH_CP <= 1'b1; end
				5'd24:begin SH_CP <= 1'b0; DS <= r_data[3];end
				5'd25:begin SH_CP <= 1'b1; end
				5'd26:begin SH_CP <= 1'b0; DS <= r_data[2];end
				5'd27:begin SH_CP <= 1'b1; end
				5'd28:begin SH_CP <= 1'b0; DS <= r_data[1];end
				5'd29:begin SH_CP <= 1'b1; end
				5'd30:begin SH_CP <= 1'b0; DS <= r_data[0];end
				5'd31:begin SH_CP <= 1'b1; end
				default:begin SH_CP <= 1'b0;ST_CP <= 1'b0;DS <= 1'b0;	end
			endcase	
		end
	end

endmodule

RTL视图：

RTL74

3.3 HEX8模块

该模块的设计是在该文章的讲解基础之上进行修改：【FPGA零基础学习之旅#11】数码管动态扫描。

上述参考文章中的模块可以称为HEX6，驱动了6个数码管，在此我们需要驱动8个数码管，故可以将模块命名为HEX8。

需要注意的是，在设计数码管位选的时候，一定要看清使用板子的电路结构，弄清楚是高电平位选还是低电平位选！

HEX8.v：

module HEX8(
		input 					Clk,		//50M
		input 					Rst_n,		//复位
		input 					En,			//数码管显示使能
		input 		[31:0]		disp_data,	//8 × 4 = 32（8个数码管，数据格式为hex，总共输32位）
		output reg 	[7:0]		seg, 		//数码管段选
		output 		[7:0]		sel	 		//数码管位选（数码管选择）
);
	reg [7:0]sel_r;

//--------<分频器>--------
	reg [14:0]divider_cnt;//25000-1
	
	reg clk_1K;
	
	reg [3:0]data_tmp;//待显示数据缓存
	
	//1KHz分频计数器
	always@(posedge Clk or negedge Rst_n)begin
		if(!Rst_n)
			divider_cnt <= 15'd0;
		else if(!En)
			divider_cnt <= 15'd0;
		else if(divider_cnt == 24999)
			divider_cnt <= 15'd0;
		else
			divider_cnt <= divider_cnt + 1'b1;
	end
	
	//1KHz扫描时钟
	always@(posedge Clk or negedge Rst_n)begin
		if(!Rst_n)
			clk_1K <= 1'b0;
		else if(divider_cnt == 24999)
			clk_1K <= ~clk_1K;
		else
			clk_1K <= clk_1K;
	end
	
//--------<6位循环移位寄存器>--------	
	always@(posedge clk_1K or negedge Rst_n)begin
		if(!Rst_n)
			sel_r <= 8'b0000_0001;
		else if(sel_r == 8'b1000_0000)
			sel_r <= 8'b0000_0001;
		else
			sel_r <= sel_r << 1;
	end	

//--------<6选1多路器>--------		
	always@(*)begin
		case(sel_r)
			8'b0000_0001:data_tmp = disp_data[3:0];
			8'b0000_0010:data_tmp = disp_data[7:4];
			8'b0000_0100:data_tmp = disp_data[11:8];
			8'b0000_1000:data_tmp = disp_data[15:12];
			8'b0001_0000:data_tmp = disp_data[19:16];
			8'b0010_0000:data_tmp = disp_data[23:20];
			8'b0100_0000:data_tmp = disp_data[27:24];
			8'b1000_0000:data_tmp = disp_data[31:28];
			default:data_tmp = 4'b0000;
		endcase
	end

//--------<LUT>--------		
	always@(*)begin
		case(data_tmp)
			4'h0:seg = 8'hc0;
			4'h1:seg = 8'hf9;
			4'h2:seg = 8'ha4;
			4'h3:seg = 8'hb0;
			4'h4:seg = 8'h99;
			4'h5:seg = 8'h92;
			4'h6:seg = 8'h82;
			4'h7:seg = 8'hf8;
			4'h8:seg = 8'h80;
			4'h9:seg = 8'h90;
			4'ha:seg = 8'h88;
			4'hb:seg = 8'h83;
			4'hc:seg = 8'hc6;
			4'hd:seg = 8'ha1;
			4'he:seg = 8'h86;
			4'hf:seg = 8'h8e;
		endcase
	end
		
//--------<2选1多路器>--------		
	assign sel = (En)?(sel_r):8'b1111_1111;
		
endmodule

3.4 顶层模块

在顶层模块中需要调用ISSP这样的一个IP核，操作过程和调试方法参考：【FPGA零基础学习之旅#11】数码管动态扫描。

smg.v：

module smg(
	input 			Clk,		//50M
	input 			Rst_n,
	//input [31:0] 	disp_data,
	output 			SH_CP,		//shift clock
	output 			ST_CP,		//latch data clock
	output 			DS			//shift serial data
);
	
	wire [7:0] sel;//数码管位选（选择当前要显示的数码管）
	wire [7:0] seg;//数码管段选（当前要显示的内容）	

	wire  [31:0] disp_data;
	
	ISSP UISSP(
		.probe(),
		.source(disp_data)
	);
		
	HEX8 UHEX8(
		.Clk(Clk),
		.Rst_n(Rst_n),
		.En(1'b1),
		.disp_data(disp_data),
		.sel(sel),
		.seg(seg)
	);
		
	m74HC595_Driver Um74HC595_Driver(
		.Clk(Clk),
		.Rst_n(Rst_n),
		.Data({seg,sel}),
		.S_EN(1'b1),
		.SH_CP(SH_CP),
		.ST_CP(ST_CP),
		.DS(DS)
	);
	
endmodule

四、按键控制改变数据值

项目要求： 通过控制按键，使得数码管显示不同的数据内容。

实现效果：
实现效果
先看RTL视图来理解整体框架：
RTL3
按下按键1，数码管显示12345678；按下按键2，数码管显示89abcdef。

按键消抖模块的设计参考该文章：【FPGA零基础学习之旅#10】按键消抖模块设计与验证（一段式状态机实现）。

在此贴出按键消抖的代码：

KeyFilter.v：

//
//模块：按键消抖模块
//key_state：输出消抖之后按键的状态
//key_flag：按键消抖结束时产生一个时钟周期的高电平脉冲
//
module KeyFilter(
	input Clk,
	input Rst_n,
	input key_in,
	output reg key_flag,
	output reg key_state
);

	//按键的四个状态
	localparam
		IDLE 		= 4'b0001,
		FILTER1 	= 4'b0010,
		DOWN 		= 4'b0100,
		FILTER2 	= 4'b1000;

	//状态寄存器
	reg [3:0] curr_st;
	
	//边沿检测输出上升沿或下降沿
	wire pedge;
	wire nedge;
	
	//计数寄存器
	reg [19:0]cnt;
	
	//使能计数寄存器
	reg en_cnt;
	
	//计数满标志信号
	reg cnt_full;//计数满寄存器
	
//------<边沿检测电路的实现>------
	//边沿检测电路寄存器
	reg key_tmp0;
	reg key_tmp1;
	
	//边沿检测
	always@(posedge Clk or negedge Rst_n)begin
		if(!Rst_n)begin
			key_tmp0 <= 1'b0;
			key_tmp1 <= 1'b0;
		end
		else begin
			key_tmp0 <= key_in;
			key_tmp1 <= key_tmp0;
		end	
	end
		
	assign nedge = (!key_tmp0) & (key_tmp1);
	assign pedge = (key_tmp0)  & (!key_tmp1);

//------<状态机主程序>------	
	//状态机主程序
	always@(posedge Clk or negedge Rst_n)begin
		if(!Rst_n)begin
			curr_st <= IDLE;
			en_cnt <= 1'b0;
			key_flag <= 1'b0;
			key_state <= 1'b1;
		end
		else begin
			case(curr_st)
				IDLE:begin
					key_flag <= 1'b0;
					if(nedge)begin
						curr_st <= FILTER1;
						en_cnt <= 1'b1;
					end
					else
						curr_st <= IDLE;
				end
				
				FILTER1:begin
					if(cnt_full)begin
						key_flag <= 1'b1;
						key_state <= 1'b0;
						curr_st <= DOWN;
						en_cnt <= 1'b0;
					end	
					else if(pedge)begin
						curr_st <= IDLE;
						en_cnt <= 1'b0;
					end
					else
						curr_st <= FILTER1;
				end
				
				DOWN:begin
					key_flag <= 1'b0;
					if(pedge)begin
						curr_st <= FILTER2;
						en_cnt <= 1'b1;
					end
					else
						curr_st <= DOWN;
				end
				
				FILTER2:begin
					if(cnt_full)begin
						key_flag <= 1'b1;
						key_state <= 1'b1;
						curr_st <= IDLE;
						en_cnt <= 1'b0;
					end	
					else if(nedge)begin
						curr_st <= DOWN;
						en_cnt <= 1'b0;
					end
					else
						curr_st <= FILTER2;
				end
				
				default:begin
					curr_st <= IDLE;
					en_cnt <= 1'b0;
					key_flag <= 1'b0;
					key_state <= 1'b1;
				end
			endcase
		end
	end
	
//------<20ms计数器>------		
	//20ms计数器
	//Clk 50_000_000Hz
	//一个时钟周期为20ns
	//需要计数20_000_000 / 20 = 1_000_000次
	
	always@(posedge Clk or negedge Rst_n)begin
		if(!Rst_n)
			cnt <= 20'd0;
		else if(en_cnt)
			cnt <= cnt + 1'b1;
		else
			cnt <= 20'd0;
	end
	
	always@(posedge Clk or negedge Rst_n)begin
		if(!Rst_n)
			cnt_full <= 1'b0;
		else if(cnt == 999_999)
			cnt_full <= 1'b1;
		else
			cnt_full <= 1'b0;
	end
	
endmodule

简单编写了一个KeyData模块用于不同数据的输入：

KeyData.v：

module KeyData(
	input Clk,
	input Rst_n,
	input Key_state1,
	input Key_flag1,
	input Key_state2,
	input Key_flag2,
	output reg [31:0] dis_data
);

	always@(posedge Clk or negedge Rst_n)begin
		if(!Rst_n)
			dis_data <= 32'h00000000;
		else if(Key_flag1 && !Key_state1)
			dis_data <= 32'h12345678;
		else if(Key_flag2 && !Key_state2)
			dis_data <= 32'h89abcdef;
		else 
			dis_data <= dis_data;
	end

endmodule

顶层模块KeyCtrlSmg.v：

module KeyCtrlSmg(
	input 	Clk,
	input 	Rst_n,
	input 	KeyIn1,
	input 	KeyIn2,
	output 	SH_CP,		//shift clock
	output 	ST_CP,		//latch data clock
	output 	DS			//shift serial data
);

	wire key_state1;
	wire key_flag1;
	wire key_state2;
	wire key_flag2;
	
	wire [7:0] sel;//数码管位选（选择当前要显示的数码管）
	wire [7:0] seg;//数码管段选（当前要显示的内容）	

	wire  [31:0] dis_data;
	
	KeyFilter KeyFilter1(
		.Clk(Clk),
		.Rst_n(Rst_n),
		.key_in(KeyIn1),
		.key_flag(key_flag1),
		.key_state(key_state1)
	);
	
	KeyFilter KeyFilter2(
		.Clk(Clk),
		.Rst_n(Rst_n),
		.key_in(KeyIn2),
		.key_flag(key_flag2),
		.key_state(key_state2)
	);

	KeyData UKeyData(
		.Clk(Clk),
		.Rst_n(Rst_n),
		.Key_state1(key_state1),
		.Key_flag1(key_flag1),
		.Key_state2(key_state2),
		.Key_flag2(key_flag2),
		.dis_data(dis_data)
	);

	HEX8 UHEX8(
		.Clk(Clk),
		.Rst_n(Rst_n),
		.En(1'b1),
		.disp_data(dis_data),
		.sel(sel),
		.seg(seg)
	);
		
	m74HC595_Driver Um74HC595_Driver(
		.Clk(Clk),
		.Rst_n(Rst_n),
		.Data({seg,sel}),
		.S_EN(1'b1),
		.SH_CP(SH_CP),
		.ST_CP(ST_CP),
		.DS(DS)
	);

endmodule

测试激励文件：

`timescale 1ns/1ns
`define clock_period 20

module KeyCtrlSmg_tb;

	reg Clk;
	reg Rst_n;
	reg KeyIn1;
	reg KeyIn2;
	
	wire SH_CP;
	wire ST_CP;
	wire DS;

	KeyCtrlSmg UKeyCtrlSmg(
		.Clk(Clk),
		.Rst_n(Rst_n),
		.KeyIn1(KeyIn1),
		.KeyIn2(KeyIn2),
		.SH_CP(SH_CP),		//shift clock
		.ST_CP(ST_CP),		//latch data clock
		.DS(DS)				//shift serial data
	);

	initial Clk = 1;
	always#(`clock_period / 2) Clk = ~Clk;
	
	initial begin 
		Rst_n = 0;
		KeyIn1 = 1;
		KeyIn2 = 1;
		#200;
		Rst_n = 1;
		#200;
		KeyIn1 = 0;
		KeyIn2 = 1;
		#(`clock_period*10000)
		KeyIn1 = 1;
		KeyIn2 = 1;
		#(`clock_period*10000)
		KeyIn1 = 1;
		KeyIn2 = 0;
		#(`clock_period*10000)
		$stop;
	end


endmodule

仿真结果：

仿真结果

csdn

🧸结尾

小夏与酒
关注
  • 18
    点赞
  • 踩
  • 26
    收藏
    觉得还不错? 一键收藏
  • 打赏
    打赏
  • 25
    评论
专栏目录
74HC595（共阴共阳数码管驱动电路）
01-08
74HC595（数码管驱动电路），可驱动共阴共阳数码管， 只须更改段码，可串接多个74HC595驱动多个数码管
SPI驱动----74HC595操作数码管
xiupong的博客
03-05 4623
SPI-----74HC595操作数码管前言一、用户态SPI编程1、设备打开和关闭2、总线控制3、示例程序代码：二、驱动层SPI编程1、SPI 驱动架构简析2、注册spi设备3、编写spi设备驱动4、示例代码 前言 通过SPI与从机74HC595驱动数码管有两种实现方法： ①、用户态SPI编程来实现 ②、驱动层SPI编程来实现 一、用户态SPI编程 用户态SPI编程是基于平台已编写好的SPI驱动来进行的，跟I2C用户态编程类似，把spi当做一个设备进行操作。 Linux 的 SPI 总线设备文件名通常.
RT-Thread与cubemx|74HC595驱动数码管详解
qq_16519885的博客
07-04 1086
Part1 74HC595简介 74HC595是一个8位串行输入、并行输出的位移缓存器：并行输出为三态输出。在SCK 的上升沿，串行数据由SDL输入到内部的8位位移缓存器，并由Q7'输出，而并行输出则是在LCK的上升沿将在8位位移缓存器的数据存入到8位并行输出缓存器。当串行数据输入端OE的控制信号为低使能时，并行输出端的输出值等于并行输出缓存器所存储的值。 74HC595是具有三态输出功能（即具有高电平、低电平和高阻抗三种输出状态）的门电路。输出寄存器可以直接清除。具有100MHz的移位频率。 引脚介
【STM32+HAL+Proteus】系列学习教程---74HC595驱动数码管
luojuan198780的专栏
03-12 1509
74HC595的数据来源于14脚，一次只能输入一个位，那么连续输入8次，就可以积攒为一个字节了。假如，我们要将二进制数据0111 1111 输入到74HC595的移位寄存器中，下面来上一张动态图，模拟了前2个位输入的情景。8位数据输入完成后，给12脚一个上升沿，数据从位移寄存器转移到存储寄存器。
3位6脚数码管驱动
c1278943913的博客
12-16 2918
数码管复用
74HC595驱动数码管显示模块使用说明
qq_44881094的博客
03-02 1万+
基于74HC595串行动态数码管显示 一、74HC595简介 74HC595是一个8位串行输入、平行输出的位移缓存器：平行输出为三态输出。在SCK的上升沿，单行数据由SDL输人到内部的8位位移缓存器，并由Q7‘输出，而平行输出则是在LCK的上升沿将在8位位移缓存器的数据存人到8位平行输出缓存器。当串行数据输人端OE的控制信号为低使能时，平行输出端的输出值等于平行输出缓存器所存储的值。而当OE为高电位，也就是输出关闭时，平行输出端会维持在高阻抗状态。 　　串行输入，并行输出。 　　 符号 引脚 描述
树梅派应用20：树莓派GPIO入门08-使用74HC595芯片驱动数码管（一）
shenghua
10-17 1286
树梅派应用20：树莓派GPIO入门08-使用74HC595芯片驱动数码管（一）http://blog.csdn.net/huayucong/article/details/53750169 前面几篇我们学习了如何利用一片或多片级联的74HC595芯片来驱动显示数码管的方法。最开始我们提出的两个问题： 占用IO口过多做动态扫描时占用CPU资源太多导致显示不稳定 第一个问题已
FPGA驱动74HC595实现数码管动态显示
fpga学就完事了
09-30 5643
FPGA驱动74HC595实现数码管动态显示，编写74hc595驱动以及顶层驱动，只需传入6个4位bcd码即可实现数码管的动态显示。
74HC595驱动四位数码管
热门推荐
liu___bai的博客
11-30 1万+
74HC595驱动四位数码管 数码管编码 出处 硬件原理图 出处 驱动程序 出处 1.数码管编码介绍 它每一段是一个发光二极管，排成一个“日”字形。通过控制某几段发光二极管的发光来显示数字0~9或字母A、B、C、D…。通常有8个发光二极管，其中七个为日字型，另外一个发光二极管表示小数点。如图1所示，如a、b、g、e、d段亮显示2；f、b、e、c、g段亮显示H。注意：dp段表示右下角的小数点。 连接分为共阳极和共阴极两种接法。（1）共阳极数码管所有发光二极管阳极连在一起，接高电平。而阴极通过串联一
74LS595 74HC595使用方法以及驱动数码管显示(附：使用代码)
qq_41818650的博客
05-21 3145
74LS595 74HC595 驱动数码管
15.[STM32]一篇文章教会你使用75HC595芯片驱动四位数码管
依点_DW的博客
05-10 1万+
74HC595驱动四位数码管
74HC595 驱动
zhuimeng_ruili的博客
01-12 3024
目录 一、芯片介绍 二、驱动电路 三、驱动程序 四、实测波形 一、芯片介绍 本例使用的芯片为飞利浦的74HC595芯片 该芯片支持100M的操作频率 各个pin脚的定义 Q0~Q7: 并行数据数据输出端; GND: 接地引脚; Q7S: 串行数据输出(多芯片级联时使用); MR: 复位引脚,当引脚接低电平时芯片内部数据存储寄存器数据清零复位.如不使用一般接高电平; SHCP: 移位寄存器的时钟输入,当接收到上升沿时移位寄存器内部数据整体后移; STCP: 数据..
74HC595驱动程序
07-14
74HC595时序图如下 #include//52芯片管脚定义头文件 #include//内部包含延时函数 _nop_(); #define uchar unsigned char #define uint unsigned int uchar code DAT[8]={0xfe,0xfd,0xfb,0xf7,0xef,0xdf,0xbf,0x7f}; sbit SDATA_595=P1^0; //串行数据输入 sbit SCLK_595 =P1^1; //移位时钟脉冲 sbit RCK_595 =P1^2; //输出锁存器控制脉冲 uchar temp; void delay(int ms) { int k; while(ms--) { for(k=0; k<250; k++) { _nop_(); _nop_(); _nop_(); _nop_(); } } } void WR_595(void) { uchar j; for (j=0;j<8;j++) { temp=temp<<1 ; SDATA_595=CY;
基于FPGA的74HC595驱动数码管动态显示--Verilog实现
08-10
基于FPGA的74HC595驱动数码管动态显示--Verilog实现.由FPGA控制74HC595驱动数码管其实主要是抓住74HC595的控制时序，进而输出所需控制显示的内容，由同步状态机实现.
74hc595驱动 并串转换模块 状态机
03-07
可以驱动两篇hc595级联的并串转换模块。用来数码管显示。并且支持逗号单独控制。使用VHDL并采用状态机编写。有说明。易懂。
单片机c语言编程，74HC573驱动数码管仿真
04-30
单片机c语言编程，74HC573驱动数码管仿真
基于FPGA的三线制同步串行通信控制器设计
01-19
摘 要： 为了简化应用系统中的三线制同步串行通信扩展接口，减小系统体积，降低系统功耗，通过研究三线制同步串行通信的原理，利用FPGA，结合硬件描述语言VHDL，设计了三线制同步串行通信控制器功能框架结构，介绍...
74HC595驱动数码管显示
08-23
基于74HC595的驱动4为数码管从0000----9999顺序显示，注释具体
基于FPGA的数字信号处理（9）--定点数据的两种溢出处理模式：饱和（Saturate）和绕回（Wrap）
最新发布
孤独的单刀
05-06 1150
定点数据的两种溢出处理模式：饱和（Saturate）和绕回（Wrap）
我用一个fpga的IO作时钟驱动60块74hc595的sclk时钟可以吗
05-05
在理论上，你可以使用FPGA的IO作为时钟驱动。但是，需要注意的是，如果你要驱动60个74hc595芯片，则每个芯片的输出需要连接到下一个芯片的输入。这将导致延迟和信号失真，因此需要进行仔细的设计和测试以确保正确的功能。此外，您还需要考虑时钟频率和占空比，以确保芯片的稳定工作。如果您不熟悉FPGA和数字电路设计，建议您寻求专业人员的帮助。

“相关推荐”对你有帮助么？

  • 非常没帮助
  • 没帮助
  • 一般
  • 有帮助
  • 非常有帮助
提交
评论 25
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包

打赏作者

小夏与酒

你的鼓励将是我创作的最大动力

¥1 ¥2 ¥4 ¥6 ¥10 ¥20
扫码支付：¥1
获取中
扫码支付

您的余额不足，请更换扫码支付或充值

打赏作者

实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值