《Unity Shader 入门精要》学习笔记07（一）---基础纹理

纹理最初的目的就是使用一张图片来控制模型的外观。使用纹理映射技术，我们可以把一张图“粘”在模型表面上，逐纹素的控制模型的颜色。
因为我是做3D角色的，所以这些东西不再描述。
1.实现单张纹理（这里依然使用BlinnPhong光照模型来计算光照），代码如下：

// Upgrade NOTE: replaced '_Object2World' with 'unity_ObjectToWorld'
// Upgrade NOTE: replaced 'mul(UNITY_MATRIX_MVP,*)' with 'UnityObjectToClipPos(*)'

Shader "Unity Shaders Book/Chapter 7/Single Texture" {
	Properties{
		_Color ("Color Tint",Color) = (1,1,1,1)
		_MainTex ("Main Tex",2D) = "white"{}
		_Specular ("Specular",Color) = (1,1,1,1)
		_Gloss ("Glose",Range(8.0,256)) = 20
	}
	SubShader{
		Pass{
			Tags{"LightMode" = "ForwardBase"}

			CGPROGRAM
			#pragma vertex vert 
			#pragma fragment frag
			#include "Lighting.cginc"

			fixed4 _Color;
			fixed4 _Specular;
			float _Gloss;
			//定义与上面声明类型相对应的变量
			sampler2D _MainTex;
			float4 _MainTex_ST;

			struct a2v{
				float4 vertex:POSITION;
				float3 normal:NORMAL;
				float4 texcoord:TEXCOORD0;
			};
			struct v2f{
				float4 pos:SV_POSITION;
				float3 worldNormal:TEXCOORD0;
				float3 worldPos:TEXCOORD1;
				float2 uv:TEXCOORD2;
			};

			v2f vert(a2v v){
				v2f o;
				o.pos = UnityObjectToClipPos(v.vertex );
				o.worldNormal = UnityObjectToWorldNormal(v.normal);
				o.worldPos = mul(unity_ObjectToWorld,v.vertex ).xyz;
				//使用纹理的属性值_MainTex_ST来对顶点纹理坐标进行变换，过程如下，
				//1.首先使用_MainTex_ST.xy对顶点纹理坐标进行缩放,
				//2.然后使用_MainTex_ST.zw对顶点纹理坐标进行平移,
				//也可直接使用内置宏TRANSFORM_TXE来实现
				o.uv = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;
				//或直接使用内置宏实现
				//o.uv = TRANSFORM_TXE(v.texcoord,_MainTex);
				return o;
			}
			fixed4 frag(v2f i):SV_Target{
				//计算法线方向
				fixed3 worldNormal = normalize(i.worldNormal);
				//计算光照方向
				fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
				//使用Cg的tex2D函数对纹理进行采样。第一个参数是被采样的纹理，第二个是float2类型的纹理坐标。
				//然后使用采样结果和颜色属性_Color的乘积来作为材质的反射率albedo
				fixed3 albedo = tex2D(_MainTex,i.uv).rgb * _Color.rgb;
				//得到环境光
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;
				//计算漫反射
				fixed3 diffuse = _LightColor0.rgb * albedo * max(0,dot(worldNormal,worldLightDir));
				//计算高光反射
				fixed3 viewDir = normalize(UnityWorldSpaceViewDir(i.worldPos));
				fixed3 halfDir = normalize(worldLightDir+viewDir);
				fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0,dot(worldNormal,halfDir)),_Gloss);

				return fixed4(ambient + diffuse + specular,1.0);
			}
			ENDCG		
		}
	}

	FallBack "Specular"
}

2.纹理的属性

相较于书上的图，我用的5.6.3已经有了一些变化，只取其中一些属性来说明，如果需要知道全部属性，请自行查阅。
Texture Type 贴图类型，指明贴图的类型，现在是用的Default默认也即是原来的Texture类型，
还有Normal map类型等等，不再详细说明。
Wrap Mode 循环模式，分两种，Repeat重复模式和Clamp固定模式
Filter Mode 决定了当纹理由于变换而产生拉伸时将会采取哪种滤波模式。给出3种，分别为
Point，Bilibear，Trilinear 即点模式，双线性模式，三线性模式，效果依次提示，消耗性能也是依次提升。
Max Size 纹理的最大尺寸 请使用2的幂次方的大小尺寸的纹理图片，不一定是正方形，可以是长方形。
Fomat 纹理模式 根据性能自行选择。