FPGA入门学习——按键消抖

按键消抖

理论学习

我们所使用的按键开关为机械弹性开关，当机械触点断开、闭合时，由于机械触点的弹性作用，一个按键开关在闭合时不会马上稳定地接通，在断开时也不会一下子断开。因而在闭合及断开的瞬间均伴随有一连串的抖动，为了不产生这种现象而做的措施就是按键消抖。

解决思路

思想：按键抖动一般在5~10ms，因此可以考虑使用计数器来过滤抖动，简单理解就是在发生抖动之后最后一次低电平开始计数，如果在计算20ms内没有再发生抖动，则说明此信号是稳定的。
做法：当系统检测到按键为低电平时计数器就计数，当检测到按键为高电平时计数器就清零。

1.程序框图

2.波形图

存在问题：key_flag存在多个脉冲
解决方法：修改计数器，当计数器达到999_999时，不清零，当key_in为高电平时再清零，可以解决key_flag多个脉冲问题

存在问题：key_flag信号不是脉冲，而变成一段高电平了
解决方法：当计数器达到999_998时，拉高key_flag电平，产生一次脉冲

3.代码

module key_filter
#(
	parameter CNT_MAX = 20'd999_999
)
(
	input clk,reset,key_in,
	output reg key_flag
);

reg[19:0] cnt;

// 计数器实现
always @(posedge clk or negedge reset)
	if(reset == 1'b0)
		cnt <= 20'd0;
	else if(key_in == 1'b1)     //key_in高电平，按键松开，计算清零
		cnt <= 20'd0;
	else if(cnt == CNT_MAX)  //计算达到最大值，保持，不清零
		cnt <= CNT_MAX;
	else
		cnt <= cnt + 20'd1;

// key_flag实现
always @(posedge clk or negedge reset)
	if(reset == 1'b0)
		key_flag <= 1'b0;
	else if(cnt == CNT_MAX - 1'd1)  // 计算达到20ms，产生脉冲
		key_flag <= 1'b1;
	else
		key_flag <= 1'b0;     //其他情况，都是低电平
endmodule

4.仿真编写

`timescale 1 ns/ 1 ns
module key_filter_vlg_tst();
// test vector input registers
reg clk;
reg key_in;
reg reset;
reg[7:0] tb_cnt;
// wires                                               
wire key_flag;

// assign statements (if any)                          
key_filter
#(
	.CNT_MAX(20'd24)
)
 i1 (
// port map - connection between master ports and signals/registers   
	.clk(clk),
	.key_flag(key_flag),
	.key_in(key_in),
	.reset(reset)
);
initial                                                
begin                                                  
	clk = 1'b1;
	reset <= 1'b0;
	#20
	reset <= 1'b1;
end     
always #10 clk = ~clk;                                               
always @(posedge clk or negedge reset)
	if(reset == 1'b0)
		tb_cnt <= 8'd0;
	else if(tb_cnt == 8'd249)
		tb_cnt <= 8'd0;
	else
		tb_cnt <= tb_cnt + 8'd1;
		

always @(posedge clk or negedge reset)
	if(reset == 1'b0)
		key_in <= 1'b1;
	else if((tb_cnt >= 8'd19) && (tb_cnt <= 8'd49)
				|| (tb_cnt >= 8'd149) && (tb_cnt <= 8'd199))
		key_in <= {$random} % 2;
	else if(tb_cnt < 8'd19 || tb_cnt > 8'd199)
		key_in <= 1'b1;
	else
		key_in <= 1'b0;                                                  
endmodule