透明度混合

Shader "Custom/testShader" {

    properties
    {
       _Color("my color", color) = (1,1,1,1)
       _MainTex("mt Tex", 2D) = "white"{}
       _AlphaScale("my Alpha", Range(0,1)) = 1
    }
    subshader
    {
        Tags{"Queue"="Transparent" "IgnoreProjector"="True" "RenderType"="Transparent"}
        pass
        {
           Tags{"LightMode"="ForwardBase"}

           ZWrite off   
           Blend SrcAlpha OneMinusSrcAlpha
          
           CGPROGRAM
           #pragma vertex vert
           #pragma fragment frag
           #include "Lighting.cginc"

           fixed4 _Color;
           sampler2D _MainTex;
           float4 _MainTex_ST;
           fixed4 _AlphaScale;

           struct a2v
           {
               float4 vertex : POSITION;
               float3 normal : NORMAL;
               float4 texcoord : TEXCOORD0;
           };

           struct v2f
           {
               float4 pos : SV_POSITION;
               float3 worldNormal : TEXCOORD0;
               float3 worldPos : TEXCOORD1;
               float2 uv : TEXCOORD2;
           };

           v2f vert(a2v v)
           {
              v2f o;
              o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
              o.worldNormal = UnityObjectToWorldNormal(v.normal);
              o.worldPos = mul(_Object2World, v.vertex).xyz;
              o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
              return o;
           }

           fixed4 frag(v2f i):SV_Target
           {
              fixed3 worldNormal = normalize(i.worldNormal);
              fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
              fixed4 texColor = tex2D(_MainTex, i.uv);
              fixed3 albedo = texColor.rgb * _Color.rgb;
              fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;
              fixed3 diffuse = _LightColor0.rgb * albedo * max(0, dot(worldNormal, worldLightDir));

              return fixed4(ambient + diffuse, texColor.a * _AlphaScale); 
           }
           ENDCG
        }
    }
    FallBack "Transparent/VertexLit"
}

【说明】

1. 透明度混合只关闭了深度写入，但没有关闭深度测试。

2. ZWrite off // 就是把深度写入关闭

  开启并设置pass的混合模式：将源颜色（该片元着色器产生的颜色）的混合因子设为SrcAlpha；

                将目标颜色（已经存在于颜色缓冲区中的颜色）的混合因子设为OneMinusSrcAlpha；

3. Blend命令

   A）Blend Off：关闭混合

   B）Blend SrcFactor DstFactor： 开启混合，并设置混合因子。源颜色会乘以SrcFactor，目标颜色乘以                            DstFactor，然后两者相加后存入颜色缓冲区

   C）Blend BlendOperation： 并非是把源颜色和目标颜色简单相加后混合，而是使用BlendOperation对他们                      进行其他操作

4. 为什么要关闭深度写入？

  答：如果不关闭深度写入，一个半透明表面背后的表面本来可以透过它被我们看到，但由于深度测试时判断的结     果是该半透明物体距离摄像机更远，导致其表面将会被剔除，我们也就无法看到半透明物体之后的物体了。但     会因此破坏深度缓冲的工作机制，所以关闭深度写入导致渲染顺序变得很重要。

5. 关闭深度写入的缺点？

  答：我们无法对模型进行像素级别的深度排序。当模型本身有复杂的遮挡关系或是包含了复杂的非凸网格的时候     就出现渲染错误。解决的方法就是开启深度写入的半透明效果，利用两个pass。

   一个pass开启深度写入，但不输出颜色，它的目的仅仅是为了把该模型的深度值写入深度缓冲中；

  另一个pass进行正常的透明度混合，由于上个pass已经得到了逐像素的正确的深度信息，该pass就可以按照像素   级别的深度排序结果进行透明渲染。

  代码：

    pass

        { 

            ZWrite on

            ColorMask 0

        }

         pass

       {

            //和上述相同代码

       }

 FallBack  “Diffuse”