FPGA实现360°SG90舵机

SG90

SG90舵机需要注意区分90°、180°和360°，今天要用的舵机是360°的。
舵机是通过输入信号来控制转动的，360°舵机不同于180°舵机，它只有顺时针旋转、逆时针选择和停止，无法通过特定的信号来达到转动的角度。所以需要通过时间和转动速度的控制来调整转动角度。

SG90的外观图奉上：

红色线接VCC，棕色线接GND，橙色线接信号。
SG90（360°）需要什么信号？
首先必须明确，SG90不论是90°、180°还是360°，它需要的控制信号都是周期为20ms 的脉宽调制（PWM)信号，只是脉冲宽度从0.5ms-2.5ms在三种舵机上的作用不同。对于360°舵机来说，0.5-1.5ms的脉冲宽度实现顺时针转动，只是速度不同；1.5-2.5ms的脉冲宽度实现逆时针转动，也只是速度不同；1.5ms的脉冲宽度实现暂停。
这里还需要明确一点（举例来说），脉冲宽度为1ms、周期为20ms的脉宽调制信号需要不断传输给舵机才能保证舵机不停地顺时针转动，并不是给了一个周期信号就完事了！

整体设计

软件：Vivado 2018.3、Notepad++
硬件：FPGA（Xilinx–xc7a35tcsg324-1 ）、360°SG90舵机、杜邦线
编程语言：Verilog HDL

设计目标
通过两个按键实现舵机顺、逆时针转动一定角度。按键一直处于高电平就一直转动。
设计思路
通过状态机实现，系统通电后首先进入停止状态，即状态1，此时FPGA不断输出脉冲宽度为1.5ms、周期为20ms的脉宽调制信号给舵机，没有操作时舵机一直处于停止状态待机；按下按键1，舵机从状态1跳到状态2，FPGA开始不断输出脉冲宽度为1ms、周期为20ms的脉宽调制信号给舵机，使其一直处于顺时针转动状态；按下按键2，舵机跳转到状态3，FPGA开始不断输出脉冲宽度为2ms、周期为20ms的脉宽调制信号给舵机，使其一直处于逆时针转动状态。设计不同脉冲宽度的pwm信号可以通过分频达到。
如何设置一定的角度，不让舵机无止尽地转动呢？
设置一个定时器，每此切换状态都开始从0计数，达到预设值后舵机状态自动跳转到停止状态，注意停止状态是没有时间限制的！状态机通过定时器只会从状态2或状态3跳转到状态1。

工程源码

实现的是每次按下90°的转动。

module SG90(
    input  rst_n,//复位信号
    input  clk,//100MHz的系统时钟
    input  key_1,//按键1-控制顺时针旋转
    input  key_2,//按键2-控制逆时针旋转
    output reg pwm//输出信号-pwm波
    );
    
    reg[1:0] state;//状态机
    reg[30:0] cnt1;//计数1，用来生成pwm信号
    reg[30:0] cnt2;//计数2，用来控制状态2和状态3的时间
    parameter MAX = 'd31000000;//状态2、3的时间预设值，类似C的宏定义可以快速改变转动的角度
    
    
    always@(posedge clk or negedge rst_n)
        begin
            if(rst_n == 1'b0)//复位信号
                begin
                    state <= 2'b00;
                end
            else        
                begin
                    case(state)//状态
                        2'b00://状态1
                            begin
                                if(key_1 == 1'b1)//按下按键1
                                    begin
                                        state <= 2'b01;//进入状态2
                                        cnt1 <= 'd0;//计数1重新计数，下同
                                        cnt2 <= 'd0;//计数2重新计数，下同
                                    end
                                else if(key_2 == 1'b1)//按下按键2
                                    begin
                                        state <= 2'b10;//进入状态3
                                        cnt1 <= 'd0;
                                        cnt2 <= 'd0;
                                    end
                                else if(cnt1 <= 'd149999)//设置脉冲宽度，下同
                                    begin
                                        cnt1 <= cnt1 + 1'b1;//计数器不断自加1实现计数，下同
                                        cnt2 <= cnt2 + 1'b1;//
                                        pwm <= 1'b1;//此宽度内，输出信号高电平，下同
                                    end
                                else if(cnt1 == 'd1999999)//设置脉冲周期，下同
                                    begin
                                        cnt2 <= cnt2 + 1'b1;
                                        cnt1 <= 'd0;//计数器1重新计数来不断产生pwm信号
                                        pwm <= 1'b0;//除上面的时间宽度其余时间输出信号pwm均为低电平，下同
                                    end
                                else//剩余情况均自加1实现计数
                                    begin
                                        cnt1 <= cnt1 + 1'b1;
                                        cnt2 <= cnt2 + 1'b1;
                                        pwm <= 1'b0;
                                    end
                                    
                            end
                        
                        2'b01:
                            begin
                                if(cnt2 == MAX)//计数器2达到预设值，跳转到停止状态，下同
                                    begin
                                        state <= 2'b00;//进入停止状态，下同
                                        cnt1 <= 'd0;
                                        cnt2 <= 'd0;
                                    end
                                else if(cnt1 <= 'd99999)
                                    begin
                                        cnt1 <= cnt1 + 1'b1;
                                        cnt2 <= cnt2 + 1'b1;                           
                                        pwm <= 1'b1;
                                    end
                                else if(cnt1 == 'd1999999)
                                    begin
                                        cnt1 <= 'd0;
                                        cnt2 <= cnt2 + 1'b1;
                                        pwm <= 1'b0;
                                    end
                                else
                                    begin
                                        cnt1 <= cnt1 + 1'b1;
                                        cnt2 <= cnt2 + 1'b1;                        
                                        pwm <= 1'b0;
                                    end
                            end
                        
                        2'b10:
                            begin
                                if(cnt2 == MAX)
                                    begin
                                        state <= 2'b00;
                                        cnt1 <= 'd0;
                                        cnt2 <= 'd0;
                                    end
                                else if(cnt1 <= 'd199999)
                                    begin
                                        cnt1 <= cnt1 + 1'b1;
                                        cnt2 <= cnt2 + 1'b1;                     
                                        pwm <= 1'b1;                                          
                                    end
                                else if(cnt1 == 'd1999999)
                                    begin
                                        cnt1 <= 'd0;
                                        cnt2 <= cnt2 + 1'b1; 
                                        pwm <= 1'b0;
                                    end
                                else
                                    begin
                                        cnt1 <= cnt1 + 1'b1;
                                        cnt2 <= cnt2 + 1'b1;       
                                        pwm <= 1'b0;                 
                                    end
                            end   
                    endcase
                end
        end           
endmodule

优化

1、添加按键消抖模块，减少舵机转动收到的操作影响。
2、添加不同角度的设置，扩大状态机实现多个角度的顺、逆时针转动。