嵌入式开发(S5PV210)——u-boot的链接脚本分析

1、脚本内容

OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm") //指定输出可执行文件是32位ARM指令，小端模式的ELF格式；
/*OUTPUT_FORMAT("elf32-arm", "elf32-arm", "elf32-arm")*/
OUTPUT_ARCH(arm)	//指定可执行平台是ARM平台
ENTRY(_start)	//指定程序入口是标号_start
SECTIONS
{
	. = 0x00000000;

	. = ALIGN(4);
	.text      :
	{
	  cpu/s5pc11x/start.o	(.text)
	  cpu/s5pc11x/s5pc110/cpu_init.o	(.text)
	  board/samsung/x210/lowlevel_init.o	(.text)
          cpu/s5pc11x/onenand_cp.o      (.text)                 
          cpu/s5pc11x/nand_cp.o (.text)                     
          cpu/s5pc11x/movi.o (.text) 
          common/secure_boot.o (.text) 
	  common/ace_sha1.o (.text)
	  cpu/s5pc11x/pmic.o (.text)
	  *(.text)
	}

	. = ALIGN(4);
	.rodata : { *(.rodata) }

	. = ALIGN(4);
	.data : { *(.data) }

	. = ALIGN(4);
	.got : { *(.got) }

	__u_boot_cmd_start = .;
	.u_boot_cmd : { *(.u_boot_cmd) }
	__u_boot_cmd_end = .;

	. = ALIGN(4);
	.mmudata : { *(.mmudata) }

	. = ALIGN(4);
	__bss_start = .;
	.bss : { *(.bss) }
	_end = .;
}

2、脚本分析

链接脚本没有什么特别的，主要注意
(1)程序的入口：ENTRY(_start)；
(2)在链接脚本中程序链接地址是0x0，但是会被-Ttext $(TEXT_BASE)覆盖掉，所以实际的链接地址是$(TEXT_BASE)；
(3).text段中将某些文件靠前排列，因为这些文件都是和BL1相关的，负责启动的第一阶段。
(4).u_boot_cmd段是自定义段，将来uboot的命令结构体都会被赋予这个段属性，集中被链接在一起。__u_boot_cmd_start就是命令集合的起始地址，__u_boot_cmd_end是命令集合的结束地址。
(5)第一行：指定输出可执行文件是32位ARM指令，小端模式的ELF格式；
(6)OUTPUT_ARCH(arm):指定可执行平台是ARM平台