FPGA学习.5——UART控制器设计

最新推荐文章于 2024-03-27 16:51:47 发布
最新推荐文章于 2024-03-27 16:51:47 发布
阅读量924 收藏 16
点赞数 3
分类专栏： FPGA科普 文章标签： fpga 串口通信 verilog fpga/cpld
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/weixin_43550752/article/details/113501861
版权

这个实在懒得多BB了，网上太多了，UART通信也简单，贴个代码你们参考下

顶层：

module  rs232
(
    input   wire    sys_clk     ,   //系统时钟50MHz
    input   wire    sys_rst_n   ,   //全局复位
    input   wire    rx          ,   //串口接收数据

    output  wire    tx              //串口发送数据
);

//********************************************************************//
//****************** Parameter and Internal Signal *******************//
//********************************************************************//
//parameter define
parameter   UART_BPS    =   20'd9600        ,   //比特率
            CLK_FREQ    =   26'd50_000_000  ;   //时钟频率

//wire  define
wire    [7:0]   po_data;
wire            po_flag;

//********************************************************************//
//*************************** Instantiation **************************//
//********************************************************************//
//------------------------ uart_rx_inst ------------------------
uart_rx
#(
    .UART_BPS    (UART_BPS  ),  //串口波特率
    .CLK_FREQ    (CLK_FREQ  )   //时钟频率
)
uart_rx_inst
(
    .sys_clk    (sys_clk    ),  //input             sys_clk
    .sys_rst_n  (sys_rst_n  ),  //input             sys_rst_n
    .rx         (rx         ),  //input             rx
            
    .po_data    (po_data    ),  //output    [7:0]   po_data
    .po_flag    (po_flag    )   //output            po_flag
);

//------------------------ uart_tx_inst ------------------------
uart_tx
#(
    .UART_BPS    (UART_BPS  ),  //串口波特率
    .CLK_FREQ    (CLK_FREQ  )   //时钟频率
)
uart_tx_inst
(
    .sys_clk    (sys_clk    ),  //input             sys_clk
    .sys_rst_n  (sys_rst_n  ),  //input             sys_rst_n
    .pi_data    (po_data    ),  //input     [7:0]   pi_data
    .pi_flag    (po_flag    ),  //input             pi_flag
                
    .tx         (tx         )   //output            tx
);

endmodule

发送：

module  uart_tx
#(
    parameter   UART_BPS    =   'd9600,         //串口波特率
    parameter   CLK_FREQ    =   'd50_000_000    //时钟频率
)
(
     input   wire            sys_clk     ,   //系统时钟50MHz
     input   wire            sys_rst_n   ,   //全局复位
     input   wire    [7:0]   pi_data     ,   //模块输入的8bit数据
     input   wire            pi_flag     ,   //并行数据有效标志信号
 
     output  reg             tx              //串转并后的1bit数据
);

//********************************************************************//
//****************** Parameter and Internal Signal *******************//
//********************************************************************//
//localparam    define
localparam  BAUD_CNT_MAX    =   CLK_FREQ/UART_BPS   ;

//reg   define
reg [12:0]  baud_cnt;
reg         bit_flag;
reg [3:0]   bit_cnt ;
reg         work_en ;

//********************************************************************//
//***************************** Main Code ****************************//
//********************************************************************//
//work_en:接收数据工作使能信号
always@(posedge sys_clk or negedge sys_rst_n)
        if(sys_rst_n == 1'b0)
            work_en <= 1'b0;
        else    if(pi_flag == 1'b1)
            work_en <= 1'b1;
        else    if((bit_flag == 1'b1) && (bit_cnt == 4'd9))
            work_en <= 1'b0;

//baud_cnt:波特率计数器计数，从0计数到BAUD_CNT_MAX - 1
always@(posedge sys_clk or negedge sys_rst_n)
        if(sys_rst_n == 1'b0)
            baud_cnt <= 13'b0;
        else    if((baud_cnt == BAUD_CNT_MAX - 1) || (work_en == 1'b0))
            baud_cnt <= 13'b0;
        else    if(work_en == 1'b1)
            baud_cnt <= baud_cnt + 1'b1;

//bit_flag:当baud_cnt计数器计数到1时让bit_flag拉高一个时钟的高电平
always@(posedge sys_clk or negedge sys_rst_n)
        if(sys_rst_n == 1'b0)
            bit_flag <= 1'b0;
        else    if(baud_cnt == 13'd1)
            bit_flag <= 1'b1;
        else
            bit_flag <= 1'b0;

//bit_cnt:数据位数个数计数，10个有效数据（含起始位和停止位）到来后计数器清零
always@(posedge sys_clk or negedge sys_rst_n)
    if(sys_rst_n == 1'b0)
        bit_cnt <= 4'b0;
    else    if((bit_flag == 1'b1) && (bit_cnt == 4'd9))
        bit_cnt <= 4'b0;
    else    if((bit_flag == 1'b1) && (work_en == 1'b1))
        bit_cnt <= bit_cnt + 1'b1;

//tx:输出数据在满足rs232协议（起始位为0，停止位为1）的情况下一位一位输出
always@(posedge sys_clk or negedge sys_rst_n)
        if(sys_rst_n == 1'b0)
            tx <= 1'b1; //空闲状态时为高电平
        else    if(bit_flag == 1'b1)
            case(bit_cnt)
                0       : tx <= 1'b0;
                1       : tx <= pi_data[0];
                2       : tx <= pi_data[1];
                3       : tx <= pi_data[2];
                4       : tx <= pi_data[3];
                5       : tx <= pi_data[4];
                6       : tx <= pi_data[5];
                7       : tx <= pi_data[6];
                8       : tx <= pi_data[7];
                9       : tx <= 1'b1;
                default : tx <= 1'b1;
            endcase

endmodule

接收：

module  uart_rx
#(
    parameter   UART_BPS    =   'd9600,         //串口波特率
    parameter   CLK_FREQ    =   'd50_000_000    //时钟频率
)
(
    input   wire            sys_clk     ,   //系统时钟50MHz
    input   wire            sys_rst_n   ,   //全局复位
    input   wire            rx          ,   //串口接收数据

    output  reg     [7:0]   po_data     ,   //串转并后的8bit数据
    output  reg             po_flag         //串转并后的数据有效标志信号
);

//********************************************************************//
//****************** Parameter and Internal Signal *******************//
//********************************************************************//
//localparam    define
localparam  BAUD_CNT_MAX    =   CLK_FREQ/UART_BPS   ;

//reg   define
reg         rx_reg1     ;
reg         rx_reg2     ;
reg         rx_reg3     ;
reg         start_nedge ;
reg         work_en     ;
reg [12:0]  baud_cnt    ;
reg         bit_flag    ;
reg [3:0]   bit_cnt     ;
reg [7:0]   rx_data     ;
reg         rx_flag     ;

//********************************************************************//
//***************************** Main Code ****************************//
//********************************************************************//
//插入两级寄存器进行数据同步，用来消除亚稳态
//rx_reg1:第一级寄存器，寄存器空闲状态复位为1
always@(posedge sys_clk or negedge sys_rst_n)
    if(sys_rst_n == 1'b0)
        rx_reg1 <= 1'b1;
    else
        rx_reg1 <= rx;

//rx_reg2:第二级寄存器，寄存器空闲状态复位为1
always@(posedge sys_clk or negedge sys_rst_n)
    if(sys_rst_n == 1'b0)
        rx_reg2 <= 1'b1;
    else
        rx_reg2 <= rx_reg1;

//rx_reg3:第三级寄存器和第二级寄存器共同构成下降沿检测
always@(posedge sys_clk or negedge sys_rst_n)
    if(sys_rst_n == 1'b0)
        rx_reg3 <= 1'b1;
    else
        rx_reg3 <= rx_reg2;

//start_nedge:检测到下降沿时start_nedge产生一个时钟的高电平
always@(posedge sys_clk or negedge sys_rst_n)
    if(sys_rst_n == 1'b0)
        start_nedge <= 1'b0;
    else    if((~rx_reg2) && (rx_reg3))
        start_nedge <= 1'b1;
    else
        start_nedge <= 1'b0;

//work_en:接收数据工作使能信号
always@(posedge sys_clk or negedge sys_rst_n)
    if(sys_rst_n == 1'b0)
        work_en <= 1'b0;
    else    if(start_nedge == 1'b1)
        work_en <= 1'b1;
    else    if((bit_cnt == 4'd8) && (bit_flag == 1'b1))
        work_en <= 1'b0;

//baud_cnt:波特率计数器计数，从0计数到BAUD_CNT_MAX - 1
always@(posedge sys_clk or negedge sys_rst_n)
    if(sys_rst_n == 1'b0)
        baud_cnt <= 13'b0;
    else    if((baud_cnt == BAUD_CNT_MAX - 1) || (work_en == 1'b0))
        baud_cnt <= 13'b0;
    else    if(work_en == 1'b1)
        baud_cnt <= baud_cnt + 1'b1;

//bit_flag:当baud_cnt计数器计数到中间数时采样的数据最稳定，
//此时拉高一个标志信号表示数据可以被取走
always@(posedge sys_clk or negedge sys_rst_n)
    if(sys_rst_n == 1'b0)
        bit_flag <= 1'b0;
    else    if(baud_cnt == BAUD_CNT_MAX/2 - 1)
        bit_flag <= 1'b1;
    else
        bit_flag <= 1'b0;

//bit_cnt:有效数据个数计数器，当8个有效数据（不含起始位和停止位）
//都接收完成后计数器清零
always@(posedge sys_clk or negedge sys_rst_n)
    if(sys_rst_n == 1'b0)
        bit_cnt <= 4'b0;
    else    if((bit_cnt == 4'd8) && (bit_flag == 1'b1))
        bit_cnt <= 4'b0;
     else    if(bit_flag ==1'b1)
         bit_cnt <= bit_cnt + 1'b1;

//rx_data:输入数据进行移位
always@(posedge sys_clk or negedge sys_rst_n)
    if(sys_rst_n == 1'b0)
        rx_data <= 8'b0;
    else    if((bit_cnt >= 4'd1)&&(bit_cnt <= 4'd8)&&(bit_flag == 1'b1))
        rx_data <= {rx_reg3, rx_data[7:1]};

//rx_flag:输入数据移位完成时rx_flag拉高一个时钟的高电平
always@(posedge sys_clk or negedge sys_rst_n)
    if(sys_rst_n == 1'b0)
        rx_flag <= 1'b0;
    else    if((bit_cnt == 4'd8) && (bit_flag == 1'b1))
        rx_flag <= 1'b1;
    else
        rx_flag <= 1'b0;

//po_data:输出完整的8位有效数据
always@(posedge sys_clk or negedge sys_rst_n)
    if(sys_rst_n == 1'b0)
        po_data <= 8'b0;
    else    if(rx_flag == 1'b1)
        po_data <= rx_data;

//po_flag:输出数据有效标志（比rx_flag延后一个时钟周期，为了和po_data同步）
always@(posedge sys_clk or negedge sys_rst_n)
    if(sys_rst_n == 1'b0)
        po_flag <= 1'b0;
    else
        po_flag <= rx_flag;

endmodule

 

 

 

 

 

 

 

 

 

基于FPGA的饭桶
关注
  • 3
    点赞
  • 踩
  • 16
    收藏
    觉得还不错? 一键收藏
  • 0
    评论
专栏目录
FIFO求和实验
好好学习，天天向上
06-17 479
FIFO求和实验
FPGA的学习：FIFO求和实验
weixin_44297949的博客
06-19 751
111
【FPGA】xilinx Vivado UART IP核使用
最新发布
weixin_42370509的博客
03-27 1002
xilinx Vivado UART IP核的例化及调用
FPGA 之 FIFO 求和算法
qq_51264805的博客
02-02 2044
要实现 FIFO求和，FIFO IP 核必不可少，需要用它用来做求和数据缓存。FIFO 是存储器的一种，满足先进先出原则，前面对它已经有了详细介绍，大家可自行翻阅我前面的博客。 要完成 3 行数据的 FIFO求和，需要调用 2 个 FIFO IP 核，当数据开始输入时，将数据的第 0 行数据存储到 fifo1 中，将第 1 行数据存储到 fifo2 中，当数据的第 2 行的第 0 个数据输入的同时，读取写入 fifo1 中的的第 0 个数据和写入 fifo2 中的第 ...
ZYNQ学习第三章-UART控制器
m0_56222647的博客
03-12 344
连接主机和ZYNQ板卡，通过串口助手发送10byte数据，同时也可以观察到板卡返回的相同的数据。当一次性发10byte数据时板卡会立刻返回相同的数据，当一次只发送01，即1byte时，需要发送十次之后，板卡才会跳出接收函数当中的while循环，同时返回10个01。
野火FPGA征途Pro学习笔记（fifo_sum）
m0_50882712的博客
09-30 951
FIFO sum 原理 利用fifo进行串行数据流的行计算。 首先需要注意的是数据是从一根数据线上传输过来的。 这里我们以3行数据相加的情况举例； 3行数据相加，需要用到2个FIFO；这里给出规律，如果需要一次计算X行数据的和，则需要用到X-1个FIFO 首先将前X-1行的数据进行FIFO保存，之后第X行数据的每一次输入，都进行一次当前对应数字的求和，比如前两行数据为： 1 2 3 4 2 3 4 5 第三行的完整数据为： 3 4 5 6 那么 ①当第三行中的数据传入到3时，将第1、 2行的对应位置的数字
FPGA——UART Rx Verilog程序设计
06-12
UART Rx通过RS232串口，通过串口调试助手将PC端的数据传输到FPGA板子上，通过数码管显示传输的数据
基于FPGA通用异步收发器UART设计
02-17
基于FPGA通用异步收发器UART设计 UART模块与串口助手正常通信 OLED 屏幕显示发送和接收数据及波特率 使用Quartus II 11.0 软件程序编写 modelsim仿真软件进行时序仿真 Verilog 语言
uart.rar_UART控制亮灯
09-21
这是用键盘控制led灯的点亮和熄灭，还可以控制蜂鸣器的响，可用于嵌入式的学习和开发
UART-and-FPGA.rar_UART implementation_uart fpga_基于FPGA的UART
07-15
基于FPGA的UART通信控制器 设计与实现持。用到modelsim6.1f环境模拟。
基于 FPGA 的 UART 控制器设计（VHDL）（中）
08-14 1785
今天给大侠带来基于FPGA的 UART 控制器设计（VHDL）（中），由于篇幅较长，分三篇。今天带来第二篇，中篇，RS-232 串口通信简介。话不多说，上货。 之前有关于 Veriliog HDL 实现的UART 控制器设计，这里放上超链接，仅供各位大侠参考。 FPGA零基础学习：UART协议驱动设计 源码系列：基于FPGA的串口UART设计（附源工程） 导读 异步串行通信是指UART（Universal Asynchronous Receiver/Transmi...
FPGA再入门——UART IP核调用
danranweixiao066的博客
12-28 2193
UART IP核调用
UART接口的FPGA实现（一）——UART接口的相关基础知识
mikusic的博客
01-22 1328
UART系列文章先介绍UART的规范，然后自己动手写Verilog代码实现这个接口并进行测试，最后介绍Xilinx的AXI-uartlite IP核。本系列文章分节较多。 一、UART简介 UART是FPGA工程师在工作中会用到的最常见的接口之一。它的全名是Universal Asynchronous Receiver/Transmitter，通用异步收发器。为什么叫异步收发器呢？因为收发双发通信时不需要严格的时钟同步。还记得前面讲的SPI接口吗，SPI的数据通信必须带着时钟一起，是一种同步通信协议，而
FPGA 串口中断_正点原子开拓者 Nios II资料连载第五章串口IP核
weixin_39794130的博客
11-20 399
1)实验平台：正点原子开拓者FPGA 开发板2)摘自《开拓者 Nios II开发指南》关注官方微信号公众号，获取更多资料：正点原子3)全套实验源码+手册+视频下载地址：http://www.openedv.com/docs/index.html第五章串口IP核我们在让 Altera FPGA 上的嵌入式系统和外部设备进行通信方式的时候，通常会用到拥有Avalon 接口的通用异步收发传输器——UAR...
FPGA实战 -- UART --- 封装UART IP核
2201_75683149的博客
02-03 1068
已经学习了UART协议，并且编写了串口回环的代码。每次一些项目遇到串口的时候都要对 RX 或者 TX 代码进行修改，所以制作一个IP核会非常方便，只需要调用一下，在top顶层连一连wire就能使用了。
基于 FPGA 的 UART 控制器设计（VHDL）（下）
08-17 1978
今天给大侠带来基于FPGA的 UART 控制器设计（VHDL）（下），由于篇幅较长，分三篇。今天带来第三篇，下篇，使用 FPGA 实现 UART。话不多说，上货。 之前有关于 Veriliog HDL 实现的UART 控制器设计，这里放上超链接，仅供各位大侠参考。 FPGA零基础学习：UART协议驱动设计 源码系列：基于FPGA的串口UART设计（附源工程） 第三篇内容摘要：本篇会介绍使用 FPGA 实现 UART，包括UART设计框架、UART 工作流程、信号监测器模块的实现、波特率发生器模块的.
SoC设计——外设篇——uart控制器
知识，既贵，又便宜。
07-05 1878
一、uart简介 uart串口的相关参数 波特率 此参数容易和比特率混淆，其实他们是由区别的。uart中的波特率就可以认为是比特率，即每秒传输的位数(bit)。 一般标准的波特率都会有600，1200，2400，9600,19200，38400，57600，115200等，该数据即指每秒传输这么多个比特位数(bit)。 分频系数 为了在给定输入频率的基础上计算得到对应的波特率，可以 数据包的结构 起始位 一般是1个逻辑”0”的信号，表示传输数据的开始。 数据位 可以选择的值有5,6,7,8这
FPGA串口（UART）通信协议制定与设计思路详解示例
月隐博客
07-07 3452
串口通信协议制定与设计思路详解 1 概述 本文用于描述规定的串口通信协议，以及传输内容。 2 项目关于串口的要求 a) 支持BIT自检，1路UART上报BIT信息； b) 1路UART接口,波特率可调，默认波特率为可达到3.125Mbps。 3 功能分析 支持BIT自检即需要串口自动上报BIT信息，即周期信息上报信息，本设计暂定为1s钟上报一次。 支持波特率可调，在无其他接口控制的环境下，则需要通过串口下发来调整波特率。 4 项目设计 本项目串口设计支持收和发两个方向，BIT上报为1s一次。波特率可
UART控制器上能接多少UART外置口？
06-13
UART控制器上可以接多个UART外置口，具体取决于UART控制器的设计。一般来说，UART控制器会设计多个UART通道，每个通道对应一个外置口，这样就可以同时管理多个外置UART设备的通信。例如，一些SOC芯片上的UART控制器可以同时管理多达8个UART通道，每个通道都可以与一个外置UART设备进行通信。不过，需要注意的是，UART控制器的外置口数量也会受到SOC芯片本身硬件资源的限制，因此具体数量需要根据具体的SOC芯片型号来确定。

“相关推荐”对你有帮助么？

  • 非常没帮助
  • 没帮助
  • 一般
  • 有帮助
  • 非常有帮助
提交
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值