Unity内置Shader解读1——Bumped Diffuse

1.Shader在什么情况下使用

Bumped(凹凸) Diffuse(漫反射)，凹凸漫反射，就是我们Shader中最最基础的，只有三项可以设置：
1.Main Color颜色
2.Base (RGB)漫反射贴图
3.Normalmap法线贴图

image.png

看到可设置的项基本就知道了这个shader只能做非常基础的效果，简单支持了一下法线贴图。

image.png

2.Shader的价值(用的多不多)，Shader的难度

Bumped Diffuse作为旧shader中的C位，其实在Unity4时代用的是非常多的，实现方式也比较简单。

3.代码详细注释

// Unity built-in shader source. Copyright (c) 2016 Unity Technologies. MIT license (see license.txt)
//凹凸漫反射
Shader "Legacy Shaders/Bumped Diffuse" {
    Properties {
        _Color ("Main Color", Color) = (1,1,1,1)//颜色
        _MainTex ("Base (RGB)", 2D) = "white" {}//漫反射贴图
        _BumpMap ("Normalmap", 2D) = "bump" {}//法线贴图
    }

    SubShader {
        Tags { 
            "RenderType"="Opaque" 
        }
        LOD 300

        CGPROGRAM
        //声明主要执行函数名为surf，使用Lambert光照模型
        #pragma surface surf Lambert 

        //上述属性对应参数
        sampler2D _MainTex;
        sampler2D _BumpMap;
        fixed4 _Color;

        //输入两套UV
        struct Input {
            float2 uv_MainTex;
            float2 uv_BumpMap;
        };

        void surf (Input IN, inout SurfaceOutput o) {
            //tex2D函数采样图像纹理并与用户自定义的_Color相乘
            fixed4 c = tex2D(_MainTex, IN.uv_MainTex) * _Color;
            //Albedo漫反射颜色设置为c的rgb
            o.Albedo = c.rgb;
            //透明度设置为c的透明，但是本shader未声明透明混合方式
            //个人认为此处的透明设置是无效的，所以是一句废代码
            //如果想要透明可以参照Transparent/Alpha-Bumped
            //在#pragma surface surf Lambert 后添加alpha:fade透明混合模式
            o.Alpha = c.a;
            //tex2D函数采样法线贴图纹理
            //法线贴图在进入Unity中并设置为Normal map格式的时候进行了一次优化压缩
            //这也就是为什么修改为Normal map格式后图片的颜色会变成蓝色调
            //UnpackNormal是Unity将储存的法线颜色逆转换出来
            o.Normal = UnpackNormal(tex2D(_BumpMap, IN.uv_BumpMap));
        }
        ENDCG
    }

    FallBack "Legacy Shaders/Diffuse"
}

4.Shader编写思路，用到的知识点

法线贴图的思路其实早就写过了，可以查看这篇。
这里有下面几个知识点需要注意一下：

tex2D函数

根据uv坐标找到贴图上对应的点颜色

UnpackNormal函数

UnpackNormal可以从这篇中获得详解
法线贴图在进入Unity中并设置为Normal map格式的时候进行了一次优化压缩
这也就是为什么修改为Normal map格式后图片的颜色会变成蓝色调
UnpackNormal是Unity将储存的法线颜色逆转换出来
UnpackNormal是UnityCG.cginc提供的函数，实际封装内容如下：

inline fixed3 UnpackNormal(fixed4 packednormal)
{
#if defined(UNITY_NO_DXT5nm)
    return packednormal.xyz * 2 - 1;
#elif defined(UNITY_ASTC_NORMALMAP_ENCODING)
    return UnpackNormalDXT5nm(packednormal);
#else
    return UnpackNormalmapRGorAG(packednormal);
#endif
}

跳转了UnpackNormalDXT5nm和UnpackNormalmapRGorAG，内容大致一样：

inline fixed3 UnpackNormalDXT5nm (fixed4 packednormal)
{
    fixed3 normal;
    normal.xy = packednormal.wy * 2 - 1;
    normal.z = sqrt(1 - saturate(dot(normal.xy, normal.xy)));
    return normal;
}
//按DXT5nm(1，y，1，x)或BC5(x，y，0，1)标准拆封
//注意像“bump”这样的中性纹理是(0，0，1，1)用于普通RGB normal和DXT5nm/BC5
fixed3 UnpackNormalmapRGorAG(fixed4 packednormal)
{
    // This do the trick
   packednormal.x *= packednormal.w;

    fixed3 normal;
    normal.xy = packednormal.xy * 2 - 1;
    normal.z = sqrt(1 - saturate(dot(normal.xy, normal.xy)));
    return normal;
}

看上篇或者看下图理解：

image.png