UVM 碎记

已于 2022-08-09 22:57:39 修改
阅读量465 收藏 3
点赞数 1
分类专栏： SV UVM 文章标签： perl verilog
于 2022-07-02 17:33:24 首次发布
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/aap6666666/article/details/125574296
版权
SV 同时被 2 个专栏收录
8 篇文章 3 订阅
订阅专栏
UVM
6 篇文章 7 订阅
订阅专栏

目录

uvm_domain

使用方法：

main phase 跳转到reset phase：

sequencer 的仲裁特性

uvm_event

uvm_barrier

uvm_callback

sequence的通信时序 

域的自动化声明

uvm_domain

控制run_phase对应的细分phase异步执行，适用于DUT含有多个时钟域时，独立的进行细分phase操作，如复位，配置，启动执行。

默认情况下，两个driver类中的复位phase 和main phase必须同时执行。

使用方法：

  1. uvm_domain xxx_domain;//组件里定义
  2. xxx_domain = new(“xxx_domain”);//实例化 function new中
  3. set_domain(xxx_domain);//将当前组件加入xxx_domain中，一般在connect_phase中使用

UVM机制学习之Objection, Domain机制_15的月亮的博客-CSDN博客

UVM：5.3.1 domain 简介_tingtang13的博客-CSDN博客

UVM：5.3.2 多domain 的例子_tingtang13的博客-CSDN博客

UVM：5.3.3 多domain中phase 的跳转_tingtang13的博客-CSDN博客

main phase 跳转到reset phase：

phase.jump(uvm_reset_phase::get());

sequencer 的仲裁特性

可以通过uvm_sequencer::set_arbitration(UVM_SEQ_ARB_TYPE val)函数来设置仲裁模式，这里的仲裁模式UVM_SEQ_ARB_TYPE 有下面几种值可以选择：

  • UVM_SEQ_ARB_FIFO：默认模式，来自于sequences的发送请求，按照FIFO先进先出的方式被依次授权，和优先级没有关系。
  • UVM_SEQ_ARB_WEIGHTED：不同sequeces的发送请求，将按照它们的优先级权重随机授权。
  • UVM_SEQ_ARB_RANDOM：不同的请求会被随机授权，而无视它们的抵达顺序和优先级。
  • UVM_SEQ_ARB_STRICT_FIFO：不同的请求，会按照它们的优先级以及抵达顺序来依次授权，因此与优先级和抵达时间都有关。
  • UVM_SEQ_ARB_STRICT_RANDOM：不同的请求，会按照它们的最高优先级随机授权，与抵达时间无关。
  • UVM_SEQ_ARB_USER：用户可以自定义仲裁方法user_priority_arbitration来裁定哪个sequencer的请求被优先授权。

uvm_event

与event 相比，uvm event类有下面几个重要特性:
 

eventuvm_event

event被->触发之后，触发使用@等待该事件的对象;

再次触发，只需再次用->触发

通过trigger()来触发,触发使用wait trigger()等待该事件的对象。

再次触发，t需要先通过reset()方法重置初始状态，再使用trigger()来触发

无法携带更多的信息可以通过trigger(T data = null)的可选参数，将伴随触发的数据对象都写入到该触发事件中，而等待该事件的对象可以通过方法wait trigger data(output T data)来获取事件触发时写入的数据对象。
t触发时无法直接触发回调函数可以通过add_callback(uvm_event_callback cb,bit append =1)函数来添加回调函数。
无法直接获取等待它的进程数目可以通过 get num waiters()来获取等待它的进程数目。


TLM 传输必须是在组件和组件之间进行的，然而，要在sequence和sequence之间进行同步，或sequence与driver之间进行同步，可以借助uvm_event来实现。

module uvm_event_sync;
  import uvm_pkg::*;
  `include "uvm_macros.svh"

  class edata extends uvm_object;
    int data;
    `uvm_object_utils(edata)
    function new(string name = "edata");
      super.new(name);
    endfunction
  endclass

  class ecb extends uvm_event_callback;
    `uvm_object_utils(ecb)
    function new(string name = "ecb");
      super.new(name);
    endfunction
    function bit pre_trigger(uvm_event e, uvm_object data = null);
      `uvm_info("EPRETRIG", $sformatf("before trigger event %s", e.get_name()), UVM_LOW)
      return 0;
    endfunction
    function void post_trigger(uvm_event e, uvm_object data = null);
      `uvm_info("EPOSTRIG", $sformatf("after trigger event %s", e.get_name()), UVM_LOW)
    endfunction
  endclass 


  class comp1 extends uvm_component;
    uvm_event e1;
    `uvm_component_utils(comp1)
    function new(string name, uvm_component parent);
      super.new(name, parent);
    endfunction
    function void build_phase(uvm_phase phase);
      super.build_phase(phase);
      e1 = uvm_event_pool::get_global("e1");
    endfunction
    task run_phase(uvm_phase phase);
      edata d = new();
      ecb cb = new();
      d.data = 100;
      #10ns;
      e1.add_callback(cb);
      e1.trigger(d);
      `uvm_info("ETRIG", $sformatf("trigger sync event at %t ps", $time), UVM_LOW)
    endtask
  endclass

  class comp2 extends uvm_component;
    uvm_event e1;
    `uvm_component_utils(comp2)
    function new(string name, uvm_component parent);
      super.new(name, parent);
    endfunction
    function void build_phase(uvm_phase phase);
      super.build_phase(phase);
      e1 = uvm_event_pool::get_global("e1");
    endfunction
    task run_phase(uvm_phase phase);
      uvm_object tmp;
      edata d;
      `uvm_info("ESYNC", $sformatf("wait sync event at %t ps", $time), UVM_LOW)
      e1.wait_trigger_data(tmp);
      void'($cast(d, tmp));
      `uvm_info("ESYNC", $sformatf("get data %0d after sync at %t ps", d.data, $time), UVM_LOW)
    endtask
  endclass

  class env1 extends uvm_env;
    comp1 c1;
    comp2 c2;
    `uvm_component_utils(env1)

    function new(string name, uvm_component parent);
      super.new(name, parent);
    endfunction

    function void build_phase(uvm_phase phase);
      super.build_phase(phase);
      c1 = comp1::type_id::create("c1", this);
      c2 = comp2::type_id::create("c2", this);
    endfunction: build_phase
  endclass

  class test1 extends uvm_test;
    `uvm_component_utils(test1)
    env1 env;
    function new(string name, uvm_component parent);
      super.new(name, parent);
    endfunction
    function void build_phase(uvm_phase phase);
      env = env1::type_id::create("env", this);
    endfunction
    task run_phase(uvm_phase phase);
      super.run_phase(phase);
      phase.raise_objection(phase);
      #1us;
      phase.drop_objection(phase);
    endtask
  endclass

  initial begin
    run_test("test1");
  end
endmodule




// UVM_INFO @ 0: reporter [RNTST] Running test test1...
// UVM_INFO @ 0: uvm_test_top.env.c2 [ESYNC] wait sync event at                    0 ps
// UVM_INFO @ 10000: reporter [EPRETRIG] before trigger event e1
// UVM_INFO @ 10000: reporter [EPOSTRIG] after trigger event e1
// UVM_INFO @ 10000: uvm_test_top.env.c1 [ETRIG] trigger sync event at                10000 ps
// UVM_INFO @ 10000: uvm_test_top.env.c2 [ESYNC] get data 100 after sync at                10000 ps

uvm_barrier

多个组件的同步。barrier.wait_for   顶层设置 barrier.set_threshold（）触发

module uvm_barrier_sync;
  import uvm_pkg::*;
  `include "uvm_macros.svh"

  class comp1 extends uvm_component;
    uvm_barrier b1;
    `uvm_component_utils(comp1)
    function new(string name, uvm_component parent);
      super.new(name, parent);
    endfunction
    function void build_phase(uvm_phase phase);
      super.build_phase(phase);
      b1 = uvm_barrier_pool::get_global("b1");
    endfunction
    task run_phase(uvm_phase phase);
      #10ns;
      `uvm_info("BSYNC", $sformatf("c1 wait for b1 at %0t ps", $time), UVM_LOW)
      b1.wait_for();
      `uvm_info("BSYNC", $sformatf("c1 is activated at %0t ps", $time), UVM_LOW)
    endtask
  endclass

  class comp2 extends uvm_component;
    uvm_barrier b1;
    `uvm_component_utils(comp2)
    function new(string name, uvm_component parent);
      super.new(name, parent);
    endfunction
    function void build_phase(uvm_phase phase);
      super.build_phase(phase);
      b1 = uvm_barrier_pool::get_global("b1");
    endfunction
    task run_phase(uvm_phase phase);
      #20ns;
      `uvm_info("BSYNC", $sformatf("c2 wait for b1 at %0t ps", $time), UVM_LOW)
      b1.wait_for();
      `uvm_info("BSYNC", $sformatf("c2 is activated at %0t ps", $time), UVM_LOW)
    endtask
  endclass

  class env1 extends uvm_env;
    comp1 c1;
    comp2 c2;
    uvm_barrier b1;
    `uvm_component_utils(env1)

    function new(string name, uvm_component parent);
      super.new(name, parent);
    endfunction

    function void build_phase(uvm_phase phase);
      super.build_phase(phase);
      c1 = comp1::type_id::create("c1", this);
      c2 = comp2::type_id::create("c2", this);
      b1 = uvm_barrier_pool::get_global("b1");
    endfunction: build_phase

    task run_phase(uvm_phase phase);
      b1.set_threshold(3);
      `uvm_info("BSYNC", $sformatf("env set b1 threshold %d at %0t ps", b1.get_threshold(), $time), UVM_LOW)
      #50ns;
      b1.set_threshold(2);
      `uvm_info("BSYNC", $sformatf("env set b1 threshold %d at %0t ps", b1.get_threshold(), $time), UVM_LOW)
    endtask

  endclass

  class test1 extends uvm_test;
    `uvm_component_utils(test1)
    env1 env;
    function new(string name, uvm_component parent);
      super.new(name, parent);
    endfunction
    function void build_phase(uvm_phase phase);
      env = env1::type_id::create("env", this);
    endfunction
    task run_phase(uvm_phase phase);
      super.run_phase(phase);
      phase.raise_objection(phase);
      #1us;
      phase.drop_objection(phase);
    endtask
  endclass

  initial begin
    run_test("test1");
  end
endmodule




// UVM_INFO @ 0: reporter [RNTST] Running test test1...
// UVM_INFO @ 0: uvm_test_top.env [BSYNC] env set b1 threshold 3 at 0 ps
// UVM_INFO @ 10000: uvm_test_top.env.c1 [BSYNC] c1 wait for b1 at 10000 ps
// UVM_INFO @ 20000: uvm_test_top.env.c2 [BSYNC] c2 wait for b1 at 20000 ps
// UVM_INFO @ 50000: uvm_test_top.env [BSYNC] env set b1 threshold 2 at 50000 ps
// UVM_INFO @ 50000: uvm_test_top.env.c1 [BSYNC] c1 is activated at 50000 ps
// UVM_INFO @ 50000: uvm_test_top.env.c2 [BSYNC] c2 is activated at 50000 ps

uvm_callback

  1. 定义callback空壳函数，extends uvm_callback；
  2. 在使用cb 的 component中注册绑定`uvm_register_cb(comp,cb)
  3. 预留函数入口：`uvm_do_callbacks(comp,cb,function) ,cb中的function
  4. 在顶层例化cb，comp，在build_phase中关联绑定，uvm_callbacks #(comp) ::add(compxx,cbxx)。
module uvm_callback_sync;
  import uvm_pkg::*;
  `include "uvm_macros.svh"

  class edata extends uvm_object;
    int data;
    `uvm_object_utils(edata)
    function new(string name = "edata");
      super.new(name);
    endfunction
  endclass

  class cb1 extends uvm_callback;
    `uvm_object_utils(cb1)
    function new(string name = "cb1");
      super.new(name);
    endfunction
    virtual function void do_trans(edata d);
      d.data = 200;
      `uvm_info("CB", $sformatf("cb1 executed with data %0d", d.data), UVM_LOW)
    endfunction
  endclass

  class cb2 extends cb1;
    `uvm_object_utils(cb2)
    function new(string name = "cb2");
      super.new(name);
    endfunction
    function void do_trans(edata d);
      d.data = 300;
      `uvm_info("CB", $sformatf("cb2 executed with data %0d", d.data), UVM_LOW)
    endfunction
  endclass


  class comp1 extends uvm_component;
    `uvm_component_utils(comp1)
    `uvm_register_cb(comp1, cb1)
    function new(string name, uvm_component parent);
      super.new(name, parent);
    endfunction
    function void build_phase(uvm_phase phase);
      super.build_phase(phase);
    endfunction
    task run_phase(uvm_phase phase);
      edata d = new();
      d.data = 100;
      `uvm_info("RUN", $sformatf("proceeding data %0d", d.data), UVM_LOW)
      `uvm_do_callbacks(comp1, cb1, do_trans(d))
    endtask
  endclass

  class env1 extends uvm_env;
    comp1 c1;
    cb1 m_cb1;
    cb2 m_cb2;
    `uvm_component_utils(env1)

    function new(string name, uvm_component parent);
      super.new(name, parent);
      m_cb1 = new("m_cb1");
      m_cb2 = new("m_cb2");
    endfunction

    function void build_phase(uvm_phase phase);
      super.build_phase(phase);
      c1 = comp1::type_id::create("c1", this);
      uvm_callbacks #(comp1)::add(c1, m_cb1);
      uvm_callbacks #(comp1)::add(c1, m_cb2);
    endfunction: build_phase
  endclass

  class test1 extends uvm_test;
    `uvm_component_utils(test1)
    env1 env;
    function new(string name, uvm_component parent);
      super.new(name, parent);
    endfunction
    function void build_phase(uvm_phase phase);
      env = env1::type_id::create("env", this);
    endfunction
    task run_phase(uvm_phase phase);
      super.run_phase(phase);
      phase.raise_objection(phase);
      #1us;
      phase.drop_objection(phase);
    endtask
  endclass

  initial begin
    run_test("test1");
  end
endmodule


// UVM_INFO @ 0: reporter [RNTST] Running test test1...
// UVM_INFO @ 0: uvm_test_top.env.c1 [RUN] proceeding data 100
// UVM_INFO @ 0: reporter [CB] cb1 executed with data 200
// UVM_INFO @ 0: reporter [CB] cb2 executed with data 300

sequence的通信时序 

         

域的自动化声明

 

BlackDogv
关注
  • 1
    点赞
  • 踩
  • 3
    收藏
    觉得还不错? 一键收藏
  • 0
    评论
专栏目录
uvm中时钟块分析
qq_63887503的博客
04-11 580
这个时序显示的是dut部内部的时序，在read信号发生时，会等待一个周期，将数据放到数据总线上。因此，采样需要： 等待两个下降沿，当然个人觉得由于提前采样，等待连个上升沿采集的应该也是正确数据。1：对于，reg_if.drv_ck .xx信号，在时钟沿边沿变化，但reg_if.xx信号会加入提前采样和延后驱动并且连接到dut上。这里如果用this.pkt_id++,指向的是req中的pkt_id.3：时序上看不到内部的数据包吗。
uvm（二）
SsyPuKoo的博客
05-25 1938
24.类的继承关系 1.uvm_object是UVM中最基本的类，几乎所有的类都继承于它，包括uvm_component 2.uvm_component有两大特性是uvm_object所没有的 一是通过在new的时候指定parent参数来形成一种树形的组织结构； 二是phase的自动执行； 25.完整的UVM树 1.所有的UVM树的结点都是由uvm_component组成的，只有基于 uvm_component派生的类才可能成为UVM树的结点 ...
[UVM] run() and run_phase()
YiSuoYanYu712的博客
08-30 354
relationship between run() and run_phase() in UVM
UVM中处理复位信号的参考代码
09-08
复位存在于每一个UVM验证环境中，简单的同时，也是我们最容易忽略的功能点。在验证环境中，通常复位信号的处理，就是在top顶层产生时钟时，做一个复位的动作。这样做的好处是简单，但是如果我们想在仿真过程中，加入一个复位的动作，实现起来就比较麻烦，对于接口上，复位后驱动的复位值，也难以实现。 本文主要介绍一种通用的方法，专门用来处理复位，具备很好的移植性，复用性，使用起来也非常方便，将复位相关的内容，单独拿出来处理，能够解决常规验证环境中，无法中间加入复位动作的痛点。
UVM知识点总结-config+phase+覆盖+打印
juvenilexhq的博客
03-13 2281
基础的点 type_id::create函数：如果一个component在实例化时，其parent被设置为null(也就是通过type_id::create创建对象，此时第二个参数为null)，那么这个component的parent将被系统设置为系统中唯一的uvm_root的实例uvm_top。针对component进行type_id::create时需要注意以下几种情况：例子：（1）如果创建了类A和类B，并且在A中实例化一个B（b），那么在A中对b进行create时，实际上parent_phase实际
UVM入门与进阶学习笔记3——phase机制
weixin_41979380的博客
01-22 1914
传统硬件设计模型在仿真开始前已完成例化和连接；而SV软件部分，类的例化需要在仿真开始后完成。虽然类的例化通过调用构建函数new()实现，但仅通过new()函数无法解决一个重要问题——验证环境层次化时需要保证例化的先后关系，以及在确立各个组件均完成例化后的连接。且如果需要实现高级功能，如顶层到底层的配置时，也无法在底层组件例化之前提前完成配置逻辑。 因此UVM引入phase机制，通过该机制可以清晰地将UVM仿真的阶段层次化。不单单是对各个phase的先后顺序，处于同一phase中的层次化组件之间的phase也
UVM0 lab1—一图看懂UVM中的phase机制(含代码结构层次图)
weixin_42162448的博客
12-18 1156
UVM0 lab1—中的phase机制详解，有结构图，1秒就看懂。
UVM学习记录.docx
03-23
在UVM（Universal Verification Methodology）中，UVM_config_db是一个关键组件，它允许在运行时动态地设置组件的配置参数。本篇文章将详细讲解如何使用UVM_config_db，主要分为三个方面：配置sequence生成...
UVM monitor_UVM
09-21
在UVM（Universal Verification Methodology）框架中，`monitor`是一个关键组件，它负责观察设计的行为并报告相关信息。本文将深入探讨UVM监控器的概念、其在验证环境中的作用，以及如何在Verilog代码中实现和应用。...
uvm template
11-13
在电子设计自动化（EDA）领域，UVM（Universal Verification Methodology）是一种广泛使用的验证方法论，主要用于系统级验证。这个“uvm template”压缩包很可能包含了一套预先配置好的UVM框架，帮助工程师快速搭建...
UVM_PHASE执行顺序
07-19
自己实测后整理的uvm_phase顺序 自己实测后整理的uvm_phase顺序
UVM简易环境生成脚本
06-06
systemverilog，UVM验证环境自动生成器，主要是利用tcl脚本一键生成，可以用于windows下modelsim仿真工程，只供参考
uvm2sadfasdfgddssddsas
08-29
UVM verification methodology UVM（Universal Verification Methodology）是一种Verify IP和SOC（Systems on Chip）设计的industry-standard verification methodology。UVM 1.2是Accellera Systems Initiative...
UVM 中run_phase和main_phase混合使用注意事项
weixin_42264693的博客
08-17 1112
run_phase和main_phase的区别这里不做多述，由于run_phase是从0时刻开始的，而main_phase并不一定，所以一般在monitor中更推荐使用run_phase。这里申明一点，在工作中，尽量不要run_phase和main_phase混合使用！这可能会给自己埋个大坑。run_phase和main_phase都会执行，run_phase受main_phase控制。1. run_phase 中raise_objection，main_phase中无。推荐使用的也是run_phase。
UVM中run phase和main phase区别
热门推荐
W1Z1Q的专栏
09-18 1万+
run_phase和main phase都是task phase，且是并行运行的，后者称为动态运行(run-time)的phase。
UVM--phase机制
创芯人--fly的博客
04-20 2681
本文主要记述了phase机制的内容，欢迎阅读指正
UVM的phase机制(Ⅰ）
行则终至
06-19 3005
介绍uvm的运行机制
UVM实用技巧【一】
qq_31515205的博客
08-01 1822
今天介绍几个UVM中较为实用的函数，在能够辅助大家调试环境。 打印环境拓扑结构 有时候，我们可能由于某些原因，组件可能层次安排不对，或者组件没有create，但是自己却没有注意到。或者我们想要看看环境的整体结构，那么就能用方法uvm_top.print_topology()打印整个拓扑结构。 它的函数原型是 function void print_topology ( uvm_prin...
Perl 语言的特点
最新发布
m0_70066267的博客
07-18 1001
Perl 语言入门学习可以涵盖多个方面，包括其特点、基本语法、高级特性以及学习资源和社区支持等。

“相关推荐”对你有帮助么？

  • 非常没帮助
  • 没帮助
  • 一般
  • 有帮助
  • 非常有帮助
提交
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值