Unity Shader 从未入门到已放弃（十七）--中级 顶点动画

2D水流

其原理通常是使用正弦函数来模拟水流的波动效果。

Shader "myShader/Water"
{
	Properties
	{
		_MainTex("Main Tex", 2D) = "white" {}
		_Color("Color Tint", Color) = (1, 1, 1, 1)
		_Magnitude("Distortion Magnitude", Float) = 1 //控制水流波动幅度
		_Frequency("Distortion Frequency", Float) = 1 //控制波动频率
		_InvWaveLength("Distortion Inverse Wave Length", Float) = 10 //控制波长的倒数（_InvWaveLength越大 波长越小）
		_Speed("Speed", Float) = 0.5
	}
	SubShader
	{
			//关闭批处理（批处理会合并所有相关模型，而这些模型各自的模型空间就会丢失）
		Tags { "Queue" = "Transparent" "IgnoreProjector" = "True" "RenderType" = "Transparent" "DisableBatching" = "True" }
		
		Pass
		{
			Tags{"LightMode" = "ForwardBase"} 
			//开启混合模式 关闭深度写入 关闭剔除功能 让水流的每个面都能显示
			ZWrite off
			Blend SrcAlpha OneMinusSrcAlpha
			Cull off

			CGPROGRAM

			#pragma vertex vert
			#pragma fragment frag

			#include "UnityCG.cginc"

			sampler2D _MainTex;
			float4 _MainTex_ST;
			fixed4 _Color;
			float _Magnitude;
			float _Frequency;
			float _InvWaveLength;
			float _Speed;

			struct a2v {
				float4 vertex : POSITION;
				float4 texcoord : TEXCOORD0;
			};

			struct v2f {
				float4 pos : SV_POSITION;
				float2 uv : TEXCOORD0;
			};

			v2f vert(a2v v) {
				v2f o;

				float4 offset;
				offset.yzw = float3(0.0, 0.0, 0.0);
				offset.x = sin(_Frequency * _Time.y + v.vertex.x * _InvWaveLength + v.vertex.y * _InvWaveLength + v.vertex.z * _InvWaveLength) * _Magnitude;
				o.pos = UnityObjectToClipPos(v.vertex + offset);

				o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
				o.uv += float2(0.0, _Time.y * _Speed);

				return o;
			}

			fixed4 frag(v2f i) : SV_Target{
				fixed4 c = tex2D(_MainTex, i.uv);
				c.rgb *= _Color.rgb;

				return c;
			}

			ENDCG
		}
	}
	FallBack "Transparent/VertexLit"
}

效果图：

 

 

Billboard

广告牌技术会根据视角方向来旋转一个被纹理着色的多边形，使得多边形看起来好像总是面对摄像机。

Shader "myShader/Billboard"
{
	//多变形结构需满足在模型空间下是竖直排列的

	Properties
	{
		_Color("Color Mint", Color) = (1,1,1,1) //控制显示整体颜色
		_MainTex("Main Tex", 2D) = "white"{} //广告牌透明纹理
		_VerticalBillboarding("Vertical Restraints",Range(0,1)) = 1 //调整是固定法线还是固定指向上方向
	}
	SubShader
	{
		Tags { "Queue" = "Transparent" "IgnoreProjector" = "True" "RenderType" = "Transparent" "DisableBatching" = "True" }
		
		Pass
		{
			Tags{"LightMode" = "ForwardBase"} 
			ZWrite off
			Blend SrcAlpha OneMinusSrcAlpha
			Cull off

			CGPROGRAM

			#pragma vertex vert
			#pragma fragment frag

			#include "Lighting.cginc"

			sampler2D _MainTex;
			float4 _MainTex_ST;
			fixed4 _Color;
			fixed _VerticalBillboarding;

			struct a2v {
				float4 vertex:POSITION;
				float4 texcoord:TEXCOORD0;
			};

			struct v2f {
				float4 pos:SV_POSITION;
				float2 uv:TEXCOORD0;
			};

			v2f vert(a2v v ) {
				v2f o;
				float3 center = float3(0, 0, 0);  //模型原点作为锚点
				float3 viewer = mul(unity_WorldToObject, float4(_WorldSpaceCameraPos, 1)); //获取模型空间下的视角

				//根据观察位置和锚点计算目标法线方向
				float3 normalDir = viewer - center;
				normalDir.y = normalDir.y * _VerticalBillboarding;
				normalDir = normalize(normalDir);

				//防止法线方向和向上方向平行
				float3 upDir = abs(normalDir.y) > 0.999 ? float3(0, 0, 1) : float3(0, 1, 0);
				float3 rightDir = normalize(cross(upDir, normalDir));
				upDir = normalize(cross(normalDir, rightDir));

				float3 centerOffs = v.vertex.xyz - center;
				float3 localPos = center + rightDir * centerOffs.x + upDir * centerOffs.y + normalDir * centerOffs.z;

				o.pos = UnityObjectToClipPos(float4(localPos, 1));
				o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);

				return o;
			}

			fixed4 frag(v2f i) :SV_Target{
				fixed4 c = tex2D(_MainTex, i.uv);
				c.rgb *= _Color.rgb;

				return c;
			}

			ENDCG
		}
	}
	FallBack "Transparent/VertexLit"
}

效果图：