Unity Shader 高级纹理 立方体纹理 反射

 使用了反射效果的物体通常看起来就像渡了层金属。想要模拟反射效果很简单，我们只需要通过入射光线的方向和表面法线方向来计算出反射方向，再利用反射方向对立方体纹理采样即可。

shader 

Shader "MyShader/Reflection"
{
    Properties{
        _Color("Color Tint", Color) = (1, 1, 1, 1)
        _ReflectColor("Reflection Color", Color) = (1, 1, 1, 1)
        _ReflectAmount("Reflect Amount", Range(0, 1)) = 1
        _Cubemap("Reflection Cubemap", Cube) = "_Skybox" {}
    }
        SubShader{
            Tags { "RenderType" = "Opaque" "Queue" = "Geometry"}

            Pass {
                Tags { "LightMode" = "ForwardBase" }

                CGPROGRAM

                #pragma multi_compile_fwdbase

                #pragma vertex vert
                #pragma fragment frag

                #include "Lighting.cginc"
                #include "AutoLight.cginc"

                fixed4 _Color;
                fixed4 _ReflectColor;
                fixed _ReflectAmount;
                samplerCUBE _Cubemap;

                struct a2v {
                    float4 vertex : POSITION;
                    float3 normal : NORMAL;
                };

                struct v2f {
                    float4 pos : SV_POSITION;
                    float3 worldPos : TEXCOORD0;
                    fixed3 worldNormal : TEXCOORD1;
                    fixed3 worldViewDir : TEXCOORD2;
                    fixed3 worldRefl : TEXCOORD3;
                    SHADOW_COORDS(4)
                };

                v2f vert(a2v v) {
                    v2f o;

                    o.pos = UnityObjectToClipPos(v.vertex);

                    o.worldNormal = UnityObjectToWorldNormal(v.normal);

                    o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;

                    o.worldViewDir = UnityWorldSpaceViewDir(o.worldPos);

                    // Compute the reflect dir in world space
                    o.worldRefl = reflect(-o.worldViewDir, o.worldNormal);

                    TRANSFER_SHADOW(o);

                    return o;
                }

                fixed4 frag(v2f i) : SV_Target {
                    fixed3 worldNormal = normalize(i.worldNormal);
                    fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
                    fixed3 worldViewDir = normalize(i.worldViewDir);

                    fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;

                    fixed3 diffuse = _LightColor0.rgb * _Color.rgb * max(0, dot(worldNormal, worldLightDir));

                    // Use the reflect dir in world space to access the cubemap
                    fixed3 reflection = texCUBE(_Cubemap, i.worldRefl).rgb * _ReflectColor.rgb;

                    UNITY_LIGHT_ATTENUATION(atten, i, i.worldPos);

                    // Mix the diffuse color with the reflected color
                    fixed3 color = ambient + lerp(diffuse, reflection, _ReflectAmount) * atten;

                    return fixed4(color, 1.0);
                }

                ENDCG
            }
    }
        FallBack "Reflective/VertexLit"
}

其中，_ReflectColor用于控制反射颜色，_ReflectAmount用于控制这个材质的反射程度，

_Cubemap就是用于模拟反射的环境映射纹理。

对立方体纹理的采样需要使用 CG 的 texCUBE 函数。

参考 我买的 unity shader 入门精要