用FPGA设计软件按键消抖

通常的按键所用开关为机械弹性开关，当机械触点断开、闭合时，由于机械触点的弹性作用，一个按键开关在闭合时不会马上稳定地接通，在断开时也不会一下子断开。因而在闭合及断开的瞬间均伴随有一连串的抖动，为了不产生这种现象而作的措施就是按键消抖。

软件消抖

软件消抖是通过编写程序来检测和忽略按键的抖动。以下是常见的软件消抖方法：

1. 延时检测法：
   • 当检测到按键状态改变时（例如从高电平变为低电平，表示按键被按下），不立即处理这个状态变化。
   • 等待一段时间（通常大于按键抖动的最大时间，如10ms至20ms），然后再次检测按键状态。
   • 如果按键状态仍然保持改变后的状态（例如仍然是低电平），则认为按键已经稳定闭合或断开，此时可以处理按键事件。
2. 状态机法：
   • 使用一个状态机来跟踪按键的状态变化。
   • 当检测到按键状态改变时，状态机进入一个新的状态，例如“等待稳定”状态。
   • 在“等待稳定”状态中，持续检测按键状态，直到按键状态在一定时间内保持稳定。
   • 如果按键状态在稳定时间内保持不变，则状态机进入下一个状态（例如“按键按下”或“按键释放”状态），并处理相应的按键事件。

模块框图：

FPGA软件延时检测法代码（该代码参考了野火的按键消抖代码）

链接：13. 按键消抖模块的设计与验证 — [野火]FPGA Verilog开发实战指南——基于Altera EP4CE10 征途Pro开发板 文档 (embedfire.com)

module  key_filter
(
    input   wire    clk_50Mhz   ,   //系统时钟50Mhz
    input   wire    rst_n       ,   //全局复位
    input   wire    key_in      ,   //按键输入信号

    output  reg     key_flag        //key_flag为1时表示消抖后检测到按键被按下
                                    //key_flag为0时表示没有检测到按键被按下
);

parameter CNT_MAX = 20'd999_999 ;//计数器计数最大值

reg     [19:0]  cnt_20ms    ;   //计数器


//cnt_20ms:如果时钟的上升沿检测到外部按键输入的值为低电平时，计数器开始计数
always@(posedge clk_50Mhz or negedge rst_n)begin
    if(rst_n == 1'b0) begin
        cnt_20ms <= 20'b0;
    end        
    else    if(key_in == 1'b1) begin
        cnt_20ms <= 20'b0;
    end
    else    if(cnt_20ms == CNT_MAX && key_in == 1'b0) begin
        cnt_20ms <= cnt_20ms;
    end
    else begin
        cnt_20ms <= cnt_20ms + 1'b1; 
    end     
end

//key_flag:当计数满20ms后产生按键有效标志位
//且key_flag在999_999时拉高,维持一个时钟的高电平
always@(posedge clk_50Mhz or negedge rst_n)begin
    if(rst_n == 1'b0) begin
        key_flag <= 1'b0;
    end
    else    if(cnt_20ms == CNT_MAX - 1'b1) begin
        key_flag <= 1'b1;
    end
    else begin
        key_flag <= 1'b0; 
    end
           
end

endmodule