CG代码卡通渲染，层级，边缘光

最新推荐文章于 2023-07-30 15:34:51 发布

[A]ddiction

最新推荐文章于 2023-07-30 15:34:51 发布

阅读量107

点赞数

分类专栏： unity 文章标签： unity 游戏引擎

本文链接：https://blog.csdn.net/weixin_54479200/article/details/126824924

版权

unity 专栏收录该内容

63 篇文章 0 订阅

订阅专栏

Shader "Unlit/cartoon"
{
    Properties
    {
        _MainTex ("Texture", 2D) = "white" {}
        _Diffuse("COLOR",Color)=(1,1,1,1)
        _OutLine("OutLine",Range(0,2))=0.1
        _OutLineColor("OutLineColor",Color)=(0,0,0,1)
        _Steps("Steps",Range(1,30))=1
        _ToonEffect("ToonEffect",Range(0,1))=0.5
        _RampTex("RampTex",2D)="white"{}
        _RimPower("RimPower",Range(0,3))=0
        _RimColor("RimColor",COLOR)=(1,1,1,1)
    }
    SubShader
    {
        Tags { "RenderType"="Opaque" }
        LOD 100
        Pass
        {
            Name "Outline"
            Cull Front
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCg.cginc"
            
            float _OutLine;
            fixed4 _OutLineColor;
          
            struct v2f
            {
                float4 vertex:SV_POSITION;
            };
            v2f vert(appdata_base  v)
            {   
                  v2f o;    
                  //v.vertex.xyz+=v.normal*_OutLine;
                  //o.vertex=UnityObjectToClipPos(v.vertex);
                  float3 pos=UnityObjectToViewPos(v.vertex);
                  float3 normal=normalize(mul((float3x3)UNITY_MATRIX_IT_MV,v.normal));//模型空间转换到视角空间 
                  pos=pos+normal*_OutLine;
                  o.vertex=UnityViewToClipPos(pos);
                  return o;
 
            }
            float4 frag(v2f i):SV_Target
            {   
                   return _OutLineColor ;
            }
            ENDCG
            
        }
        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCG.cginc"
            #include "Lighting.cginc"
          
 
            struct v2f
            {   
                float4 vertex : SV_POSITION;
                float2 uv : TEXCOORD0;
                fixed3 worldNormal:TEXCOORD1;
                float3 worldPos: TEXCOORD2;
 
            };
 
            sampler2D _MainTex;
            float4 _MainTex_ST;
            sampler2D _RampTex;
         
 
            float4 _Diffuse;
            float _Steps;
            float _ToonEffect;
            float4 _RimColor;
            float _RimPower;
            v2f vert (appdata_base v)
            {
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
                o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
                fixed3 worldNormal=UnityObjectToWorldNormal(v.normal);
                o.worldNormal=worldNormal;
                o.worldPos=mul(unity_ObjectToWorld,v.vertex);
 
                return o;
            }
 
            fixed4 frag (v2f i) : SV_Target
            {   
                fixed3 ambient=UNITY_LIGHTMODEL_AMBIENT.xyz;

                 fixed4 albedo=tex2D(_MainTex,i.uv);

              fixed3 WorldLightDir = UnityWorldSpaceLightDir(i.worldPos);
                fixed3 ViewDir=normalize( UnityWorldSpaceViewDir(i.worldPos));
                
                float difLight=dot(WorldLightDir,i.worldNormal)*0.5+0.5;
               
                difLight=smoothstep(0,1,difLight);
                float toon=floor(difLight*_Steps)/_Steps;
                difLight=lerp(difLight,toon,_ToonEffect);
             

            
                fixed3 diffuse=_LightColor0.rgb*albedo*_Diffuse.rgb*difLight;
               
                float rim=1-dot(i.worldNormal,ViewDir);
                fixed3 rimColor=_RimColor*pow(rim,1/_RimPower);
                 fixed3 color=diffuse+ambient+rimColor;
                 return fixed4(ambient + diffuse + rimColor,1);
            }
            ENDCG
        }
    }
}