【牛客网verilog刷题】跨时钟域传输，VL46同步FIFO（详细讲解了同步fifo）

已于 2023-11-01 15:51:17 修改
阅读量181 收藏 1
点赞数 2
分类专栏： 【verilog刷题】 文章标签： fpga开发
于 2023-10-26 21:59:23 首次发布
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/weixin_47730622/article/details/134059559
版权

同步FIFO

1.序言

（1）什么是FIFO

FIFO（First in,First out）,先入先出缓冲器，对数据起缓冲作用，常用在数据的跨时钟域传输。

（2）FIFO分类

FIFO由数据存取电路和外围的控制电路构成，通过外围控制电路将需要写入的数据写入存储器件，并在需要时将数据读出。
写入数据操作和读出数据操作分别在写数据时钟和读数据时钟的控制下进行。当这两个时钟为同一个时，我们称之为同步FIFO；当这两个时钟不是同一个时，我们称之为异步FIFO。（异步fifo涉及到跨时钟域数据传输问题，设计更为复杂）
在这里插入图片描述

2.同步FIFO

（1）接口说明（同步fifo同用一个时钟和复位）

端口名I/O描述
端口名I/O描述
clkinput系统时钟，读写操作共用
rst_ninput系统复位，读写操作共用
wdatainput写入的数据
wincinput写入数据使能信号
wfulloutput存储空间写满反馈信号
rdataoutput读出的数据
rincinput读出数据使能信号
wemptyoutput存储空间读空反馈信号

在这里插入图片描述

（2）代码实现

A)序言
FIFO由数据存取电路和外围的控制电路构成。数据存取电路由存储空间配置和读写操作电路实现，外围控制电路由读写使能信号产生,读写操作地址产生和写满/读空信号产生两部分实现。（本文采用高位扩展法实现写满/读空信号产生,还有一种计数器的方法本文没有说明）
B)存储空间配置
作用：根据需要存取数据的位宽和深度分配一个存储空间。用来存储写入的数据。
注意：为了适应不同的数据位宽和存储深度，我们通常将位宽和深度参数化，使其可配置。即在调用此fifo函数时，通过传参实现不同数据位宽和存储深度的fifo。需要注意的是，fifo存储深度通常给的参数是10进制，就需要根据10进制数计算所需要的二进制存储空间，使用了系统函数**$clog2**，比如当存储深度为16时，我们所需要的数据地址位宽为log216-1，所以定义数据位宽：

	input [$clog2(DEPTH)-1:0] waddr;

实现：

	reg [WIDTH-1:0] RAM_MEM [0:DEPTH-1];

C)读写操作电路
作用:当读写使能信号有效时，根据当前需要读出或写入数据的地址，进行读写数据操作。
实现：

always @(posedge wclk) begin
	if(wenc)
		RAM_MEM[waddr] <= wdata;
end 

always @(posedge rclk) begin
	if(renc)
		rdata <= RAM_MEM[raddr];
end

D)读写使能信号产生
作用：提供给读写操作电路读写数据操作有效信号（wenc，renc），
写入数据操作时：数据能够写入需要满足两个条件，第一个是写入数据有效（即写入数据使能信号winc为高）；第二个是当前存储空间还有空位置，即存储空间没有被写满（full为低）。
读出数据操作时，数据能够读出需要满足两个条件：第一个是读出数据使能信号rinc为高；第二个是当前存储空间还有没有被读出的数据，即存储空间没有被读空（empty为低）。
实现：

	//读写操作有效信号
	wire wenc;
	wire renc;
	assign wenc = (winc && (!wfull))?1'b1:1'b0;
	assign renc = (rinc && (!rempty))?1'b1:1'b0;

E)读写操作地址
作用：提供读写操作数据的读写地址；
注意：a)当读写操作有效信号有效，就会按照当前地址读写数据，说明地址是提前准备好的，所以读写一个数据的同时，需要准备好下一时刻的数据地址；
时序图：（以写数据操作为例）
在这里插入图片描述
b)为了方便产生写满信号和读空信号，将读/写数据地址扩展了一位（高位扩展法）构成地址指针，高位扩展法在下一步详细说明；
c)所以实际的数据地址应该为地址指针除去最高位。
实现：

	//读写操作地址指针
	reg [$clog2(DEPTH):0] waddr_ptr;
	reg [$clog2(DEPTH):0] raddr_ptr;	
	always@(posedge clk or negedge rst_n)begin
		if(!rst_n)
			waddr_ptr <= 1'b0;
		else if(wenc)
			waddr_ptr <= waddr_ptr +1'b1;
		else
			waddr_ptr <= waddr_ptr;
	end
	always@(posedge clk or negedge rst_n)begin
		if(!rst_n)
			raddr_ptr <= 1'b0;
		else if(renc)
			raddr_ptr <= raddr_ptr +1'b1;
		else
			raddr_ptr <= raddr_ptr;
	end
	//实际的地址为地址指针除去最高位；
	assign waddr = waddr_ptr[$clog2(DEPTH)-1:0];
	assign raddr = raddr_ptr[$clog2(DEPTH)-1:0];

F)写满/读空信号产生
作用：
指示当前存储空间的状态，是否被写满或读空；
说明：#############关键知识点###############
实际的读写数据地址位宽为[WIDTH-1:0]，但是上一步我们给的数据地址指针（raddr_ptr，waddr_ptr）位宽为[WIDTH:0]，拓展了一位（后面称为拓展位），这一位就是为了方便产生写满和读空信号。如下图所示，数据进行写入和读出的数据地址从小到大递增，当操作到最后一个地址后，又会再一次跳到0000。当读和写操作地址指针指向同一个存储单元，其实有两种可能性，第一种是所有被写入的数据均已经被读出去了，即读空状态；第二种是写数据操作已经进行了一周，即写数据地址已经超过读数据地址一周了，即写满状态。所以地址指针通过增加拓展位，来区分读空和写满状态。
读空写满信号判断依据：
读空信号：读写地址指针完全一致；
写满信号：读写地址指针，只有拓展位不同。
在这里插入图片描述
代码：

	//读空写满信号产生模块
	assign rempty = (waddr_ptr == raddr_ptr)?1'b1:1'b0;
	assign wfull = ((waddr_ptr[$clog2(DEPTH)] != raddr_ptr[$clog2(DEPTH)])&&((waddr_ptr[$clog2(DEPTH)-1:0] == raddr_ptr[[$clog2(DEPTH)-1:0]])))?1'b1:1'b0;

3.同步完整代码

（1）完整代码（前面说明的代码也是基于此的）

`timescale 1ns/1ns
/**********************************RAM************************************/
module dual_port_RAM #(parameter DEPTH = 16,
					   parameter WIDTH = 8)(
	 input wclk
	,input wenc
	,input [$clog2(DEPTH)-1:0] waddr  //深度对2取对数，得到地址的位宽。
	,input [WIDTH-1:0] wdata      	//数据写入
	,input rclk
	,input renc
	,input [$clog2(DEPTH)-1:0] raddr  //深度对2取对数，得到地址的位宽。
	,output reg [WIDTH-1:0] rdata 		//数据输出
);
//存储空间配置
reg [WIDTH-1:0] RAM_MEM [0:DEPTH-1];

always @(posedge wclk) begin
	if(wenc)
		RAM_MEM[waddr] <= wdata;
end 

always @(posedge rclk) begin
	if(renc)
		rdata <= RAM_MEM[raddr];
end 

endmodule  

/**********************************SFIFO************************************/
module sfifo#(
	parameter	WIDTH = 8,
	parameter 	DEPTH = 16
)(
	input 					clk		, 
	input 					rst_n	,
	input 					winc	,
	input 			 		rinc	,
	input 		[WIDTH-1:0]	wdata	,

	// output reg				wfull	,
	// output reg				rempty	,
	output 				wfull	,
	output 				rempty	,
	output wire [WIDTH-1:0]	rdata
);
	//读写操作有效信号
	wire wenc;
	wire renc;
	assign wenc = (winc && (!wfull))?1'b1:1'b0;
	assign renc = (rinc && (!rempty))?1'b1:1'b0;
	//读写操作地址指针
	reg [$clog2(DEPTH):0] waddr_ptr;
	reg [$clog2(DEPTH):0] raddr_ptr;	
	always@(posedge clk or negedge rst_n)begin
		if(!rst_n)
			waddr_ptr <= 1'b0;
		else if(wenc)
			waddr_ptr <= waddr_ptr +1'b1;
		else
			waddr_ptr <= waddr_ptr;
	end
	always@(posedge clk or negedge rst_n)begin
		if(!rst_n)
			raddr_ptr <= 1'b0;
		else if(renc)
			raddr_ptr <= raddr_ptr +1'b1;
		else
			raddr_ptr <= raddr_ptr;
	end
	// //读空写满信号产生模块
	// always@(posedge clk or negedge rst_n)begin
	// 	if(!rst_n)
	// 		rempty <= 1'b0;
	// 	else if(waddr_ptr == raddr_ptr)
	// 		rempty <= 1'b1;
	// 	else
	// 		rempty <= 1'b0;
	// end
	// always@(posedge clk or negedge rst_n)begin
	// 	if(!rst_n)
	// 		wfull <= 1'b0;
	// 	else if((waddr_ptr[$clog2(DEPTH)] != raddr_ptr[$clog2(DEPTH)])&&((waddr_ptr[$clog2(DEPTH)-1:0] == raddr_ptr[$clog2(DEPTH)-1:0])))
	// 		wfull <= 1'b1;
	// 	else
	// 		wfull <= 1'b0;
	// end
	assign rempty = (waddr_ptr == raddr_ptr)?1'b1:1'b0;
	assign wfull = ((waddr_ptr[$clog2(DEPTH)] != raddr_ptr[$clog2(DEPTH)])&&((waddr_ptr[$clog2(DEPTH)-1:0] == raddr_ptr[$clog2(DEPTH)-1:0])))?1'b1:1'b0;
	//实际的数据地址
	wire [3:0]	waddr;
	wire [3:0]	raddr;
	assign waddr = waddr_ptr[$clog2(DEPTH)-1:0];
	assign raddr = raddr_ptr[$clog2(DEPTH)-1:0];
	
	//模块例化
	dual_port_RAM #(
		.DEPTH(DEPTH),
		.WIDTH(WIDTH)
	)
	u_dual_port_RAM
	(
		.wclk	(clk	),
		.wenc	(wenc	),
		.waddr  (waddr	),
		.wdata	(wdata	),
		.rclk	(clk	),
		.renc	(renc	),
		.raddr  (raddr	),
		.rdata 	(rdata)	
);
endmodule

（2）牛客网提交通过的代码（为提交通过做了修改）

说明：
牛客网的提交通过的代码存在bug，即存在和实际情况不符合的地方：
（1）牛客网的读空和写满信号是reg类型，且相较于正常情况延迟了一拍，当读写地址指一致的时候（读空），读出使能信号先到，会误读一位数据；
（2）牛客网的读空和写满信号是reg类型,且读空信号复位为0才能通过，但是实际情况是系统复位清空，存储空间没有数据，所以实际读空信号应该复位为1。
牛客网完整代码：

`timescale 1ns/1ns
/**********************************RAM************************************/
module dual_port_RAM #(parameter DEPTH = 16,
					   parameter WIDTH = 8)(
	 input wclk
	,input wenc
	,input [$clog2(DEPTH)-1:0] waddr  //深度对2取对数，得到地址的位宽。
	,input [WIDTH-1:0] wdata      	//数据写入
	,input rclk
	,input renc
	,input [$clog2(DEPTH)-1:0] raddr  //深度对2取对数，得到地址的位宽。
	,output reg [WIDTH-1:0] rdata 		//数据输出
);
//存储空间配置
reg [WIDTH-1:0] RAM_MEM [0:DEPTH-1];

always @(posedge wclk) begin
	if(wenc)
		RAM_MEM[waddr] <= wdata;
end 

always @(posedge rclk) begin
	if(renc)
		rdata <= RAM_MEM[raddr];
end 

endmodule  

/**********************************SFIFO************************************/
module sfifo#(
	parameter	WIDTH = 8,
	parameter 	DEPTH = 16
)(
	input 					clk		, 
	input 					rst_n	,
	input 					winc	,
	input 			 		rinc	,
	input 		[WIDTH-1:0]	wdata	,

	output reg				wfull	,
	output reg				rempty	,
	// output 				wfull	,
	// output 				rempty	,
	output wire [WIDTH-1:0]	rdata
);
	//读写操作有效信号
	wire wenc;
	wire renc;
	assign wenc = (winc && (!wfull))?1'b1:1'b0;
	assign renc = (rinc && (!rempty))?1'b1:1'b0;
	//读写操作地址指针
	reg [4:0] waddr_ptr;
	reg [4:0] raddr_ptr;	
	always@(posedge clk or negedge rst_n)begin
		if(!rst_n)
			waddr_ptr <= 1'b0;
		else if(wenc)
			waddr_ptr <= waddr_ptr +1'b1;
		else
			waddr_ptr <= waddr_ptr;
	end
	always@(posedge clk or negedge rst_n)begin
		if(!rst_n)
			raddr_ptr <= 1'b0;
		else if(renc)
			raddr_ptr <= raddr_ptr +1'b1;
		else
			raddr_ptr <= raddr_ptr;
	end
	//读空写满信号产生模块
	always@(posedge clk or negedge rst_n)begin
		if(!rst_n)
			rempty <= 1'b0;
		else if(waddr_ptr == raddr_ptr)
			rempty <= 1'b1;
		else
			rempty <= 1'b0;
	end
	always@(posedge clk or negedge rst_n)begin
		if(!rst_n)
			wfull <= 1'b0;
		else if((waddr_ptr[$clog2(DEPTH)] != raddr_ptr[$clog2(DEPTH)])&&((waddr_ptr[$clog2(DEPTH)-1:0] == raddr_ptr[$clog2(DEPTH)-1:0])))
			wfull <= 1'b1;
		else
			wfull <= 1'b0;
	end
	// assign rempty = (waddr_ptr == raddr_ptr)?1'b1:1'b0;
	// assign wfull = ((waddr_ptr[$clog2(DEPTH)] != raddr_ptr[$clog2(DEPTH)])&&((waddr_ptr[$clog2(DEPTH)-1:0] == raddr_ptr[$clog2(DEPTH)-1:0])))?1'b1:1'b0;
	//实际的数据地址
	wire [3:0]	waddr;
	wire [3:0]	raddr;
	assign waddr = waddr_ptr[$clog2(DEPTH)-1:0];
	assign raddr = raddr_ptr[$clog2(DEPTH)-1:0];
	
	//模块例化
	dual_port_RAM #(
		.DEPTH(DEPTH),
		.WIDTH(WIDTH)
	)
	u_dual_port_RAM
	(
		.wclk	(clk	),
		.wenc	(wenc	),
		.waddr  (waddr	),
		.wdata	(wdata	),
		.rclk	(clk	),
		.renc	(renc	),
		.raddr  (raddr	),
		.rdata 	(rdata)	
);
endmodule
原地打转的瑞哥
关注
  • 2
    点赞
  • 踩
  • 1
    收藏
    觉得还不错? 一键收藏
  • 0
    评论
专栏目录
跨时钟域传输和Verilog代码
SummerXRT的博客
07-18 9067
文章目录基本概念一、单bit信号1.慢时钟域信号同步到快时钟域2.快时钟域信号同步到慢时钟域3.结绳法处理单bit信号跨时钟域二、多bit控制信号跨时钟域同步三、多bit数据流跨时钟域同步 前面我们谈到了亚稳态的产生与处理，在异步信号进行跨时钟域传输时，很大概率会产生亚稳态的问题，那么该如何解决跨时钟域信号传输的问题呢？跨时钟域信号分为单bit控制信号、多比特控制信号和多bit数据流传输，依照这个进行分类处理。 基本概念 同步电路：即电路中所有受时钟控制的单元（寄存器和触发器）全部由一个统一的全局时钟控制。
基于FPGA设计Verilog 跨时钟域传输：慢到快
最新发布
GJZGRB的博客
11-21 427
理论上讲，快时钟域的信号总会采集到慢时钟域传输来的信号，如果存在异步可能会导致采样数据出错，所以需要进行同步处理。此类同步处理相对简单，一般采用延迟打拍法，或延迟采样法。
跨时钟域传输总结（包含verilog代码|Testbench|仿真结果）
Loudrs的博客
06-08 5517
采样中“快到慢”与“慢到快”在考虑问题时有什么区别？只需要考虑亚稳态问题除亚稳态问题外，还需考虑慢时钟的采样速率问题。因为根据采样定理，采样频率低于信号最高频率2倍的时候，是无法完整采样的。CDC传输方法总结：慢到快只考虑亚稳态问题，采用延迟打拍法；快到慢还需要考虑慢时钟采样速度，但是只要延长信号长度即可。常用方法为电平同步器、脉冲同步器、握手协议。其中，握手协议限制较为灵活，但握手信号需要在两个时钟域来回传递导致延时很大，所以握手协议是以牺牲效率为代价保证信号传递质量。
【Verilog】握手信号实现跨时钟域数据传输-handshake
秃头仔仔-安凯雯的博客
03-07 2881
【代码】【Verilog】握手信号实现跨时钟域数据传输-handshake。
Verilog设计_跨时钟域(CDC)
2301_76660661的博客
02-23 830
单bit信号跨时钟域传输，慢到快和快到慢。
46-FPGA跨时钟域异步FIFO设计.7z
03-17
FPGA跨时钟域异步FIFO设计,Vivado仿真工程
fifo.zip_FIFO verilog code_同步FIFO verilog_同步fifo
09-19
同步fifo的verilog代码，很好的资料，值得学习
verilog+牛客网刷题自己编写代码汇总+时序分析+状态机等+刷题学习
08-10
1. Verilog快速入门 1. 基础语法 VL1 四选一多路器 VL2 异步复位的串联T触发器 LV3 奇偶校验 VL4 移位运算与乘法 LV5 位拆分与运算 VL6 多功能数据处理器 VL7 求两个数的差值 VL8 使用generate…for语句简化代码 VL9...
同步FIFO设计verilog设计及仿真
01-31
用16*8 RAM实现一个同步先进先出（FIFO）队列设计。由写使能端控制该数据流的写入FIFO，并由读使能控制FIFO中数据的读出。写入和读出的操作由时钟的上升沿触发。当FIFO的数据满和空的时候分别设置相应的高电平加以...
fifo-code.rar_FIFO VHDL 计数_同步FIFO verilog
09-14
Verilog代码：同步\异步FIFO。包含格雷码计数器.
FPGA设计中跨时钟域问题的处理
wczzmmp2的博客
06-19 4304
FPGA设计中跨时钟域问题的处理
verilog 跨时钟域信号处理
yanxiaopan的博客
09-10 2445
1.对于控制信号 通常使用同步器，同步器又分为两种，一种是源时钟频率低于目的时钟，第二种是源时钟频率高于目的时钟。 2.对于数据信号 通常采用异步FIFO 参考：https://blog.csdn.net/DdiIcey/article/details/73928380...
verilog学习之-跨时钟域信号处理（1）
qq_37864715的博客
06-18 3017
1. 建立时间：触发器在时钟上升沿到来之前，其数据输入端的数据必须保持不变的最小时间。保持时间：触发器在时钟上升沿到来之后，其数据输入端的数据必须保持不变的最小时间。触发器内部数据的形成是需要一定的时间的，如果不满足建立和保持时间，触发器将进入亚稳态，进入亚稳态后触发器的输出将不稳定，在0和1之间变化，这时需要经过一个恢复时间，其输出才能稳定，但稳定后的值并不一定是你的输入值。这就是为什么要用两级触发器来同步异步输入信号。这样做可以防止由于异步输入信号对于本级时钟可能不满足建立保持时间而使本级触发器产.
#Verilog HDL# verilog设计中的跨时钟域处理技术
那么菜的博客
12-24 1999
本文介绍的3种方法跨时钟域处理方法如下： 打两拍； 异步双口RAM； 格雷码转换。 第一种方法：打两拍 大家很清楚，处理跨时钟域的数据有单bit和多bit之分，而打两拍的方式常见于处理单bit数据的跨时钟域问题。 打两拍的方式，其实说白了，就是定义两级寄存器，对输入的数据进行延拍。如下图所示。 应该很多人都会问，为什么是打两拍呢，打一拍、打三拍行不行呢？ 先简单说下两级寄存器的原理：两级寄存是一级寄存的平方，两级并不能完全消除亚稳态危害，但是提高了可靠性减少其发生概率。总的来讲，就是一级概
跨时钟域信号传输（Verilog）
FPGA小学生的博客
06-10 3214
本篇着重讲解单bit信号由快时钟域到慢时钟域的转化。 对于跨时钟域信号的处理，方法我们都知道： 单bit：两级触发器同步（适用于慢到快） 多bit：采用异步FIFO，异步双口RAM 加握手信号 格雷码转换 对于多bit信号来说我们想要跨时钟域处理直接使用fifo就可以了。如果对于单bit信号来说，慢时钟域到快时钟域使用两级触发器就可以，代码如下图所示： //---------慢时钟域到快时钟域----------// module mul_clk( input clk, //快时钟域时钟
Verilog基础知识（亚稳态和跨时钟域的同步电路）
热门推荐
maxwell2ic的博客
07-16 2万+
亚稳态 锁存器出现亚稳态 （1）在其中一个输入端输入的脉冲太短。 （2）两个端口输入同时有效，或两输入有效相差足够短。 （3）在使能输入的边缘处，输入信号不稳定。 触发器出现亚稳态 （1）建立/保持时间内输入信号不稳定。 （2）时钟脉冲太窄。 （3）异步信号对时钟有效沿是随机的，易产生亚稳态。异步信号包括：不被时钟控制的信号；或被不同时钟域的时钟同步的信号。 亚稳态的处理方法 ...
跨时钟域信号处理(一)--Verilog单比特信号
king阿金
03-16 1万+
网上有很多的跨时钟域信号处理的相关文章，主要分为三种： 单比特信号--打两拍或打更多拍（使用触发器）； 多比特信号--异步双口块RAM或者异步FIFO； 格雷码转换。 这次就主要说第1种情况，适用于单比特信号。 1.应用场景 从时钟域1的单比特信号DATA需要传到时钟域2下，在2下就可以使用寄存器打拍的方式将DATA信号同步到自己的时钟域下。 为什么要打拍？因为要解决亚稳态的问题。 ...
VerilogHDL之跨时钟域知识点总结
lfasdf的博客
04-22 680
跨时钟域之亚稳态、建立时间、保持时间
Verilog之跨时钟域设计-FIFO
AMD81192的博客
04-27 2219
用verilog写一个跨时钟域同步
09-17
这是一个简单的跨时钟域同步的Verilog示例，当然，实际情况中可能会有更多的细节和考虑，但这个例子可以帮助你了解如何用Verilog实现跨时钟域同步。 ### 回答3： 在Verilog中实现跨时钟域同步可以通过以下步骤完成...

“相关推荐”对你有帮助么？

  • 非常没帮助
  • 没帮助
  • 一般
  • 有帮助
  • 非常有帮助
提交
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值