Blob分析--检查图中焊接点，并获取焊接点的直径

* ball.hdev: Inspection of Ball Bonding
* 检查图中焊接点，并获取焊接点的直径
*首先，分离比较明亮的区域，然后将找出来的结果，转换成最小的平行矩形，即获得了图像处理的ROI
*然后，在ROI区域内选择比较暗的区域，移除不适合的区域（利用形状，面积等参数），
*把物体抽出变成一个独立的物，找出圆形物体，并且排列物体即可。
dev_update_window ('off')
dev_close_window ()
dev_open_window (0, 0, 728, 512, 'black', WindowID)
read_image (Bond, 'die/die_03')
dev_display (Bond)
*设置字体
set_display_font (WindowID, 14, 'mono', 'true', 'false')
*在荧幕上显示暂停程序继续操作的信息
disp_continue_message (WindowID, 'black', 'true')
stop ()
*阈值分割
threshold (Bond, Bright, 100, 255)
*变换区域的形状
shape_trans (Bright, Die, 'rectangle2')
dev_set_color ('green')
dev_set_line_width (3)
dev_set_draw ('margin')
dev_display (Die)
disp_continue_message (WindowID, 'black', 'true')
stop ()
*获得特定区域Region位置的图像
reduce_domain (Bond, Die, DieGrey)
*阈值分割
threshold (DieGrey, Wires, 0, 50)
*fill_up_shape有条件填充
fill_up_shape (Wires, WiresFilled, 'area', 1, 100)
dev_display (Bond)
dev_set_draw ('fill')
dev_set_color ('red')
dev_display (WiresFilled)
disp_continue_message (WindowID, 'black', 'true')
stop ()
*用圆形结构开运算（先腐蚀后膨胀）
opening_circle (WiresFilled, Balls, 15.5)
dev_set_color ('green')
dev_display (Balls)
disp_continue_message (WindowID, 'black', 'true')
stop ()
*连通区域分割
connection (Balls, SingleBalls)
*根据特征值选择圆形区域
select_shape (SingleBalls, IntermediateBalls, 'circularity', 'and', 0.85, 1.0)
*对区域进行排序
sort_region (IntermediateBalls, FinalBalls, 'first_point', 'true', 'column')
dev_display (Bond)
dev_set_colored (12)
dev_display (FinalBalls)
disp_continue_message (WindowID, 'black', 'true')
stop ()
*计算一个给定区域的最小外接圆参数
smallest_circle (FinalBalls, Row, Column, Radius)
NumBalls := |Radius|
Diameter := 2 * Radius
meanDiameter := mean(Diameter)
minDiameter := min(Diameter)
dev_display (Bond)
*在一个窗口中显示圆
disp_circle (WindowID, Row, Column, Radius)
dev_set_color ('white')
disp_message (WindowID, 'D: ' + Diameter$'.4', 'image', Row - 2 * Radius, Column, 'white', 'false')
dev_update_window ('on')