zynq ultrascale mpsoc 自定义配置文件解析

雪天鱼

已于 2022-02-23 20:16:28 修改

阅读量2.2k

点赞数 1

分类专栏： JTAG 调试 & RISC-V调试文章标签： openocd A53 zynq MPSOC debug

于 2022-02-23 15:58:58 首次发布

本文链接：https://blog.csdn.net/qq_44447544/article/details/123050948

版权

JTAG 调试 & RISC-V调试专栏收录该内容

15 篇文章 54 订阅

订阅专栏

本文详细解析了使用OpenOCD通过PJTAG调试Zynq UltraScale+ MPSoC PS端A53核心的配置文件，包括JTAG连接、DAP设置、CTI创建以及target配置等关键步骤，同时提供了相关OpenOCD命令的官方文档链接以供参考。

摘要由CSDN通过智能技术生成

最近在用 openocd 调试 zynq ultrascale mpsoc PS端的 A53。现在调通了，对配置文件进行一个解析记录，方便自己后续回顾。

一、配置文件代码

openocd 使用的是 PJTAG 端去连接的 MPSOC，JTAG 扫描链上只有 ARM DAP。如下图所示：

在这里插入图片描述
调试器使用的是 FTDI ft4232h。这个配置文件简单，openocd官方也有demo，也不赘述了。
zynq mpsoc的配置文件如下所示，我会逐行解释代码：

# SD 卡配置模式启动，配置 MIO 映射，启用 PJTAG 接口。
# zynq_ultrascale  MPSOC
# 执行命令：openocd -f ft4232h.cfg -f zynq.cfg
# 设置 芯片名，自定义即可
set _CHIPNAME uscale
# 设置 ARM DAP 的 IDCODE，会通过此ID去检索 DAP。
set _DAP_TAPID 0x5ba00477

# 创建名为 tap 的JTAG TAP，指定 IR 长度为4，期望 IDCODE 为 0x5ba00477，并验证 IR 移位capture的正确性。
jtag newtap $_CHIPNAME tap -irlen 4 -ircapture 0x1 -irmask 0xf -expected-id $_DAP_TAPID
# 创建一个 DAP 实例绑定到刚创建的 JTAG TAP 上。
dap create $_CHIPNAME.dap -chain-position $_CHIPNAME.tap

# 设置一些变量，后续使用
set _TARGETNAME $_CHIPNAME.a53
set _CTINAME $_CHIPNAME.cti
set _smp_command ""

# ug1085 p1200 CoreSight Address Map
# 四个 A53 core debug coresignt 组件的地址
set DBGBASE {0x80410000 0x80510000 0x80610000 0x80710000}
# 四个 A53 core CIT coresignt 组件的地址
set CTIBASE {0x80420000 0x80520000 0x80620000 0x80720000}
# A53 core 的数量，zynq mpsoc PS端有 四核 A53
set _cores 4

# TCL语法，用于创建 target
for { set _core 0 } { $_core < $_cores } { incr _core } {
	#  在DAP实例上指定 MEM-AP 和基地址访问 Coresight 组件 CTI，并创建对应实例。一共4个CTI实例，对应4个core。
    cti create $_CTINAME.$_core -dap $_CHIPNAME.dap -ap-num 1 \
        -baseaddr [lindex $CTIBASE $_core]
	# 通过指定 DAP，CTI以及Core debug 组件地址来创建 target
    set _command "target create $_TARGETNAME.$_core aarch64 -dap $_CHIPNAME.dap \
        -dbgbase [lindex $DBGBASE $_core] -cti $_CTINAME.$_core"

    if { $_core != 0 } {
        # 对于 core1,2,3取消 JTAG 链初始化和复位时的检查操作
        # 需要手动调用 arp_examine 才能访问这些目标进行调试。
        set _command "$_command -defer-examine"
        # 拼接指令
        set _smp_command "$_smp_command $_TARGETNAME.$_core"
    } else {
        # 拼接指令
        set _smp_command "target smp $_TARGETNAME.$_core"
    }
    # 执行命令
    eval $_command
}
# 指定 ap 为 AXI-AP ，创建目标 axi,可访问 axi bus上所挂载的外设。
target create $_CHIPNAME.axi mem_ap -dap uscale.dap -ap-num 0
 # 执行命令 target smp uscale.a53.0 uscale.a53.1 uscale.a53.2 uscale.a53.3
eval $_smp_command
targets $_TARGETNAME.0

# tcl语法，定义名为 core_up 的过程，用于切换当前 target。
proc core_up { args } {
    global _TARGETNAME
    foreach { core } [set args] {
        $_TARGETNAME.$core arp_examine
    }
}

二、相关命令官方文档参考链接

查找渠道：通过 Command and Driver Index 页面进行命令检索。

jtag newtap ：10.3 TAP Declaration Commands

举例：

jtag newtap $_CHIPNAME tap -irlen 4 -ircapture 0x1 -irmask 0xf -expected-id $_DAP_TAPID
dap create $_CHIPNAME.dap -chain-position $_CHIPNAME.tap

（1）这里需要注意的一点是调用 tap 时，通过 chipname.tapname 的形式进行调用。
（2）然后 -ircapture 0x1 -irmask 0xf 是用来验证 IR 扫描链的正确性的，但具体怎么做的还是没懂，这个掩码表示什么意思如果有明白的朋友可以在评论区分享下，谢谢啦！

dap create：10.8 DAP declaration (ARMv6-M, ARMv7 and ARMv8 targets)
cti create:16.2 ARM Cross-Trigger Interface
target create : 11.3 Target Configuration
创建所要进行 debug 的目标芯片或者其他器件，通过 TAP 发送指令对其进行调试操作。
（1）-defer-examine ：在 JTAG 扫描链初始化和复位时跳过对目标的检查，需要手动调用 arp_examine才能访问这些目标进行调试。
$target_name arp_examine 11.4 Other $target_name Commands