【CMake】CMakeList编写整理

最新推荐文章于 2024-04-29 14:41:26 发布

沾liana

最新推荐文章于 2024-04-29 14:41:26 发布

阅读量1.3w

点赞数 34

分类专栏：通用cv及cs 文章标签： c++

本文链接：https://blog.csdn.net/weixin_45677333/article/details/121332641

版权

通用cv及cs 专栏收录该内容

6 篇文章 3 订阅

订阅专栏

什么是CMake

如果软件想跨平台，必须要保证能够在不同平台编译。而如果使用 Make 工具，就得为每一种标准写一次 Makefile 。
CMake 就是针对上面问题所设计的工具：它首先允许开发者编写一种平台无关的 CMakeList.txt 文件来定制整个编译流程，然后再根据目标用户的平台进一步生成所需的本地化 Makefile 和工程文件。

在 linux 平台下使用 CMake 生成 Makefile 并编译的流程如下：

编写 CMake 配置文件 CMakeLists.txt 。
执行命令 cmake PATH 或者 ccmake PATH 生成Makefile（ccmake 和 cmake 的区别在于前者提供了一个交互式的界面）。其中， PATH 是CMakeLists.txt 所在的目录。
使用 make 命令进行编译。

指令快查

变量

引用：
　　前面我们已经提到了，使用 ${variable_name} 进行变量的引用。在 IF 等语句中，是直接使用变量名而不通过 ${variable_name} 取值。

自定义变量方式：
　　主要有隐式定义和显式定义两种。
　　使用 SET(variable_name value) 指令，显式定义变量。

SET(SRC_LIST main.cpp)

PROJECT 指令，会隐式的定义 _BINARY_DIR 和 _SOURCE_DIR 两个变量。

# 项目信息
project(Test)

常用变量：
CMAKE_BINARY_DIR/PROJECT_BINARY_DIR /_BINARY_DIR
运行 cmake 命令的目录，通常是 ${PROJECT_SOURCE_DIR}/build。
这三个变量指代的内容是一致的，如果 in-source build，指的是工程顶层目录；如果是 out-of-source build，指的是工程编译发生的目录。

CMAKE_SOURCE_DIR/PROJECT_SOURCE_DIR /_SOURCE_DIR
这三个变量指代的内容是一致的，不论采用何种编译方式，都是工程顶层目录。

PROJECT_NAME：返回通过 project 命令定义的项目名称。

CMAKE_CURRENT_SOURCE_DIR
指的是当前处理的 CMakeLists.txt 所在的路径，比如上面例子中的 src 源代码子目录。

CMAKE_CURRRENT_BINARY_DIR
　如果是 in-source 编译，它跟 CMAKE_CURRENT_SOURCE_DIR 一致；
　如果是 out-of-source 编译，他指的是 target 编译目录。
　使用我们上面提到的ADD_SUBDIRECTORY(src bin) 可以更改这个变量的值。
　使用 SET(EXECUTABLE_OUTPUT_PATH <新路径>) 并不会对这个变量造成影响，它仅仅修改了最终目标文件存放的路径。
　
CMAKE_CURRENT_LIST_DIR：CMakeLists.txt 的完整路径；
CMAKE_CURRENT_LIST_LINE：当前所在的行。

EXECUTABLE_OUTPUT_PATH：可执行文件的存放位置；
LIBRARY_OUTPUT_PATH：库文件的存放位置。

调用环境变量：
　　使用$ENV{variable_name} 指令就可以调用系统的环境变量了。

set(CMAKE_BUILD_TYPE "Debug")
set(CMAKE_CXX_FLAGS_DEBUG "$ENV{CXXFLAGS} -O0 -Wall -g -ggdb")
set(CMAKE_CXX_FLAGS_RELEASE "$ENV{CXXFLAGS} -O3 -Wall")

系统信息变量：
　　UNIX
　　　在所有的类 UNIX 平台为 true，包括 OS X 和 cygwin。
　　WIN32
　　　在所有的 win32 平台为 true，包括 cygwin。

# 判断平台差异，控制在不同的平台进行不同的控制
IF(WIN32)
  MESSAGE(STATUS “Thisiswindows.”)
  #作一些 Windows 相关的操作
ELSE(WIN32)
  MESSAGE(STATUS “Thisisnotwindows”)
  #作一些非 Windows 相关的操作
ENDIF(WIN32)

主要开关选项

set(CMAKE_CXX_STANDARD 11)
# C++11設置

set(CMAKE_CXX_STANDARD_REQUIRED ON)
# 如果不设置的话，则之前设置的STANDARD 11标准可能会失效。因此，其和后一条语句一般是连用的。

set(CMAKE_CXX_EXTENSIONS OFF)
# 该值默认使用gnu++11编译，我们的protobuf编译的时候是使用c++11编译的，因此，应该把该变量关了。

指令

cmake_minimum_required()指定cmake最低版本

project()会定义两个变量：PROJECT_BINARY_DIR 和 PROJECT_SOURCE_DIR。
# ${PROJECT_SOURCE_DIR}：本CMakeLists.txt所在的文件夹路径
# ${PROJECT_NAME}：本CMakeLists.txt的project名称

aux_source_directory(目录 变量)查找指定目录下所有源文件，并保存到指定变量名

add_definitions()添加编译选项

add_executable(可执行文件名 源文件)根据源文件生成可执行文件；

add_library(静态库 STATIC 源文件)根据源文件生成静态库（当没有STATIC选项时，默认生成静态库）；

add_library(动态库 SHARED 源文件) 根据源文件生成动态库或共享库。

add_subdirectory(子目录)指定调用子目录的CMakeLists.txt，通常用于将子目录中的源文件编译成库，来给父目录中的CMakeLists.txt使用。（此时对于父目录的CMakeLists.txt而言，已经知晓子目录中编译后生成的库的存在，因此无需使用link_directories()将该库的所在文件目录另外包含进来。）
# 在add_subdirector之前set的各个变量，在子文件夹中是可以调用的！

include_directories(目录)指定头文件目录；

link_directories(目录)指定库文件目录。

target_link_libraries()指定链接库

option(宏 "备注" ON)添加一个选项，并设置默认值为开

configure_file(配置文件 配置头文件)根据配置文件生成配置头文件

message()打印消息

include()指定要包含的其他CMake文件或目录

find_package()引入外部依赖包，find_program()

FetchContent_Declare()，FetchContent_MakeAvailable()

常用組合:

# 搜索当前目录下的所有.cpp文件，并将其存储到一个变量中，然後指定生成目標。
aux_source_directory(. SRC_LIST) 
add_library(Test ${SRC_LIST})

# 子文件:
# 搜索当前目录以及protocol目录下的所有.cpp文件,然後生成链接库
file(GLOB SRC_LIST "*.cpp" "protocol/*.cpp")
add_library(MathFunctions ${SRC_LIST})
# 或者
file(GLOB SRC_LIST "*.cpp")
file(GLOB SRC_PROTOCOL_LIST "protocol/*.cpp")
add_library(MathFunctions ${SRC_LIST} ${SRC_PROTOCOL_LIST})
# 或者
aux_source_directory(. SRC_LIST)
aux_source_directory(protocol SRC_PROTOCOL_LIST)
add_library(MathFunctions ${SRC_LIST} ${SRC_PROTOCOL_LIST})

# 根文件:
# 添加链接库
target_link_libraries(Test4 MathFunctions)

通常流程：

project(xxx)                                          #必须

add_subdirectory(子文件夹名称)                         #父目录必须，子目录不必

add_library(库文件名称 STATIC 文件)                    #通常子目录(二选一)
add_executable(可执行文件名称 文件)                     #通常父目录(二选一)

include_directories(路径)                              #必须
link_directories(路径)                                 #必须

target_link_libraries(库文件名称/可执行文件名称 链接的库文件名称)       #必须

流程

if语句

if(...)
  ...
else()
  ...
endif

while语句

while(condition)
    ...
endwhile()

foreach语句

foreach(_target
  ... ...
  )
  ...
  endforeach

如：

foreach(i RANGE 1 9 2) #1为起始数，9为终止数，2为步长。
    message(${i})
endforeach(i)

从简单开始

CMakeList大小写不敏感。

编写 CMakeLists.txt

首先编写 CMakeLists.txt 文件，并保存在与 main.cc 源文件同个目录下：

# CMake 最低版本号要求
cmake_minimum_required (VERSION 3.10.0)
# 项目信息
project(Test)
# 指定生成目标
add_executable(Test main.cpp)

cmake_minimum_required：指定运行此配置文件所需的 CMake 的最低版本；
project：参数值是Test，表示项目的名称是 Test 。
add_executable：将名为 main.cpp 的源文件编译成一个名称为 Test 的可执行文件。

也可以写成：

# CMake 最低版本号要求
cmake_minimum_required (VERSION 3.10.0)
# 项目信息
project(Test)
# 设置CMakeList变量
SET(SRC_LIST main.cpp)
# 指定生成目标
# add_executable(ClionProject main.cpp)
ADD_EXECUTABLE(Test1 ${SRC_LIST})

SET 用于设置 CMake 变量，另外通过 ${VAR_NAME} 的方式引用变量
在这里插入图片描述

编译项目

之后，在当前目录执行 cmake . ，得到 Makefile 后再使用 make 命令编译得到 Demo1 可执行文件。

(base) liana@liana-930MBE:~/Learning/CMakeListTest$ cmake .
-- The C compiler identification is GNU 5.4.0
-- The CXX compiler identification is GNU 5.4.0
-- Check for working C compiler: /usr/bin/cc
-- Check for working C compiler: /usr/bin/cc -- works
-- Detecting C compiler ABI info
-- Detecting C compiler ABI info - done
-- Detecting C compile features
-- Detecting C compile features - done
-- Check for working CXX compiler: /usr/bin/c++
-- Check for working CXX compiler: /usr/bin/c++ -- works
-- Detecting CXX compiler ABI info
-- Detecting CXX compiler ABI info - done
-- Detecting CXX compile features
-- Detecting CXX compile features - done
-- Configuring done
-- Generating done
-- Build files have been written to: /home/liana/Learning/CMakeListTest

(base) liana@liana-930MBE:~/Learning/CMakeListTest$ make
Scanning dependencies of target Test1
[ 50%] Building CXX object CMakeFiles/Test1.dir/main.cpp.o
[100%] Linking CXX executable Test1
[100%] Built target Test1

(base) liana@liana-930MBE:~/Learning/CMakeListTest$ ./Test1 5 4
5 ^ 4 is 625

cmake .：‘.’ 表示当前目录，运行后将会自动生成 CMakeFiles 文件夹，CMakeCache.txt，cmake_install.cmake 等文件，并且生成了 Makefile。
在这里插入图片描述

make 则是去执行的 Makefile，生成我们的目标文件 CLionProject。
在这里插入图片描述
善用make clean,可以删除生成的可执行文件。

或者进行外部构建, 新建立build文件夹并进入:

(base) liana@liana-930MBE:~/Learning/CMakeListTest$ mkdir build
(base) liana@liana-930MBE:~/Learning/CMakeListTest$ cd build

(base) liana@liana-930MBE:~/Learning/CMakeListTest/build$ cmake ..
-- The C compiler identification is GNU 5.4.0
-- The CXX compiler identification is GNU 5.4.0
-- Check for working C compiler: /usr/bin/cc
-- Check for working C compiler: /usr/bin/cc -- works
-- Detecting C compiler ABI info
-- Detecting C compiler ABI info - done
-- Detecting C compile features
-- Detecting C compile features - done
-- Check for working CXX compiler: /usr/bin/c++
-- Check for working CXX compiler: /usr/bin/c++ -- works
-- Detecting CXX compiler ABI info
-- Detecting CXX compiler ABI info - done
-- Detecting CXX compile features
-- Detecting CXX compile features - done
-- Configuring done
-- Generating done
-- Build files have been written to: /home/liana/Learning/CMakeListTest/build

(base) liana@liana-930MBE:~/Learning/CMakeListTest/build$ make
Scanning dependencies of target MathFunctions

cmake .. 中的 .. 表示 build 目录的父目录，即是我们的源代码工程目录，因为父目录存在我们需要的 CMakeLists.txt。一般建议在源代码工程目录下新建 build 目录进行构建。
　　通过外部构建这种方式完成构建后的工程源文件目录如下，构建过程中的中间产物和目标文件都存放在 build 目录中，源文件并没有受其影响。通过删除该文件夹，即可实现中间文件快速删除。即 out-of-source 方式来构建（即生成的中间产物和源代码分离）
在这里插入图片描述

一个目录，多个cpp文件

如果有多个cpp文件，

./Test2
    |
    +--- main.cpp
    |
    +--- MathFunctions.cpp
    |
    +--- MathFunctions.h

就写为：

add_executable(Test2 main.cpp MathFunctions.cpp)

或者使用 aux_source_directory 命令，该命令会查找指定目录下的所有源文件，然后将结果存进指定变量名。其语法如下：

aux_source_directory(<dir> <variable>)

# 查找当前目录下的所有源文件
# 并将名称保存到 DIR_SRCS 变量
aux_source_directory(. DIR_SRCS)
# 指定生成目标
add_executable(Test3 ${DIR_SRCS})

这样，CMake 会将当前目录('.' 表示当前目录)所有源文件的文件名赋值给变量 DIR_SRCS ，再指示变量 DIR_SRCS 中的源文件需要编译成一个名称为 Test3 的可执行文件。

多个目录，多个源文件

./Test4
    |
    +--- main.cpp
    |
    +--- math/
          |
          +--- MathFunctions.cpp
          |
          +--- MathFunctions.h

对于这种情况，需要分别在项目根目录 Demo3 和 math 目录里各编写一个 CMakeLists.txt 文件。为了方便，我们可以先将 math 目录里的文件编译成静态库再由 main 函数调用。

记得main函数头文件路徑:
在这里插入图片描述

根目录中的 CMakeLists.txt ：

# CMake 最低版本号要求
cmake_minimum_required (VERSION 3.10.0)
# 项目信息
project(Test)
# 查找当前目录下的所有源文件
# 并将名称保存到 DIR_SRCS 变量
aux_source_directory(. DIR_SRCS)
# 添加 math 子目录
add_subdirectory(math)
# 指定生成目标 
add_executable(Test4 ${DIR_SRCS})
# 添加链接库
target_link_libraries(Test4 MathFunctions)

使用命令 add_subdirectory 指明本项目包含一个子目录 math，这样 math 目录下的 CMakeLists.txt 文件和源代码也会被处理。
使用命令 target_link_libraries 指明可执行文件 main 需要连接一个名为 MathFunctions 的链接库。

子目录中的 CMakeLists.txt：

# 查找当前目录下的所有源文件
# 并将名称保存到 DIR_LIB_SRCS 变量
aux_source_directory(. DIR_LIB_SRCS)
# 生成链接库
add_library (MathFunctions ${DIR_LIB_SRCS})

在该文件中使用命令 add_library 将 src 目录中的源文件编译为静态链接库 MathFunctions 。

自定义编译选项

CMake 允许为项目增加编译选项，从而可以根据用户的环境和需求选择最合适的编译方案。

例如，可以将 MathFunctions 库设为一个可选的库，如果该选项为 ON ，就使用该库定义的数学函数来进行运算。否则就调用标准库中的数学函数库。

修改根目录下的 CMakeLists.txt 文件：

# CMake 最低版本号要求
cmake_minimum_required (VERSION 3.10.0)
# 项目信息
project(Test)

# 加入一个配置头文件，用于处理 CMake 对源码的设置
configure_file (
  "${PROJECT_SOURCE_DIR}/config.h.in"
  "${PROJECT_BINARY_DIR}/config.h"
  )
# 是否使用自己的 MathFunctions 库
option (USE_MYMATH
       "Use provided math implementation" ON)
# 是否加入 MathFunctions 库
if (USE_MYMATH)
  include_directories ("${PROJECT_SOURCE_DIR}/math")
  add_subdirectory (math)  
  set (EXTRA_LIBS ${EXTRA_LIBS} MathFunctions)
endif (USE_MYMATH)

# 查找当前目录下的所有源文件
# 并将名称保存到 DIR_SRCS 变量
aux_source_directory(. DIR_SRCS)
# 指定生成目标 
add_executable(Test5 ${DIR_SRCS})
# 添加链接库
target_link_libraries(Test5 ${EXTRA_LIBS})

configure_file 命令用于加入一个配置头文件 config.h ，这个文件由 CMake 从 config.h.in生成，通过这样的机制，将可以通过预定义一些参数和变量来控制代码的生成。
option 命令添加了一个 USE_MYMATH选项，并且默认值为 ON 。
根据 USE_MYMATH 变量的值来决定是否使用我们自己编写的 MathFunctions 库。

修改 main.cpp 文件
之后修改 main.cpp 文件，让其根据 USE_MYMATH 的预定义值来决定是否调用标准库还是MathFunctions 库：

#include "config.h"

#ifdef USE_MYMATH
  #include "math/MathFunctions.h"
#else
  #include <math.h>
#endif

int main(int argc, char *argv[])
{

#ifdef USE_MYMATH
    printf("Now we use our own Math library. \n");
    //
#else
    printf("Now we use the standard library. \n");
    //
#endif
    //
    return 0;
}

编写 config.h.in 文件
上面的程序值得注意的是第2行，这里引用了一个 config.h 文件，这个文件预定义了 USE_MYMATH 的值。

./Test5
    |
    +--- main.cpp
    |
    +--- CMakeLists.txt
    |
    +--- config.h.in
    |
    +--- math/
          |
          +--- MathFunctions.cpp
          |
          +--- MathFunctions.h
          |
          +--- CMakeLists.txt

但我们并不直接编写这个文件，为了方便从 CMakeLists.txt 中导入配置，我们编写一个 config.h.in 文件，内容如下：

#cmakedefine USE_MYMATH

编译项目
现在编译一下这个项目，为了便于交互式的选择该变量的值，可以使用 ccmake 命令（也可以使用 cmake -i 命令，该命令会提供一个会话式的交互式配置界面）
从中可以找到刚刚定义的 USE_MYMATH 选项，按键盘的方向键可以在不同的选项窗口间跳转，按下 enter 键可以修改该选项。修改完成后可以按下 c 选项完成配置，之后再按 g 键确认生成 Makefile 。ccmake 的其他操作可以参考窗口下方给出的指令提示。

這樣,就可以用config.h文件將CMakeLists.txt跟cpp文件連接起來了

安装和测试

CMake 也可以指定安装规则，以及添加测试。这两个功能分别可以通过在产生 Makefile 后使用 make install 和 make test 来执行。在以前的 GNU Makefile 里，你可能需要为此编写 install 和 test 两个伪目标和相应的规则，但在 CMake 里，这样的工作同样只需要简单的调用几条命令。

定制安装规则
首先先在 math/CMakeLists.txt 文件里添加下面两行：

# 指定 MathFunctions 库的安装路径
install (TARGETS MathFunctions DESTINATION bin)
install (FILES MathFunctions.h DESTINATION include)

指明 MathFunctions 库的安装路径。之后同样修改根目录的 CMakeLists 文件，在末尾添加下面几行：

# 指定安装路径
install (TARGETS Test6 DESTINATION bin)
install (FILES "${PROJECT_BINARY_DIR}/config.h"
         DESTINATION include)

通过上面的定制，生成的 Test6 文件和 MathFunctions 函数库 libMathFunctions.o 文件将会被复制到 /usr/local/bin 中，而 MathFunctions.h 和生成的 config.h 文件则会被复制到 /usr/local/include 中。

我们可以验证一下（顺带一提的是，这里的 /usr/local/ 是默认安装到的根目录，可以通过修改 CMAKE_INSTALL_PREFIX 变量的值来指定这些文件应该拷贝到哪个根目录）：

格式化工程

除了上面的cmake ..,还需要更多的格式化工程,让整体变的更好.

./Test4
├── build
| └── bin
| | └── <project_name>
├── doc
| └── <project_name>.txt
├── src
| ├── xxx.c
| └── CMakeLists.txt
├── CMakeLists.txt

├── COPYRIGHT
├── README

└── run<project_name>.sh

src，用来放置工程源代码，包括源文件、头文件以及该目录的 CMake 文件；
doc，用来放置工程的说明文档；
文本文件 COPYRIGHT 和 README 是有关 license 和如何使用的说明；构建后的目标文件将放在构建目录的 bin 子目录下；
工程目录下添加一个 run<project_name>.sh 脚本，可以用来调用二进制文件，比如需要按照一定配置、顺序调用多个目标文件，才能完成整个项目的功能。

首先，编写 src 目录下的工程源代码，包括 main.c 和该目录的 CMake 文件 CMakeLists.txt (這裏主要寫出CMakeLists.txt )

# ./src/CMakeLists.txt
ADD_EXECUTABLE(hello main.c)
 
INSTALL(TARGETS hello RUNTIME DESTINATION bin)
# INSTALL 指令用于定义安装规则，安装的内容可以包括目标二进制、动态库、静态库以及文件、目录、脚本等
# 参数中的TARGETS后面跟的就是我们通过ADD_EXECUTABLE或者ADD_LIBRARY定义的目标文件（可执行二进制、动态库、静态库）
# 目标类型也就相对应的有三种，ARCHIVE 特指静态库，LIBRARY 特指动态库，RUNTIME 特指可执行目标二进制
# DESTINATION 定义了安装的路径，如果路径以/开头，那么指的是绝对路径；否则是相对路径${CMAKE_INSTALL_PREFIX}/<dir>

默认的的安装路径前缀 ${CMAKE_INSTALL_PREFIX} 是 /usr/local，所以，采用默认的安装路径 make install 时，会因为权限问题而报错。
在这里插入图片描述
在执行 “cmake” 命令时可以指定参数 CMAKE_INSTALL_PREFIX，如下:

ADD_EXECUTABLE 用于生成目标文件，INSTALL 命令则是跟 make install 安装相关，这里是安装目标文件。

接下来是工程根目录下的 CMakeLists.txt，该文件是整个工程的 CMake 文件，需要使用 src 目录下的 CMake 文件。

# ./CMakeLists.txt
CMAKE_MINIMUM_REQUIRED(VERSION 2.10.0)
 
PROJECT(HELLO)
ADD_SUBDIRECTORY(src bin)
# 这个指令用于向当前工程添加存放源文件的子目录，并可以指定中间二进制和目标二进制存放的位置。
# 上面的例子定义了将 src 子目录加入工程，并指定编译输出(包含编译中间结果)路径为 bin 目录。
# 如果不进行 bin 目录的指定，那么编译结果(包括中间结果)都将存放在 build/src 目录(这个目录跟原有的 src 目录对应)
# 指定 bin 目录后，相当于在编译时将 src 重命名为 bin，所有的中间结果和目标二进制都将存放在 bin 目录。
 
INSTALL(PROGRAMS runhello.sh DESTINATION bin)
# 非目标文件的可执行程序安装(比如脚本之类)，跟 FILES 指令使用方法相似
INSTALL(FILES COPYRIGHT README DESTINATION doc/cmake/ex_02)
# 用于安装一般文件，并可以指定访问权限，文件名是此指令所在路径下的相对路径（相对于指令所在 CMakeLists.txt）
INSTALL(DIRECTORY doc/ DESTINATION doc/cmake/ex_02)
# DIRECTORY 后面连接的是所在 Source 目录的相对路径，但务必注意：abc 和 abc/有很大的区别。
# 如果目录名不以/结尾，那么这个目录将被安装为目标路径下的 abc；
# 如果目录名以/结尾，代表将这个目录中的内容安装到目标路径，但不包括这个目录本身
 
ADD_TEST(mytest ${PROJECT_BINARY_DIR}/bin/hello)
ENABLE_TESTING()

ADD_SUBDIRECTORY 将整个工程的 CMake 文件与 src 工程源代码关联；
INSTALL 用于安装，这里是安装脚本文件、普通文件和 doc 目录。
ADD_TEST 和 ENABLE_TESTING 则与 “make test” 相关

构建：
　　构建过程基本与上一个例子一样，make 之后，生成的目标文件将保存在 ./build/bin/ 目录下，make test、make install 分别执行上述的 ADD_TEST 和 INSTALL 指令。

> cd ~/Workspace/cmake_ws/ex_02/
> mkdir build
> cd build/
> cmake ..
> make
> ./hello
> make test
> make install
> cd ..
> rm -rf build/

安装
主要是因为存放的路径比较特殊，如上面提到的 /usr/local，这些路径存在于 shell 的默认路径中。举个例子，某个可执行文件安装到 /usr/local 中，那他在任何一个terminal 中都能被运行，就像在 Windows 下，随便双击某个桌面图标，就能启动程序一样，把那个程序安装到系统上了。

将其他平台的项目迁移到 CMake

CMake 可以很轻松地构建出在适合各个平台执行的工程环境。而如果当前的工程环境不是 CMake ，而是基于某个特定的平台，是否可以迁移到 CMake 呢？答案是可能的。下面针对几个常用的平台，列出了它们对应的迁移方案。

autotools

am2cmake可以将 autotools 系的项目转换到 CMake，这个工具的一个成功案例是 KDE 。
Alternative Automake2CMake 可以转换使用 automake 的 KDevelop 工程项目。
Converting autoconf tests

qmake
qmake converter 可以转换使用 QT 的 qmake 的工程。

Visual Studio

vcproj2cmake.rb 可以根据 Visual Studio 的工程文件（后缀名是 .vcproj 或 .vcxproj）生成
CMakeLists.txt 文件。
vcproj2cmake.ps1 vcproj2cmake 的 PowerShell 版本。
folders4cmake 根据 Visual Studio 项目文件生成相应的 “source_group”
信息，这些信息可以很方便的在 CMake 脚本中使用。支持 Visual Studio 9/10 工程文件。

CMakeLists.txt 自动推导

gencmake 根据现有文件推导 CMakeLists.txt 文件。
CMakeListGenerator 应用一套文件和目录分析创建出完整的 CMakeLists.txt 文件。仅支持 Win32 平台。

參考網址

https://cmake.org/cmake/help/v3.15/
https://www.hahack.com/codes/cmake/
https://durant35.github.io/2016/04/21/tool_CMake_%E5%BF%AB%E9%80%9F%E5%85%A5%E9%97%A8/
https://blog.csdn.net/mindizhike/article/details/113749198?spm=1001.2014.3001.5506

沾liana

关注

34
点赞
踩
140

收藏

觉得还不错? 一键收藏
2
评论
【CMake】CMakeList编写整理

什么是CMake如果软件想跨平台，必须要保证能够在不同平台编译。而如果使用 Make 工具，就得为每一种标准写一次 Makefile 。CMake 就是针对上面问题所设计的工具：它首先允许开发者编写一种平台无关的 CMakeList.txt 文件来定制整个编译流程，然后再根据目标用户的平台进一步生成所需的本地化 Makefile 和工程文件。在 linux 平台下使用 CMake 生成 Makefile 并编译的流程如下：编写 CMake 配置文件 CMakeLists.txt 。执行命令 cm
复制链接

扫一扫