《Unity Shader 入门精要》学习笔记07（二）---凹凸映射

纹理的另一种常见应用就是凹凸映射。
主要用两种方法来进行，高度纹理（高度映射）和法线纹理（法线映射）。
高度纹理：使用一张高度图来实现凹凸映射，颜色越深位置越凹。
优点：直观可见，缺点：计算更复杂。
法线纹理：存储的就是表面的法线方向。
使用不同空间的法线纹理的优缺点，不再说明，这里直接使用切线空间下的法线纹理。
我们需要在计算光照模型中统一各个方向矢量所在的坐标空间，由于法线纹理中存储的是切线空间下的方向，因此我们有2种选择：
1.在切线空间下进行光照计算，此时需要把光照方向，视角方向变换到切线空间；
2.选择在世界空间下进行光照计算，此时需要把采样得到的法线方向变换到世界空间下，再和世界空间的光照方向和视角方向进行计算。
从效率上来讲，第一种要优于第二种，因为我们在顶点着色器中就完成对光照方向和视角的变换，而第二种方法由于要先对法线纹理进行采样，所以变换过程必须在片元着色器中实现，这意味着我们需要在片元着色器中进行一次矩阵操作。
但从通用性角度来讲，第二种方法要优于第一种，因为有时我们需要在世界空间下进行一些计算。
下面给出两种空间计算的代码：
1.在切线空间下计算。

Shader "Unity Shaders Book/Chapter 7/Normal Map In Tangent Space" {
	Properties{
		_Color ("Color Tint",Color) = (1,1,1,1)
		_MainTex ("Main Tex",2D) = "white"{}
		_BumpMap ("Normal Map",2D) = "bump"{}
		_BumpScale ("Bump Scale",Float) = 1.0
		_Specular ("Specular",Color) = (1,1,1,1)
		_Gloss ("Gloss",Range(8.1,256)) = 20
	}
	SubShader{
		Pass{
			Tags{"LightMode" = "ForwardBase"}

			CGPROGRAM
			#pragma vertex vert 
			#pragma fragment frag 
			#include "Lighting.cginc"
			//#include "UnityCG.cginc"

			//定义变量
			fixed4 _Color;
			sampler2D _MainTex;
			float4 _MainTex_ST;
			//为了得到法线纹理的属性（平铺和偏移系数），定义ST
			sampler2D _BumpMap;
			float4 _BumpMap_ST;
			float _BumpScale;
			fixed4 _Specular;
			float _Gloss;

			struct a2v{
				float4 vertex:POSITION;
				float3 normal:NORMAL;
				float4 tangent:TANGENT;
				float4 texcoord:TEXCOORD0;
			};
			struct v2f{
				float4 pos:SV_POSITION;
				float4 uv:TEXCOORD0;
				float3 lightDir:TEXCOORD1;
				float3 viewDir:TEXCOORD2;
			};
			v2f vert(a2v v){
				v2f o;
				o.pos = UnityObjectToClipPos(v.vertex);
				o.uv.xy = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;
				o.uv.zw = v.texcoord.xy * _BumpMap_ST.xy + _BumpMap_ST.zw;

				

				//TANGENT_SPACE_ROTATION 相当于以下两行被注释的代码
				//float3 bionormal = cross(normalize(v.normal),normalize(v.tangent)) * v.tangent.w;
				//float3x3 rotation = float3x3(v.tangent.xyz,bionormal,v.normal);
				TANGENT_SPACE_ROTATION;
				//ObjSpaceLightDir
				o.lightDir = mul(rotation,ObjSpaceLightDir(v.vertex)).xyz;
				o.viewDir = mul(rotation,ObjSpaceViewDir(v.vertex)).xyz;

				//fixed3 worldNormal = UnityObjectToWorldNormal(v.normal);  
				//fixed3 worldTangent = UnityObjectToWorldDir(v.tangent.xyz);  
				//fixed3 worldBinormal = cross(worldNormal, worldTangent) * v.tangent.w; 
				//float3x3 worldToTangent = float3x3(worldTangent, worldBinormal, worldNormal);
				// Transform the light and view dir from world space to tangent space
				//o.lightDir = mul(worldToTangent, WorldSpaceLightDir(v.vertex));
				//o.viewDir = mul(worldToTangent, WorldSpaceViewDir(v.vertex));

				return o;
			}
			fixed4 frag(v2f i):SV_Target{
				fixed3 tangentLightDir = normalize(i.lightDir);
				fixed3 tangentViewDir = normalize(i.viewDir);

				fixed4 packedNormal = tex2D(_BumpMap,i.uv.zw);
				fixed3 tangentNormal;

				tangentNormal = UnpackNormal(packedNormal);
				tangentNormal.xy *= _BumpScale;
				tangentNormal.z = sqrt(1.0 - saturate(dot(tangentNormal.xy,tangentNormal.xy)));

				fixed3 albedo = tex2D(_MainTex,i.uv).rgb * _Color.rgb;
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT * albedo;
				fixed3 diffuse = _LightColor0.rgb * albedo * max(0,dot(tangentNormal,tangentLightDir));
				fixed3 halfDir = normalize(tangentLightDir + tangentViewDir);
				fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0,dot(tangentNormal,halfDir)),_Gloss);
				return fixed4(ambient + diffuse + specular,1.0);
			}
			ENDCG		
		}	
	}
	FallBack "Specular"
}

当初，找了半天问题，原来是一个字母被大写了，悲剧。
2.世界空间下计算，代码如下：

// Upgrade NOTE: replaced '_Object2World' with 'unity_ObjectToWorld'

Shader "Unity Shaders Book/Chapter 7/Normal Map In World Space" {
	Properties{
		_Color ("Color Tint",Color) = (1,1,1,1)
		_MainTex ("Main Tex",2D) = "white"{}
		_BumpMap ("Normal Map",2D) = "bump"{}
		_BumpScale ("Bump Scale",Float) = 1.0
		_Specular ("Specular",Color) = (1,1,1,1)
		_Gloss ("Gloss",Range(8.1,256)) = 20
	}
	SubShader{
		Pass{
			Tags{"LightMode" = "ForwardBase"}

			CGPROGRAM
			#pragma vertex vert 
			#pragma fragment frag 
			#include "Lighting.cginc"
			//#include "UnityCG.cginc"

			//定义变量
			fixed4 _Color;
			sampler2D _MainTex;
			float4 _MainTex_ST;
			//为了得到法线纹理的属性（平铺和偏移系数），定义ST
			sampler2D _BumpMap;
			float4 _BumpMap_ST;
			float _BumpScale;
			fixed4 _Specular;
			float _Gloss;

			struct a2v{
				float4 vertex:POSITION;
				float3 normal:NORMAL;
				float4 tangent:TANGENT;
				float4 texcoord:TEXCOORD0;
			};
			//修改输出结构体
			struct v2f{
				float4 pos:SV_POSITION;
				float4 uv:TEXCOORD0;
				//float3 lightDir:TEXCOORD1;//切线空间计算
				//float3 viewDir:TEXCOORD2;//切线空间计算
				//下面结构体成员依次存储从切线空间到世界空间的变换矩阵的每一行
				float4 Ttow0:TEXCOORD1;
				float4 Ttow1:TEXCOORD2;
				float4 Ttow2:TEXCOORD3;
			};
			v2f vert(a2v v){
				v2f o;
				o.pos = UnityObjectToClipPos(v.vertex);
				o.uv.xy = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;
				o.uv.zw = v.texcoord.xy * _BumpMap_ST.xy + _BumpMap_ST.zw;

				float3 worldPos = mul(unity_ObjectToWorld,v.vertex).xyz;
				//法线
				float3 worldNormal = UnityObjectToWorldNormal(v.normal);
				//顶点切线
				float3 worldTangent = UnityObjectToWorldDir(v.tangent.xyz);
				//副切线
				float3 worldBinormal = cross(worldNormal,worldTangent) * v.tangent.w;
				//上面计算了世界空间下的顶点切线，副切线和法线的矢量表示，然后下面把他们按列摆放，
				//得到从切线空间到世界空间的变换矩阵，并把世界空间下的定点位置的xyz分量分别存储在这些变量的w分量中，
				//以便充分利用插值寄存器的存储空间。
				o.Ttow0 = float4(worldTangent.x, worldBinormal.x, worldNormal.x, worldPos.x);
				o.Ttow1 = float4(worldTangent.y, worldBinormal.y, worldNormal.y, worldPos.y);
				o.Ttow2 = float4(worldTangent.z, worldBinormal.z, worldNormal.z, worldPos.z);

				return o;
			}
			fixed4 frag(v2f i):SV_Target{
				
				//得到世界空间的顶点位置
				float3 worldPos = float3(i.Ttow0.w,i.Ttow1.w,i.Ttow2.w);
				//得到光照方向和视角方向
				fixed3 lightDir = normalize(UnityWorldSpaceLightDir(worldPos));
				fixed3 viewDir = normalize(UnityWorldSpaceViewDir(worldPos));
				//得到切线空间的法线纹理
				fixed3 bump = UnpackNormal(tex2D(_BumpMap,i.uv.zw));
				bump.xy *= _BumpScale;
				bump.z = sqrt(1.0 - saturate(dot(bump.xy,bump.xy)));
				bump = normalize(half3(dot(i.Ttow0.xyz,bump),dot(i.Ttow1.xyz,bump),dot(i.Ttow2.xyz,bump)));
				//计算光照
				//计算反射率
				fixed3 albedo = tex2D(_MainTex,i.uv).rgb * _Color.rgb;
				//计算环境光
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT * albedo;
				//计算漫反射
				fixed3 diffuse = _LightColor0.rgb * albedo * max(0,dot(bump,lightDir));
				//计算高光反射
				fixed3 halfDir = normalize(lightDir + viewDir);
				fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0,dot(bump,halfDir)),_Gloss);
				return fixed4(ambient + diffuse + specular,1.0);

			}
			ENDCG			
		}		
	}
	FallBack "Specular"
}

得到的效果如下，左边是切线空间，右边是世界空间，
Bump Scale 分别为 -0.8，-0.5

以上，下节是渐变纹理。