我的前老板告诉我,shader要想做好,就要多看多记。
初学sahder,自然想看看大佬们的shader都是怎么写的。虽然程序员只需要ctrl+c ctrl+v就可以编程,但是我还是想细致理解其中的过程,在看这个雷达波的shader中感觉学到了很多东西,特此记录。接上一篇。依然是这个雷达波的shader。
首先,贴上大佬的链接:
http://www.manew.com/thread-105501-1-1.html
然后开始拾大佬的牙慧。
大佬的总体思路是,先实现一个球的边缘会发光,然后在考虑与别的物体相交边缘高亮,然后再加上一些扭曲。这个shader就完成了。
我直接把每一行代码都加上注释,详细的解释这些代码。
/*
Created by chenjd
http://www.cnblogs.com/murongxiaopifu/
*/
Shader "chenjd/ForceField"
{
Properties
{
_Color("Color", Color) = (0,0,0,0)
_NoiseTex("NoiseTexture", 2D) = "white" {}
_DistortStrength("DistortStrength", Range(0,1)) = 0.2
_DistortTimeFactor("DistortTimeFactor", Range(0,1)) = 0.2
_RimStrength("RimStrength",Range(0, 10)) = 2
_IntersectPower("IntersectPower", Range(0, 3)) = 2
}
SubShader
{
ZWrite Off
Cull Off
Blend SrcAlpha OneMinusSrcAlpha
Tags
{
"RenderType" = "Transparent"
"Queue" = "Transparent"
}
/*通过GrabPass定义了一个抓取屏幕图像的Pass,
在这个Pass中定义了一个字符串,该字符串决定了抓到的图像会存储到哪一张纹理中
就是存到了sampler2D _GrabTempTex;这个里面*,这里在扭曲里会用到*/
GrabPass
{
"_GrabTempTex"
}
Pass
{
CGPROGRAM
#pragma target 3.0
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
struct appdata
{
float4 vertex : POSITION;
float2 uv : TEXCOORD0;
float3 normal : NORMAL;
};
struct v2f
{
float4 vertex : SV_POSITION;
float2 uv : TEXCOORD0;
float4 screenPos : TEXCOORD1;
float4 grabPos : TEXCOORD2;
float3 normal : NORMAL;
float3 viewDir : TEXCOORD3;
};
sampler2D _GrabTempTex;
float4 _GrabTempTex_ST;
sampler2D _NoiseTex;
float4 _NoiseTex_ST;
float _DistortStrength;
float _DistortTimeFactor;
float _RimStrength;
float _IntersectPower;
//通过声明_CameraDepthTexture变量来访问摄像机的深度纹理,摄像机也要有这么一个设置camera.depthTextureMode=DepthTextureMode.Depth
sampler2D _CameraDepthTexture;
v2f vert(appdata v)
{
v2f o;
o.vertex = UnityObjectToClipPos(v.vertex);
//计算顶点在抓取到的纹理中的位置
o.grabPos = ComputeGrabScreenPos(o.vertex);
o.uv = TRANSFORM_TEX(v.uv, _NoiseTex);
//计算顶点在当前屏幕中的位置
o.screenPos = ComputeScreenPos(o.vertex);
//因为_CameraDepthTexture中不记录透明物体的深度,所以用COMPUTE_EYEDEPTH(o.screenPos.z)来计算屏幕位置对应的深度。
//在UnityCG.cginc 里 #define COMPUTE_EYEDEPTH(o) o = -UnityObjectToViewPos( v.vertex ).z
COMPUTE_EYEDEPTH(o.screenPos.z);
o.normal = UnityObjectToWorldNormal(v.normal);
o.viewDir = normalize(UnityWorldSpaceViewDir(mul(unity_ObjectToWorld, v.vertex)));
return o;
}
fixed4 _Color;
fixed4 frag(v2f i) : SV_Target
{
//获取已有的深度信息,此时的深度图里没有力场的信息
//判断相交
//这段代码在文章里解释一下
//SAMPLE_DEPTH_TEXTURE_PROJ是对深度纹理进行采样 第二个参数通常使用顶点着色器输出插值而得的屏幕坐标
//UNITY_PROJ_COORD:given a 4-component vector, return a texture coordinate suitable for projected texture reads. On most platforms this returns the given value directly.
//LinearEyeDepth让深度值线性化
float sceneZ = LinearEyeDepth(SAMPLE_DEPTH_TEXTURE_PROJ(_CameraDepthTexture, UNITY_PROJ_COORD(i.screenPos)));
float partZ = i.screenPos.z;
float diff = sceneZ - partZ;
float intersect = (1 - diff) * _IntersectPower;
//圆环
//这个画圆环就是一个菲涅尔折射了,让物体边缘发光
float3 viewDir = normalize(UnityWorldSpaceViewDir(mul(unity_ObjectToWorld, i.vertex)));
float rim = 1 - abs(dot(i.normal, normalize(i.viewDir))) * _RimStrength;
float glow = max(intersect, rim);
//扭曲
//扭曲就是加一些噪声 然后让uv动起来就可以了
float4 offset = tex2D(_NoiseTex, i.uv - _Time.xy * _DistortTimeFactor);
i.grabPos.xy -= offset.xy * _DistortStrength;
fixed4 color = tex2Dproj(_GrabTempTex, i.grabPos);
fixed4 col = _Color * glow + color;
return col;
}
ENDCG
}
}
}
接下来重点解释一下这几行:
float sceneZ = LinearEyeDepth(SAMPLE_DEPTH_TEXTURE_PROJ(_CameraDepthTexture, UNITY_PROJ_COORD(i.screenPos)));
float partZ = i.screenPos.z;
float diff = sceneZ - partZ;
float intersect = (1 - diff) * _IntersectPower;
sceneZ是获取到深度纹理中的深度,但是这个深度不包括透明物体的。partZ才是该透明物体(就是能量罩)上每一个点的深度。
为什么相交的地方会发光呢? 首先要判断相交的地方在哪里,怎么判断呢?就要用到深度值了,(以上边第二张图)如果能量罩上的某些点深度值和立方体上某些点的深度值一致,那么这些点就是交线上的点了。所以用sceneZ-partZ来表示这些点的距离差,差值越小说明越靠近。然后用1-diff来说明相交的程度。可以先这么理解,差值越小,1-diff越大,相交得越厉害。
之后再使用这句float glow = max(intersect, rim);就可以让交线处发光了,这句该怎么理解呢?
可以这么看,假设我们不考虑交线发光,那么这个图是这样子的。
的确,交线处无发光的迹象,然而球的边缘却是发光的。
当它使用float glow = max(intersect, rim)这句时,可以这么理解,当远离交线时,intersect值比较小,所以远离交线的地方就取rim值,当离交线很近时,显然intersect值比较大,这时候就要取intersect的值,所以交线处也会发亮。
至此,这个交线发亮就做完了,但是其中有一点为什么diff=sceneZ-partZ,而不是diff=partZ-sceneZ呢?下面是我自己的一些推理,不清楚对不对,大概是对的(我瞎猜的)
如图,黑色点是相机,红色的是不透明的物体,蓝色框是透明的物体。假设,sceneZ是红色物体的深度,partZ是透明物体的深度
显然红色离相机远,蓝色离相机近,所以sceneZ-partZ>0 当两者相差的过大时,sceneZ-partZ>1 那么intersect值会是一个负值,所以会用原始rim值。
考虑另一种情况
当蓝色在后面,红色在前面,此刻partZ>sceneZ 那么sceneZ-partZ<0,则intersect>1 此刻绿色框内应该疯狂发光才对
but,被红色不透明物体遮住了。。。你看不见。
所以只有下面这种情况才对
透明物体在不透明物体前面一点点,这样0<sceneZ-partZ<1。
也就是这么说当蓝色物体在红色物体后面时,虽然intersect值会很大,但是你看不见,被红色物体遮住了。当蓝色物体在红色物体前面一点点时,两者里的越近sceneZ-partZ越接近0 ,那么1-(sceneZ-partZ)会越大,即intersect值越大,所以交线发亮。所以使用diff=sceneZ-partZ没毛病。
告辞!