1、Phong 高光反射模型
1.1 原理
Phong式高光反射光照模型的理论是,基于光的反射行为和观察者的位置决定高光反射的表现效果认为高光反射的颜色和光源的反射光线以及观察者位置方向向量夹角的余弦成正比,并且通过对余弦值取n次幂来表示光泽度(或反光度)
1.2 公式
高光反射光照颜色 = 光源的颜色 * 材质高光反射颜色 * max(0, 标准化后观察方向向量 · 标准化后的反射方向)^ 幂
- 标准化后观察方向向量· 标准化后的反射方向 得到的结果就是 cosθ
- 幂 代表的是光泽度 余弦值取n次幂\
1.3 如何在Shader中获取公式中的关键信息
- 观察者的位置(摄像机的位置): _WorldSpaceCameraPos
- 相对于法向量的反射向量:方法reflect(入射向量, 顶点法向量) 返回反射向量
- 指数幂方法:pow(底数,指数) 返回计算结果
1.4 逐顶点光照
Shader "ShaderProj/1/Phong_vertex"
{
Properties
{
_SpecularColor("_SpecularColor", Color)=(1,1,1,1) // 高光反射颜色
_SpecularNum("_SpecularNum", Range(0, 20)) = 0.5 // 光泽度
}
SubShader
{
Tags { "LightMode"="ForwardBase" }
LOD 100
Pass
{
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
#include "Lighting.cginc"
struct v2f
{
float4 pos:SV_POSITION;
fixed3 color:COLOR;
};
fixed3 _SpecularColor;
float _SpecularNum;
v2f vert (appdata_base v)
{
v2f v2fData;
v2fData.pos = UnityObjectToClipPos(v.vertex);
// 将模型空间下的顶点位置通过矩阵 [UNITY_MATRIX_M] 转换到世界空间下
float3 worldPos = mul(UNITY_MATRIX_M, v.vertex);
float3 viewDir = _WorldSpaceCameraPos.xyz - worldPos;
viewDir = normalize(viewDir);
float3 normal = UnityObjectToWorldNormal(v.normal);
float3 lightDir = normalize(_WorldSpaceLightPos0);
//lightDir = normalize(lightDir);
float3 reflectDir = reflect(-lightDir, normal);
float3 color = _LightColor0.rgb * _SpecularColor.rgb * pow(max(0, dot(viewDir, reflectDir)), _SpecularNum);
v2fData.color = color;
return v2fData;
}
fixed4 frag (v2f i) : SV_Target
{
return fixed4(i.color, 1);
}
ENDCG
}
}
}
1.5 逐片元光照
Shader "ShaderProj/1/Phont_frag"
{
Properties
{
_SpecularColor("_SpecularColor",Color) = (1,1,1,1)
_SpecularNum("_SpecularNum", Range(0,20)) = 0.5
}
SubShader
{
// 如果有多个 Pass 渲染通道时,一般情况下会把光照模式的 Tags 放到对应的 Pass 中
// 以免影响其他 Pass
Tags { "LightMode"="ForwardBase" }
LOD 100
Pass
{
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
#include "Lighting.cginc"
struct v2f
{
float4 pos:SV_POSITION;
float3 wNormal:NORMAL;
float3 wPos:TEXCOORD0;
};
fixed3 _SpecularColor;
float _SpecularNum;
v2f vert (appdata_base v)
{
v2f v2fData;
v2fData.pos = UnityObjectToClipPos(v.vertex);
v2fData.wNormal = UnityObjectToWorldNormal(v.normal);
v2fData.wPos = mul(UNITY_MATRIX_M, v.vertex).xyz;
// 得到世界坐标还有两种写法
// 1、v2fData.wPos = mul(unity_ObjectToWorld, v.vertex).xyz; // 新版
// 2、v2fData.wPos = mul(_Object2World, v.vertex).xyz; // 老版
return v2fData;
}
fixed4 frag (v2f i) : SV_Target
{
float3 viewDir = normalize(_WorldSpaceCameraPos - i.wPos);
float3 lightDir = normalize(_WorldSpaceLightPos0);
float3 reflectDir = reflect(-lightDir, i.wNormal);
fixed3 color = _LightColor0.rgb * _SpecularColor.rgb * pow(max(0, dot(viewDir, reflectDir)), _SpecularNum);
return fixed4(color, 1);
}
ENDCG
}
}
}