【Shader特效】—— 音符跳动

  之前在看B站上看到unity官方用Shader Graph做的一个模型随音乐跳动的教程，想着直接用Shader代码实现一下吧，最后实现效果如下，配合之前的烟花效果，还有点KTV的感觉。示例工程和c#脚本在Shader学习笔记

Shader代码

  里面大部分代码都跟这个效果没啥关系，关键代码就两行，顶点着色器中的取随机数和顶点偏移，shader写完之后，c#脚本通过采集声音信息给shader的_Intensity赋值就可以实现上面的效果。还可以通过判断Intensity的大小来确定是否显示烟花特效。

// 音符跳动

Shader "XDEDZL/Note Bounce"
{

	Properties{
		_Color("Color Tint", Color) = (1,1,1,1)
		_MainTex("Main Tex", 2D) = "white" {}
		_Specular("Specular",Color) = (1,1,1,1)
		_Gloss("Gloss",Range(8.0,256)) = 20
        _Intensity("Intensity",Float) = 1
	}

	SubShader{
		Pass{
			// 光照模式
			Tags{"LightMode" = "ForwardBase"}

			CGPROGRAM

			#pragma vertex vert
			#pragma fragment frag
			#include "Lighting.cginc"

			fixed4 _Color;
			sampler2D _MainTex;
			// 纹理名_ST声明某个纹理的属性，.xy是缩放.zw是偏移
			float4 _MainTex_ST;
			fixed4 _Specular;
			float _Gloss;
            float _Intensity;
			 
			struct a2v {
				float4 vertex : POSITION;
				float4 normal : NORMAL;
				float4 texcoord : TEXCOORD0;
			};

			struct v2f {
				float4 pos : SV_POSITION;
				float3 worldNormal : TEXCOORD0;
				float3 worldPos : TEXCOORD1;
				float2 uv : TEXCOORD2;
			};

			v2f vert(a2v v) {
				v2f o;
                //v.vertex += v.normal * 1;
                float offset = frac(sin(dot(v.vertex.xy + _Time.xy, (12.9898,78.233))) * 43758.5453) * _Intensity;
                v.vertex += v.normal * offset;
				o.pos = UnityObjectToClipPos(v.vertex);
				o.worldNormal = UnityObjectToWorldNormal(v.normal);
				o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
				o.uv = TRANSFORM_TEX(v.texcoord,_MainTex);  // 内置函数实现了上面注释的算法

				return o;
			}

			fixed4 frag(v2f i) : SV_Target{
				fixed3 worldNormal = normalize(i.worldNormal);
				fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));

				// tex2D获取纹理对应坐标的纹素值
				fixed3 albedo = tex2D(_MainTex,i.uv).rgb * _Color.rgb;
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;  // 环境光照
				fixed3 diffuse = _LightColor0.rgb * albedo * max(0,dot(worldNormal,worldLightDir)); // 漫反射光照

				fixed3 viewDir = normalize(UnityWorldSpaceViewDir(i.worldPos));
				fixed3 halfDir = normalize(worldLightDir + viewDir);
				fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0,dot(worldNormal,halfDir)),_Gloss);  // 高光反射光照
				return fixed4(ambient + diffuse + specular, 1.0);
			}

			ENDCG
		}
	}
	Fallback "Specular"
}