兰伯特光照模型

1、漫反射基本概念

漫反射（DIFFUSE REFLECTION）是光线撞击一个物体表面后以各个方向均匀地反射出去的过程在漫反射下，光线以无规律的方式散射，而不像镜面反射那样按照特定的角度反射。这种散射导致了物体表面看起来均匀而不闪烁的效果。

2、兰伯特光照模型的公式

漫反射光照颜色 = 光源的颜色 * 材质的漫反射颜色 * max（0, 标准化后物体表面法线向量 · 标准化后光源方向向量）
其中：
1.标准化后物体表面法线向量· 标准化后光源方向向量 得到的结果就是 cosθ
2.max(0,cosθ)的目的是避免负数，对于模型背面的部分，认为找不到光，直接乘以0，变为黑色

2.1 如何在Shader中获取公式中的关键信息

1.光源的颜色
    Lighting.cginc 内置文件中的 _LightColor0
2.光源的方向
    _WorldSpaceLightPos0 表示光源0在世界坐标系下的位置（表示了从世界空间中每个顶点到光源的位置的向量，所以其实也是方向）
3.向量归一化方法
    normalize
4.取最大值方法
    max
5.点乘方法
    dot
6.兰伯特光照模型环境光变量（用于模拟环境光对物体的影响，避免物体阴影部分完全黑暗）
    UNITY_LIGHTMODEL_AMBIENT.rgb
7.将法线从模型空间转换到世界空间
    UnityObjectToWorldNormal

2.2 逐顶点光照

Shader "ShaderProj/1/Lambert_vertex"
{
    Properties
    {
        _MainColor("MainColor", Color) = (1,1,1,1)      // 材质漫反射颜色
    }
    SubShader
    {
        // ForwarBase 向前渲染模式主要是用来处理不透明物体的光照渲染的
        Tags { "LightMode"="ForwardBase" }
        LOD 100

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCG.cginc"
            #include "Lighting.cginc"

            fixed4 _MainColor;

            // 顶点着色器传递给片元着色器的内容
            struct v2f
            {
                float4 vertex:SV_POSITION; // 裁剪空间下的顶点坐标信息
                fixed3 color:COLOR;     // 对应顶点的漫反射光照颜色                 
            };

            // 逐顶点光照，所以相关的漫反射光照颜色的计算需要写在顶点着色器
            v2f vert (appdata_base v)
            {
                v2f v2fData;
                v2fData.vertex = UnityObjectToClipPos(v.vertex);

                float3 normal = UnityObjectToWorldNormal(v.normal);
                float3 lightDir = normalize(_WorldSpaceLightPos0.xyz);
                
                fixed3 color = _LightColor0.rgb * _MainColor.rgb * max(0, dot(normal, lightDir));
                
                // 加上兰伯特光照模型环境变量(UNITY_LIGHTMODEL_AMBIENT)的目的，是希望阴影处不要全黑
                v2fData.color = UNITY_LIGHTMODEL_AMBIENT.rgb + color;
                return v2fData;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                return fixed4(i.color.rgb, 1);
            }
            ENDCG
        }
    }
}

2.3 逐片元光照

区别：

1. 在顶点着色器中计算顶点和法线
2. 在片元着色器中计算光照

Shader "ShaderProj/1/Lambert_frag"
{
    Properties
    {
        _MainColor("_MainColor", Color) = (1,1,1,1)
    }
    SubShader
    {
        Tags { "LightMode"="ForwardBase" }
        LOD 100

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCG.cginc"
            #include "Lighting.cginc"

            fixed3 _MainColor;

            struct v2f{
                float4 vertex:SV_POSITION;
                fixed3 normal:NORMAL;
            };

            v2f vert (appdata_base v)
            {
                v2f v2fData;

                v2fData.vertex = UnityObjectToClipPos(v.vertex);
                v2fData.normal = UnityObjectToWorldNormal(v.normal);

                return v2fData;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                float3 lightDir = normalize(_WorldSpaceLightPos0.xyz);
                fixed3 color = _MainColor.rgb * _LightColor0.rgb * max(0, dot(lightDir, i.normal));
                color = color + UNITY_LIGHTMODEL_AMBIENT.rgb;
                return fixed4(color, 1);
            }
            ENDCG
        }
    }
}

3、半兰伯特光照模型

3.1 公式：

漫反射光照颜色 = 光源的颜色 * 材质的漫反射颜色 * （（标准化后物体表面法线向量 · 标准化后光源方向向量）* 0.5 + 0.5)

兰伯特光照模型通过点乘后，小于0的部分会变成0（黑色），而半兰伯特光照模型的点乘结果小于0的部分变为（0~0.5）

3.2 逐顶点光照

Shader "ShaderProj/1/HalfLambert_vertex"
{
    Properties
    {
        _MainColor("MainColor", Color) = (1,1,1,1)
    }
    SubShader
    {
        Tags { "LightMode"="ForwardBase" }
        LOD 100

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCG.cginc"
            #include "Lighting.cginc"

            fixed3 _MainColor;

            struct v2f
            {
                float4 vertex:SV_POSITION;
                fixed3 color:COLOR;
            };

            v2f vert (appdata_base v)
            {
                v2f v2fData;

                v2fData.vertex = UnityObjectToClipPos(v.vertex);
                float3 lightDir = normalize(_WorldSpaceLightPos0.xyz);
                float3 normal = UnityObjectToWorldNormal(v.normal);
                float3 color = _LightColor0.rgb * _MainColor.rgb * (dot(lightDir, normal) * 0.5 + 0.5);
                v2fData.color = UNITY_LIGHTMODEL_AMBIENT + color;

                return v2fData;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                return fixed4(i.color.rgb, 1);
            }
            ENDCG
        }
    }
}

3.3 逐片元光照

Shader "ShaderProj/1/HalfLambert_frag"
{
    Properties
    {
        _MainColor("MainColor", Color)=(1,1,1,1)
    }
    SubShader
    {
        Tags { "LightMode"="ForwardBase" }
        LOD 100

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCG.cginc"
            #include "Lighting.cginc"

            fixed3 _MainColor;
            
            struct v2f
            {
                float3 normal:NORMAL;
                float4 vertex:SV_POSITION;
            };


            v2f vert (appdata_base v)
            {
                v2f v2fData;

                v2fData.normal = UnityObjectToWorldNormal(v.normal);
                v2fData.vertex = UnityObjectToClipPos(v.vertex);

                return v2fData;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                float3 lightDir = normalize(_WorldSpaceLightPos0.xyz);
                fixed3 color = _MainColor.rgb * _LightColor0.rgb * (dot(lightDir, i.normal) * 0.5 + 0.5);
                color = color + UNITY_LIGHTMODEL_AMBIENT;

                return fixed4(color.rgb, 1);
            }
            ENDCG
        }
    }
}